Video  - AS3

Indica o tipo de filtro aplicado ao vídeo decodificado como parte do pós-processamento. O valor padrão é 0, que permite que o compressor do vídeo aplique um filtro de desbloqueio, conforme necessário.

A compressão do vídeo pode resultar em artefatos indesejados. Você pode usar a propriedade deblocking para definir os filtros que reduzem o bloqueio e, nos vídeos compactados com o codec On2, realizar pico.

O Blocking se refere às imperfeições visíveis entre os limites dos blocos que compõem cada quadro do vídeo. O Ringing se refere às bordas distorcidas ao redor dos elementos em uma imagem de vídeo.

Há dois filtros de desbloqueio disponíveis: um no coded Sorenson e um no coded On2 VP6. Além disso, há disponível um filtro de deringing quando você usa o coded On2 VP6. Para configurar um filtro, use um dos seguintes valores:

• 0 – Permite que o compressor de vídeo aplique o filtro de desbloqueio conforme necessário.
• 1 – Não usa um filtro de desbloqueio.
• 2 – Usa o filtro de desbloqueio Sorenson.
• 3 – Apenas para o vídeo On2, usa o filtro de desbloqueio On2, mas nenhum filtro de deringing.
• 4 – Apenas para o vídeo On2, usa o filtro de desbloqueio On2 e o filtro de deringing.
• 5 – Apenas para o vídeo On2, usa o filtro de desbloqueio On2 e um filtro de deringing On2 de maior desempenho.

Se for selecionado um valor maior do que 2 para o vídeo quando você estiver usando o codec Sorenson, o decodificador Sorenson será configurado em 2 como padrão.

O uso de um filtro de desbloqueio tem um efeito sobre o desempenho de reprodução geral, e, em geral, não é necessário para o vídeo de alta largura de banda. Caso o sistema do usuário não seja poderoso o suficiente, ele pode ter dificuldades para reproduzir o vídeo com um filtro de desbloqueio ativado.

Especifica se o vídeo deve ser suavizado (interpolado) ao ser dimensionado. Para que a suavização funcione, o tempo de execução deve estar em modo de alta qualidade(o padrão). O valor padrão é false (sem suavização).

Para reproduzir vídeo com o Flash Player 9.0.115.0 e versões posteriores, defina essa propriedade como true para aproveitar a otimização de imagem mipmapping.

Um inteiro que especifica a altura do fluxo de vídeo, em pixels. Para fluxos ao vivo, esse valor é igual à propriedade Camera.height do objeto Camera que está capturando o fluxo de vídeo. Para arquivos de vídeo gravados, este valor é a altura do vídeo. O evento NetStream.Video.DimensionChange é enviado em caso de vídeos registrados quando este valor é alterado.

Talvez você queira usar essa propriedade, por exemplo, para garantir que o usuário esteja vendo o vídeo com o mesmo tamanho em que foi capturado, independentemente do tamanho real do objeto Video no Palco.

Elementos da API relacionados

Um inteiro que especifica a largura do fluxo de vídeo, em pixels. Para fluxos ao vivo, esse valor é igual à propriedade Camera.width do objeto Camera que está capturando o fluxo de vídeo. Para arquivos de vídeo gravados, este valor é a largura do vídeo. O evento NetStream.Video.DimensionChange é enviado em caso de vídeos registrados quando este valor é alterado.

Talvez você queira usar essa propriedade, por exemplo, para garantir que o usuário esteja vendo o vídeo com o mesmo tamanho em que foi capturado, independentemente do tamanho real do objeto Video no Palco.

Elementos da API relacionados

Cria uma nova ocorrência de Video. Caso não sejam fornecidos valores para os parâmetros width e height, são usados os valores padrão. Você também pode definir as propriedades de largura e altura do objeto Video depois da construção inicial, usando Video.width e Video.height. Quando é criado um novo objeto Video, os valores de zero para largura e altura não são permitidos; se você passar zero, serão aplicados os padrões.

Depois de criar o Video, chame o método DisplayObjectContainer.addChild() ou DisplayObjectContainer.addChildAt() para adicionar o objeto Video a um objeto DisplayObjectContainer pai.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Especifica um fluxo de vídeo a partir de uma câmera a ser exibido dentro dos limites do objeto Video no aplicativo.

Use este método para anexar o vídeo ao vivo capturado pelo usuário ao objeto Video. Você pode reproduzir o vídeo ao vivo localmente no mesmo computador ou dispositivo em que ele está sendo capturado, ou pode enviá-lo ao Flash Media Server e usar o servidor para canalizá-los para outros usuários.

Nota: em um aplicativo AIR iOS, o vídeo de câmera não pode ser exibido quando o aplicativo usa o modo de renderização de GPU.

Parâmetros

Elementos da API relacionados

Especifica um fluxo de vídeo a ser exibido dentro dos limites do objeto Video no aplicativo. O fluxo de vídeo é um arquivo de vídeo reproduzido com NetStream.play(), com um objeto Camera ou com null. Se você usar um arquivo de vídeo, ele pode ser armazenado no sistema de arquivos local ou no Flash Media Server. Se o valor do argumento netStream for null, o vídeo não será mais reproduzido no objeto Video.

Você não precisar usar esse método se o arquivo de vídeo contiver apenas áudio; a parte de áudio dos arquivos de vídeo é reproduzida automaticamente quando você chama NetStream.play(). Para controlar o áudio associado a um arquivo de vídeo, use a propriedade soundTransform do objeto NetStream que reproduz o arquivo de vídeo.

Parâmetros

Elementos da API relacionados

Apaga a imagem atualmente exibida no objeto Video (não o fluxo de vídeo). Este método é útil para manipular a imagem atual. Por exemplo, você pode apagar a última imagem ou visualizar as informações no modo de espera, sem precisar ocultar o objeto Video.

Elementos da API relacionados

Nesse exemplo, o código que cria os objetos Video e NetStream e chama Video.attachNetStream() e NetStream.play() é colocado em uma função de manipulador. O manipulador é chamado apenas se a tentativa de se conectar a um objeto NetConnection for bem-sucedida, e isso se dá quando o evento netStatus retornar um objeto info com uma propriedade code que indica sucesso. Recomenda-se aguardar uma conexão bem-sucedida antes de chamar NetStream.play().

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }