Camera  - AS3

A quantidade de movimento que a câmera está detectando. Os valores variam de 0 (não há movimento sendo detectado) a 100 (está sendo detectada uma grande quantidade de movimento). O valor dessa propriedade pode ajudá-lo a determinar se você precisa transmitir uma configuração para o método setMotionLevel().

Se a câmera está disponível, mas ainda não está sendo usada porque o método Video.attachCamera() não foi chamado, essa propriedade é definida como -1.

Se você estiver realizando streaming apenas do vídeo local descompactado, essa propriedade é definida apenas se você tiver atribuído uma função para o manipulador de eventos. Do contrário, ele fica indefinido.

Elementos da API relacionados

A quantidade máxima de largura de banda que o feed de vídeo de saída atual pode usar, em bytes. O valor 0 significa que o feed pode usar tanta largura de banda quanto for necessário para manter a qualidade do quadro desejada.

Para definir essa propriedade, use o método setQuality().

Elementos da API relacionados

A taxa na qual a câmera está capturando dados, em quadros por segundo. Essa propriedade não pode ser definida; no entanto, é possível usar o método setMode() para definir uma propriedade relacionada – fps – que especifica a taxa máxima de quadros com a qual você gostaria que a câmera capturasse os dados.

Elementos da API relacionados

A taxa máxima na qual a câmera pode capturar dados, em quadros por segundo. A taxa máxima possível depende dos recursos da câmera; essa taxa de quadros pode não ser obtida.

• Para definir um valor desejado para essa propriedade, use o método setMode().
• Para determinar a taxa com a qual a câmera está atualmente capturando os dados, use a propriedade currentFPS.

Elementos da API relacionados

A altura da captura atual, em pixels. Para definir um valor para essa propriedade, use o método setMode().

Elementos da API relacionados

Um índice com base em zero que especifica a posição da câmera na matriz Camera.names, que enumera todas as câmeras disponíveis.

Elementos da API relacionados

A propriedade isSupported será definida como true se a classe Camera for suportada na plataforma atual; de outra maneira, ela será definida como false.

O número de quadros de vídeo transmitidos integralmente (chamados de quadros-chave) em vez de serem interpolados pelo algoritmo de compactação de vídeo. O valor padrão é 15, o que significa que há um quadro-chave de 15 em 15 quadros. O valor 1 indica que todos os quadros são chave. Os valores permitidos são de 1 a 300.

Elementos da API relacionados

Indica se uma exibição local do que a câmera está capturando é compactada e descompactada (true), como seria o caso de uma transmissão ao vivo usando o Flash Media Server, ou não compactada (false). O valor padrão é false.

Embora um fluxo compactado seja útil para testar, por exemplo, ao pré-visualizar as configurações de qualidade do vídeo, ele tem um custo de processamento significativo. A visualização local é compactada, editada para transmissão como seria em uma conexão ao vivo e depois descompactada para visualização local.

Para definir esse valor, use Camera.setLoopback(). Para definir a quantidade de compressão usada quando esta propriedade for verdadeira, use Camera.setQuality().

Elementos da API relacionados

A quantidade de movimento necessária para chamar o evento activity. A faixa de valores aceitável varia de 0 a 100. O valor padrão é 50.

O vídeo pode ser exibido independentemente do valor do parâmetro motionLevel. Para obter mais informações, consulte setMotionLevel().

Elementos da API relacionados

O número de milésimos de segundo entre o momento em que a câmera para de detectar o movimento e o momento em que o evento activity é invocado. O valor padrão é de 2000 (2 segundos).

Para definir este valor, use setMotionLevel().

Elementos da API relacionados

Um valor booliano que indica se o usuário tem acesso negado à câmera (true) ou permitido (false) na caixa de diálogo Privacidade do Flash Player. Quando esse valor for alterado, o evento status é despachado.

Elementos da API relacionados

O nome da câmera atual, retornado pelo hardware da câmera.

Elementos da API relacionados

Uma matriz de strings que contém os nomes de todas as câmeras disponíveis. Acessar esta matriz não exibe a caixa de diálogo Flash Player Privacy. Esta matriz fornece o índice com base em zero de cada câmera e o número de câmeras no sistema (por meio de names.length).

A chamada para a propriedade names requer um exame extenso do hardware. Na maioria dos casos, você pode apenas usar a câmera padrão.

Elementos da API relacionados

Determina se o aplicativo recebeu permissão para usar a câmera.

Elementos da API relacionados

Especifica o lado de um dispositivo em que a câmera está localizada.

Use a propriedade position para determinar se uma câmera em um dispositivo móvel está na parte frontal ou traseira do dispositivo. A seguinte função verifica cada câmera disponível até localizar uma câmera com a posição desejada. Se nenhuma câmera tiver a posição desejada, então a câmera padrão será retornada.

     function getCamera( position:String ):Camera
     {
       var camera:Camera;
       var cameraCount:uint = Camera.names.length;
      for ( var i:uint = 0; i < cameraCount; ++i )
      {
        camera = Camera.getCamera( String(i) );
        if ( camera.position == position ) return camera;
      }
      return Camera.getCamera();
     
     

Nos dispositivos móveis a posição da câmara geralmente é CameraPosition.FRONT ou CameraPosition.BACK. Se a posição da Câmera não puder ser determinada, a posição será relatada como CameraPosition.UNKNOWN. Nas plataformas de desktop, a posição é sempre CameraPosition.UNKNOWN.

As constantes dos valores válidos dessa propriedade são definidas na classe CameraPosition

Elementos da API relacionados

O nível necessário de qualidade da imagem, determinado pela intensidade de compactação que está sendo aplicada a cada quadro de vídeo. Os valores aceitáveis de qualidade variam de 1 (qualidade mais baixa, compressão máxima) a 100 (qualidade mais alta, sem compressão). O valor padrão é 0, o que significa que a qualidade da imagem podem variar conforme necessário para não ultrapassar a largura de banda disponível.

Para definir essa propriedade, use o método setQuality().

Elementos da API relacionados

A largura da captura atual, em pixels. Para definir um valor desejado para essa propriedade, use o método setMode().

Elementos da API relacionados

Preenche uma matriz de bytes com base em uma região retangular dos dados de pixels

Grava um inteiro não sem sinal (um valor de pixel não multiplicado de 32 bits) para cada pixel na matriz de bytes. A matriz é redimensionada para o número necessário de bytes para conter todos os pixels.

Parâmetros

Elementos da API relacionados

Preenche um vetor com base em uma região retangular dos dados de pixel.

Grava um inteiro não assinado (um valor de pixel não multiplicado de 32 bits) para cada pixel no vetor. O vetor é redimensionado para o número necessário de entradas para conter todos os pixels.

Parâmetros

Elementos da API relacionados

Copia o último quadro em um bitmap.

Esse método copia o conteúdo do último quadro dos dados de bitmap para uma ocorrência BitmapData.

Parâmetros

Elementos da API relacionados

Retorna uma referência a um objeto Camera para captura de vídeo. Para iniciar a captura do vídeo, você deve acoplar o objeto Camera a um objeto Video (consulte Video.attachCamera()). Para transmitir o vídeo para o Flash Media Server, chame NetStream.attachCamera() para acoplar o objeto Camera a um objeto NetStream.

Múltiplas chamadas ao método getCamera() fazem referência ao mesmo driver da câmera. Assim, se o código contiver algo como firstCam:Camera = getCamera() e secondCam:Camera = getCamera(), tanto firstCam quanto secondCam fazem referência à mesma câmera, que é a câmera padrão do usuário.

Em dispositivos móveis com câmeras com foco dianteiro e traseiro, só é possível capturar vídeo de uma câmera de cada vez.

Em geral, você não deve passar um valor para o parâmetro name; basta usar getCamera() para retornar uma referência à câmera padrão. Por meio do painel de configurações Camera (que será discutido depois nesta seção), o usuário pode especificar a câmera padrão a usar.

Não é possível usar o ActionScript para definir a configuração de permissão Permitir ou Negar para acessar a câmera, mas é possível exibir a caixa de diálogo de configuração da câmera do Adobe Flash Player onde as permissões do usuário podem ser definidas. Quando um arquivo SWF usando o método attachCamera() tenta anexar a câmera retornada pelo método getCamera() para um objeto Video ou NetStream, o Flash Player exibe uma caixa de diálogo que permite ao usuário selecionar se permite ou nega acesso à câmera. (O tamanho da janela do aplicativo deve ter, pelo menos, 215 x 138 pixels; este é o tamanho mínimo que o Flash Player exige para que a caixa de diálogo seja exibida.) Quando o usuário responde à caixa de diálogo de configurações da câmera, o Flash Player retorna um objeto de informação no evento status que indica a resposta do usuário: Camera.muted indica que o usuário negou acesso a uma câmera; Camera.Unmuted indica que o usuário permitiu o acesso a uma câmera. Para determinar se o usuário negou ou permitiu acesso à câmera sem manipular o evento status, use a propriedade muted.

No Flash Player, o usuário pode especificar configurações permanentes de privacidade para um determinado domínio, clicando com o botão direito (no Windows e no Linux) ou com o botão Control (no Macintosh), enquanto um arquivo SWF estiver sendo executado, selecionando Configurações, caixa de diálogo Privacidade e selecionando Lembrar. Se o usuário selecionar Lembrar, o Flash Player não pergunta mais se deve permitir ou negar aos arquivos SWF deste domínio o acesso à sua câmera.

Observação: O método attachCamera() não invocará a caixa de diálogo Permitir ou Negar acesso à câmera se o usuário negar o acesso selecionando Lembrar na caixa de diálogo Configurações do Flash Player. Neste caso, é possível solicitar ao usuário que altere a configuração exibindo o painel Privacidade do Flash Player para o usuário, usando Security.showSettings(SecurityPanel.PRIVACY).

Se getCamera() retornar null, a câmera está sendo usada por outro aplicativo, ou não há câmeras instaladas no sistema. Para determinar se há câmeras instaladas, use a propriedade names.length. Para exibir o painel Configurações da câmera do Flash Player, que permite que o usuário escolha a câmera que será a referência de getCamera(), use System.showSettings(SecurityPanel.CAMERA).

Analisar as câmeras do hardware é algo que leva tempo. Quando o tempo de execução encontra pelo menos uma câmera, o hardware não é analisado novamente durante todo o tempo de vida da ocorrência do player. No entanto, se o tempo de execução não encontrar câmeras, ele vai analisar todas as vezes que getCamera for chamado. Isso é útil caso a câmera esteja presente, mas desativada; se o seu arquivo SWF fornecer o botão Tentar novamente que chama getCamera, o Flash Player consegue encontrar a câmera sem que o usuário precise reiniciar o arquivo SWF.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);
        
        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            if (Camera.isSupported)
            {
                cam = Camera.getCamera();
                
                 if (!cam) {
                    myTextField.text = "No camera is installed.";
                    
                } else if (cam.muted) {
                    myTextField.text = "To enable the use of the camera,\n"
                                     + "please click on this text field.\n" 
                                     + "When the Flash Player Settings dialog appears,\n"
                                     + "make sure to select the Allow radio button\n" 
                                     + "to grant access to your camera.";
    
                    myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
    
                }else {
                    myTextField.text = "Connecting";
                    connectCamera(); 
                }
       
                addChild(myTextField);
    
                t.addEventListener(TimerEvent.TIMER, timerHandler);
            }else {
                myTextField.text = "The Camera class is not supported on this device.";
            }
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

Solicita a permissão da câmera para o aplicativo.

Especifica quais quadros de vídeo são transmitidos integralmente (chamados de quadros-chaves) em vez de serem interpolados pelo algoritmo de compactação de vídeo. Este método é aplicável apenas se você estiver transmitindo vídeo com o Flash Media Server.

O algoritmo de compressão do Flash Video compacta o vídeo transmitindo apenas o que foi alterado desde o último quadro do vídeo; essas partes são consideradas quadros interpolados. Os quadros de um vídeo podem ser interpolados de acordo com o conteúdo do quadro anterior. Um quadro-chave, no entanto, é um quadro de vídeo que é completo; não é interpolado dos quadros anteriores.

Para determinar como definir um valor para o parâmetro keyFrameInterval, considere a utilização da largura de banda e a acessibilidade da reprodução de vídeo. Por exemplo, especificar um valor maior para keyFrameInterval (enviando quadros-chaves com menos frequência) reduz a utilização da largura de banda. No entanto, isso pode aumentar o tempo necessário para posicionar o indicador de reprodução em um ponto particular no vídeo; talvez seja necessário interpolar quadros de vídeo anteriores antes que o vídeo possa ser retomado.

Por outro lado, especificar um valor menor para keyFrameInterval (enviando os quadros-chaves com mais frequência) aumenta a utilização da largura de banda porque todos os quadros de vídeo são transmitidos com mais frequência, mas pode diminuir o tempo necessário para buscar um quadro em particular em um vídeo gravado.

Parâmetros

Elementos da API relacionados

Especifica se um fluxo de vídeo compactado será ou não usado para uma exibição local da câmera. Esse método é aplicável apenas se você estiver transmitindo o vídeo com o Flash Media Server; a definição de compress como true permite ver com mais precisão como o vídeo vai aparecer para os usuários quando o visualizam em tempo real.

Embora um fluxo compactado seja útil para fins de testes, como pré-visualização das configurações da qualidade de vídeo, ele tem um custo de processamento significativo, pois a visualização local não é simplesmente compactada; é compactada, editada para transmissão (como seria em uma conexão ao vivo), e depois descompactada para visualização local.

Para definir a quantidade de compressão usada quando você define compress como true, use Camera.setQuality().

Parâmetros

Elementos da API relacionados

Define o modo de captura da câmera como o modo nativo que melhor atende aos requisitos especificados. Se a câmera não tiver um modo nativo que corresponda a todos os parâmetros que você passar, o tempo de execução selecionará o modo de captura que melhor sintetiza o modo solicitado. Essa manipulação pode envolver cortar a imagem e soltar quadros.

Por padrão, o modo de execução solta os quadros conforme necessário para manter o tamanho da imagem. Para minimizar o número de quadros liberados, mesmo que isso signifique reduzir o tamanho da imagem, passe false para o parâmetro favorArea.

Ao escolher um modo nativo, o tempo de execução tenta manter a proporção solicitada sempre que possível. Por exemplo, se você emitir o comando myCam.setMode(400, 400, 30) e os valores máximos de largura e altura disponíveis na câmera forem 320 e 288, o tempo de execução definirá a largura e a altura como 288. Definindo essas propriedades com o mesmo valor, o tempo de execução mantém a proporção 1:1 que você solicitou.

Para determinar os valores atribuídos a essas propriedades depois que o tempo e execução seleciona o modo que mais se aproxima dos valores solicitados, use as propriedades width, height e fps.

Se estiver usando o Flash Media Server, você também pode capturar quadros únicos ou criar uma fotografia de lapso de tempo. Para obter mais informações, consulte NetStream.attachCamera().

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.events.MouseEvent;
    import flash.display.StageScaleMode;

    public class Camera_setModeExample extends Sprite {
        private var cam:Camera;
        private var vid:Video;

        public function Camera_setModeExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;

            cam = Camera.getCamera();
            
            if (!cam) {
                trace("No camera is installed.");
            }else {
                connectCamera();
            }
        }

        private function connectCamera():void {
            vid = new Video();
            vid.width = cam.width;
            vid.height = cam.height; 
            vid.attachCamera(cam);
            addChild(vid);    

            stage.addEventListener(MouseEvent.CLICK, clickHandler);
        }
    
        private function clickHandler(e:MouseEvent):void {

            switch (cam.width) {
                case 160:
                cam.setMode(320, 240, 10); 
                break;
                case 320:
                cam.setMode(640, 480, 5); 
                break;
                default:
                cam.setMode(160, 120, 15); 
                break;
            } 

            removeChild(vid);           
            connectCamera();
        }
    }
}

Especifica quanto movimento é necessário para despachar o evento activity. Como opção, define o número de milissegundos que devem transcorrer sem atividade até que o tempo de execução considere que o movimento foi interrompido e despache o evento.

Observação: o vídeo pode ser exibido independentemente do valor do parâmetro motionLevel. Esse parâmetro determina apenas quando e em que circunstâncias o evento é despachado – e não se o vídeo está sendo capturado ou exibido.

Para impedir que a câmera detecte qualquer tipo de movimento, passe o valor 100 para o parâmetro motionLevel; o evento activity nunca é despachado. (Provavelmente você usaria este valor apenas para fins de testes – por exemplo, para desativar temporariamente quaisquer manipuladores que normalmente seriam acionados quando o evento for despachado.)

Para determinar a quantidade de movimento que a câmera está detectando no momento, use a propriedade activityLevel. Os valores de sensibilidade de movimento correspondem diretamente aos valores de atividade. A completa falta de movimento é um valor de atividade 0. O movimento constante é um valor de atividade 100. Seu valor da atividade é menor do que o valor de sensibilidade de movimento quando você não estiver se movendo; quando estiver, os valores de atividades frequentemente ultrapassam o valor de sensibilidade de movimento.

Esse método é semelhante, em objetivo, ao método Microphone.setSilenceLevel(); os dois são usados para especificar quando o evento activity deve ser despachado. No entanto, esses métodos têm um impacto significativamente diferente nos fluxos de publicação:

• Microphone.setSilenceLevel() foi projetado para otimizar a largura de banda. Quando um fluxo de áudio é considerado silencioso, não são enviados dados de áudio. Em vez disso, é enviada uma única mensagem, indicando que o silêncio iniciou.
• Camera.setMotionLevel() foi projetado para detectar movimento e não afeta a utilização da largura de banda. Mesmo que um fluxo de vídeo não detecte movimento, o vídeo ainda é enviado.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.ActivityEvent;

    public class Camera_setMotionLevelExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_setMotionLevelExample() {
            myTextField = new TextField();
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            cam = Camera.getCamera();
            
            if (!cam) {
                myTextField.text = "No camera is installed.";

            }else {
                myTextField.text = "Waiting to connect.";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                cam.setMotionLevel(5, 1000);
                cam.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
        }

        private function activityHandler(e:ActivityEvent):void {
            if (e.activating == true) {
                t.start();    
            } else {
                myTextField.text = "Everything is quiet.";
                t.stop();
            }    
        }

        private function timerHandler(event:TimerEvent):void {
             myTextField.x = 10;
             myTextField.y = cam.height + 20;
             myTextField.text = "There is some activity. Level: " + cam.activityLevel;
        }
    }
}

Define a quantidade máxima de largura de banda por segundo ou a qualidade de imagem necessária do feed de vídeo de saída atual. Este método é geralmente aplicável apenas se você estiver transmitindo vídeo com o Flash Media Server.

Use esse método para especificar qual elemento do feed do vídeo de saída é mais importante para a sua aplicação – utilização de largura de banda ou qualidade de imagem.

• Para indicar qual utilização da largura de banda tem precedência, transmita um valor para bandwidth e 0 para quality. O tempo de execução transmite vídeo com a qualidade mais alta possível na largura de banda especificada. Se necessário, o tempo de execução reduz a qualidade da imagem para não ultrapassar a largura de banda especificada. Em geral, à medida que aumenta o movimento, diminui a qualidade.
• Para indicar qual qualidade tem precedência, transmita 0 para bandwidth e um valor numérico para quality. O tempo de execução usa tanta largura de banda quanto necessário para manter a qualidade especificada. Se necessário, o tempo de execução reduz a taxa de quadros para manter a qualidade da imagem. Em geral, à medida que aumenta o movimento, aumenta também a largura de banda.
• Para especificar que a largura de banda e a qualidade são igualmente importantes, transmita valores numéricos para os dois parâmetros. O tempo de execução transmite vídeo que atinge a qualidade especificada e que não excede a largura de banda especificada. Se necessário, o tempo de execução reduz a taxa de quadros para manter a qualidade da imagem sem exceder a largura de banda especificada.

Parâmetros

Elementos da API relacionados

Despachado quando uma câmera inicia ou encerra uma sessão. Chame Camera.setMotionLevel() para especificar a quantidade de movimento necessária para disparar um evento activity com um valor activating de true, ou a hora sem a atividade que deve transcorrer antes do disparo de um evento activity com um valor para activating de false.

Esse evento tem as seguintes propriedades:

Será despachado quando o aplicativo solicitar permissão para usar a câmera no dispositivo. Verifique o valor da propriedade status para determinar se a permissão for concedida ou recusada

Elementos da API relacionados

Despachado quando uma câmera relata seu status. Antes de acessar uma câmera, o tempo de execução exibe uma caixa de diálogo Privacidade para que os usuários permitam ou neguem o acesso à sua câmera. Se o valor da propriedade code for "Camera.Muted", o usuário se recusou a permitir o acesso do arquivo SWF à câmera do usuário. Se o valor da propriedade code for "Camera.Unmuted", o usuário permitiu o acesso do arquivo SWF à câmera do usuário.

Nota: Este evento não é despachado na plataforma do AIR. Ele é utilizado somente no Flash Player.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Enviado depois que um novo quadro de câmera é processado pelo runtime e disponibilizado para cópia.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Observação: é necessário acoplar uma câmera ao seu computador para que este exemplo funcione corretamente.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Camera;
    import flash.media.Video;

    public class CameraExample extends Sprite {
        private var video:Video;
        
        public function CameraExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var camera:Camera = Camera.getCamera();
            
            if (camera != null) {
                camera.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
                video = new Video(camera.width * 2, camera.height * 2);
                video.attachCamera(camera);
                addChild(video);
            } else {
                trace("You need a camera.");
            }
        }
        
        private function activityHandler(event:ActivityEvent):void {
            trace("activityHandler: " + event);
        }
    }
}