ParagraphElement

パッケージ	flashx.textLayout.elements
クラス	public final class ParagraphElement
継承	ParagraphElement ParagraphFormattedElement FlowGroupElement FlowElement Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

ParagraphElement クラスは、テキストフロー階層で段落を表します。その親は ParagraphFormattedElement で、その子には範囲エレメント（SpanElement）、イメージエレメント（inLineGraphicElement）、リンクエレメント（LinkElement）および TCY（Tatechuuyoko - 縦中横）エレメント（TCYElement）を含めることができます。段落テキストは、1 つ以上の SpanElement オブジェクトに保存されます。このオブジェクトは、同じ属性を共有するテキストの範囲を定義します。TCYElement オブジェクトは、縦書きの行の中の横書きテキストのように、行に対して垂直な短い日本語テキストの実行を定義します。TCYElement にも、複数の範囲を含めることができます。

デフォルトの MXML プロパティmxmlChildren

例を表示

さらに例を参照

Creating TextFlow objects

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		alignmentBaseline : * TextLayoutFormat：行の基準を揃えるベースラインを指定します。	FlowElement
		backgroundAlpha : * TextLayoutFormat：背景のアルファ（透明）値です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		backgroundColor : * TextLayoutFormat：テキストの背景色です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		baselineShift : * TextLayoutFormat：ベースラインを dominantBaseline 値から移動させる量です。	FlowElement
		blockProgression : * TextLayoutFormat：垂直方向または並行方向の行配置を指定します。	FlowElement
		breakOpportunity : * TextLayoutFormat：折り返しのあるテキストを複数行に分割する際の、改行可能位置を制御します。	FlowElement
		cffHinting : * TextLayoutFormat：このテキストに使用される CFF ヒンティングのタイプです。	FlowElement
		clearFloats : * TextLayoutFormat：フロートを回り込むようにテキストを配置する方法を制御します。	FlowElement
		color : * TextLayoutFormat：テキストの色です。	FlowElement
		columnCount : * TextLayoutFormat：テキスト列の数です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		columnGap : * TextLayoutFormat：列間のふち取り領域をピクセル単位で指定します（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		columnWidth : * TextLayoutFormat：列幅（ピクセル単位）です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		computedFormat : flashx.textLayout.formats:ITextLayoutFormat [読み取り専用] このエレメントに有効な計算済みのフォーマット属性を返します。	FlowElement
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		coreStyles : Object [読み取り専用] この FlowElement の coreStyles を返します。	FlowElement
		digitCase : * TextLayoutFormat：このテキストに使用される数字の大文字小文字区別のタイプです。	FlowElement
		digitWidth : * TextLayoutFormat：このテキストに使用される数字の幅のタイプです。	FlowElement
		direction : * TextLayoutFormat：テキストブロック内のテキストのデフォルトの双方向埋め込みレベルを指定します。	FlowElement
		dominantBaseline : * TextLayoutFormat：行のエレメントの垂直座標を決定するために alignmentBaseline に吸着させるエレメントのベースラインを指定します。	FlowElement
		firstBaselineOffset : * TextLayoutFormat：コンテナ内の最初の行のベースライン位置を指定します。	FlowElement
		fontFamily : * TextLayoutFormat：使用するフォント名またはフォント名のカンマ区切りリストです。	FlowElement
		fontLookup : * TextLayoutFormat：使用するフォント参照です。	FlowElement
		fontSize : * TextLayoutFormat：テキストのサイズ（ピクセル単位）です。	FlowElement
		fontStyle : * TextLayoutFormat：テキストのスタイルです。	FlowElement
		fontWeight : * TextLayoutFormat：テキストの太さです。	FlowElement
		format : flashx.textLayout.formats:ITextLayoutFormat このエレメントに直接適用される TextLayoutFormat プロパティです。	FlowElement
		id : String エレメントに識別名を割り当て、id の参照により、エレメントへのスタイルの設定を可能にします。	FlowElement
		justificationRule : * TextLayoutFormat：段落のテキストの均等配置に使用するルールです。	FlowElement
		justificationStyle : * TextLayoutFormat：段落の均等配置に使用するスタイルです。	FlowElement
		kerning : * TextLayoutFormat：カーニングでは、読みやすくするために、特定の文字ペア間でピクセルを調整します。	FlowElement
		leadingModel : * TextLayoutFormat：行送りの基準と行送り方向の組み合わせである、行送りモデルを指定します。	FlowElement
		ligatureLevel : * TextLayoutFormat：フォントで定義された合字のうち、どの合字がテキストで使用されるかを制御します。	FlowElement
		lineBreak : * TextLayoutFormat：コンテナ内のテキスト折り返しを制御します（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		lineHeight : * TextLayoutFormat：テキストの行送りを制御します。	FlowElement
		lineThrough : * TextLayoutFormat：true の場合、打ち消し線が適用されます。打ち消し線はテキストの中央に描画される線です。	FlowElement
		linkActiveFormat : * TextLayoutFormat：通常の状態のリンクに使用されるフォーマット属性を定義します。	FlowElement
		linkHoverFormat : * TextLayoutFormat：マウスがリンクの境界内に移動されたときにホバー状態のリンクに対して使用されるフォーマット属性を定義します。	FlowElement
		linkNormalFormat : * TextLayoutFormat：通常の状態のリンクに使用されるフォーマット属性を定義します。	FlowElement
		listAutoPadding : * TextLayoutFormat：リストの始端におけるパディング値が auto である場合に、始端に対して自動インデントを指定します。	FlowElement
		listMarkerFormat : * TextLayoutFormat：フォーマット属性のリストマーカーを定義します。	FlowElement
		listStylePosition : * TextLayoutFormat：有効な値は、ListStylePosition.INSIDE、ListStylePosition.OUTSIDE、FormatValue.INHERIT です。デフォルト値は定義されていません。つまり、未設定です。カスケード時に定義されていない場合、このプロパティは祖先から値を継承します。	FlowElement
		listStyleType : * TextLayoutFormat：有効な値は、ListStyleType.UPPER_ALPHA、ListStyleType.LOWER_ALPHA、ListStyleType.UPPER_ROMAN、ListStyleType.LOWER_ROMAN、ListStyleType.NONE、ListStyleType.DISC、ListStyleType.CIRCLE、ListStyleType.SQUARE、ListStyleType.BOX、ListStyleType.CHECK、ListStyleType.DIAMOND、ListStyleType.HYPHEN、ListStyleType.ARABIC_INDIC、ListStyleType.BENGALI、ListStyleType.DECIMAL、ListStyleType.DECIMAL_LEADING_ZERO、ListStyleType.DEVANAGARI、ListStyleType.GUJARATI、ListStyleType.GURMUKHI、ListStyleType.KANNADA、ListStyleType.PERSIAN、ListStyleType.THAI、ListStyleType.URDU、ListStyleType.CJK_EARTHLY_BRANCH、ListStyleType.CJK_HEAVENLY_STEM、ListStyleType.HANGUL、ListStyleType.HANGUL_CONSTANT、ListStyleType.HIRAGANA、ListStyleType.HIRAGANA_IROHA、ListStyleType.KATAKANA、ListStyleType.KATAKANA_IROHA、ListStyleType.LOWER_ALPHA、ListStyleType.LOWER_GREEK、ListStyleType.LOWER_LATIN、ListStyleType.UPPER_ALPHA、ListStyleType.UPPER_GREEK、ListStyleType.UPPER_LATIN、FormatValue.INHERIT です。デフォルト値は定義されていません。つまり、未設定です。カスケード時に定義されていない場合、このプロパティは祖先から値を継承します。	FlowElement
		locale : * TextLayoutFormat：テキストのロケールです。	FlowElement
		mxmlChildren : Array 子の配列をこのオブジェクトに追加します。	FlowGroupElement
		numChildren : int [読み取り専用] この FlowGroupElement オブジェクトに含まれる子 FlowElement の数を返します。	FlowGroupElement
		paddingBottom : * TextLayoutFormat：下部のインセット（ピクセル単位）です。	FlowElement
		paddingLeft : * TextLayoutFormat：左側のインセット（ピクセル単位）です。	FlowElement
		paddingRight : * TextLayoutFormat：右側のインセット（ピクセル単位）です。	FlowElement
		paddingTop : * TextLayoutFormat：上部のインセット（ピクセル単位）です。	FlowElement
		paragraphEndIndent : * TextLayoutFormat：段落の終端をどれだけインデントするかを指定する数値（ピクセル単位）です。	FlowElement
		paragraphSpaceAfter : * TextLayoutFormat：段落の後に空けるスペースを指定する数値（ピクセル単位）です。	FlowElement
		paragraphSpaceBefore : * TextLayoutFormat：段落の前に空けるスペースを指定する数値（ピクセル単位）です。	FlowElement
		paragraphStartIndent : * TextLayoutFormat：段落の始端をどれだけインデントするかを指定する数値（ピクセル単位）です。	FlowElement
		parent : FlowGroupElement [読み取り専用] この FlowElement オブジェクトの親を返します。	FlowElement
		parentRelativeEnd : int [読み取り専用] 親に含まれるこの FlowElement オブジェクトの相対的な末尾を返します。	FlowElement
		parentRelativeStart : int [読み取り専用] 親に含まれるこの FlowElement オブジェクトの相対的な先頭を返します。	FlowElement
		renderingMode : * TextLayoutFormat：このテキストに使用されるレンダリングモードです。	FlowElement
		styleName : * TextLayoutFormat：エレメントに識別クラスを割り当て、styleName を参照することで、エレメントへのスタイルの設定を可能にします。	FlowElement
		styles : Object [読み取り専用] この FlowElement のスタイルを返します。	FlowElement
		tabStops : * TextLayoutFormat：段落に関連付けるタブストップを指定します。	FlowElement
		textAlign : * TextLayoutFormat：コンテナを基準とした段落内の行揃えです。	FlowElement
		textAlignLast : * TextLayoutFormat：均等配置テキストの、コンテナを基準とした段落内の最後（単一）の行の行揃えです。	FlowElement
		textAlpha : * TextLayoutFormat：テキストのアルファ（透明）値です。	FlowElement
		textDecoration : * TextLayoutFormat：テキストの装飾です。	FlowElement
		textIndent : * TextLayoutFormat：段落の一行目をどれだけインデントするかを指定する数値（ピクセル単位）です。	FlowElement
		textJustify : * TextLayoutFormat：テキストの均等配置オプションを指定します。	FlowElement
		textLength : int [読み取り専用] この FlowElement オブジェクトとその子が所有するテキストの長さの合計を返します。	FlowElement
		textRotation : * TextLayoutFormat：テキストの回転角度を決定します。	FlowElement
		tracking : Object [書き込み専用] 追跡を設定します。trackingRight プロパティと同義です。	FlowElement
		trackingLeft : * TextLayoutFormat：各文字の左側にトラッキング（または手動カーニング）をどれだけ適用するかの数値（ピクセル単位または fontSize のパーセント（120％など））です。	FlowElement
		trackingRight : * TextLayoutFormat：各文字の右側にトラッキング（または手動カーニング）をどれだけ適用するかの数値（ピクセル単位または fontSize のパーセント（120％など））です。	FlowElement
		typeName : String 各 FlowElement には typeName が含まれます。	FlowElement
		typographicCase : * TextLayoutFormat：このテキストに使用される文字の大文字小文字区別のタイプです。	FlowElement
		userStyles : Object FlowElement オブジェクトでのユーザースタイルの読み取りおよび書き込みを可能にします。	FlowElement
		verticalAlign : * TextLayoutFormat：垂直方向の行揃えまたは均等配置です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		whiteSpaceCollapse : * TextLayoutFormat：テキストを TextFlow にインポートする際、空白を圧縮または保持します。	FlowElement
		wordSpacing : * TextLayoutFormat：均等配置に使用する単語間の最適間隔、最小間隔、および最大間隔（通常の間隔幅の倍数）を指定します。	FlowElement

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		ParagraphElement() コンストラクター - テキストフロー内の段落を表します。	ParagraphElement
		addChild(child:FlowElement):FlowElement 子 FlowElement オブジェクトを追加します。	FlowGroupElement
		addChildAt(index:uint, child:FlowElement):FlowElement 指定したインデックス位置に子 FlowElement オブジェクトを追加します。	FlowGroupElement
		clearStyle(styleProp:String):void styleProp パラメーターにより指定されたスタイルを、この FlowElement オブジェクトからクリアします。	FlowElement
		deepCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement この FlowElement オブジェクトのディープコピー（すべての子を含む）を作成し、指定された 2 つの文字位置間のコンテンツをコピーし、そのコピーを FlowElement オブジェクトとして返します。	FlowElement
		equalUserStyles(otherElement:FlowElement):Boolean userStyles を他の otherElement の userStyles と比較します。	FlowElement
		findChildIndexAtPosition(relativePosition:int):int テキストの相対位置が指定されると、相対位置を含む最初の子 FlowElement のインデックスを検出します。	FlowGroupElement
		findLeaf(relativePosition:int):FlowLeafElement テキストの相対位置が指定されると、位置を含むリーフエレメントを検出します。	FlowGroupElement
		findNextAtomBoundary(relativePosition:int):int 指定された位置より先をスキャンして、テキスト内の次のアトムの位置を検出してインデックスを返します。	ParagraphElement
		findNextWordBoundary(relativePosition:int):int テキスト内の次の単語境界のインデックスを返します。	ParagraphElement
		findPreviousAtomBoundary(relativePosition:int):int 指定された位置より手前をスキャンして、テキスト内の前のアトムの位置を検出してインデックスを返します。	ParagraphElement
		findPreviousWordBoundary(relativePosition:int):int テキスト内の前の単語境界のインデックスを返します。	ParagraphElement
		getAbsoluteStart():int テキストフロー内のエレメントの開始位置を絶対インデックスとして返します。	FlowElement
		getCharAtPosition(relativePosition:int):String この FlowElement オブジェクトに対して相対的な、指定された位置の文字を返します。	FlowElement
		getCharCodeAtPosition(relativePosition:int):int この FlowElement に対して相対的な、指定された位置の文字コードを返します。	FlowElement
		getChildAt(index:int):FlowElement 指定されたインデックス位置にある子 FlowElement を返します。	FlowGroupElement
		getChildIndex(child:FlowElement):int 指定された FlowElement オブジェクトの子の中を検索し、そのインデックス位置を返します。	FlowGroupElement
		getElementRelativeStart(ancestorElement:FlowElement):int 上位エレメントに対して相対的な、このエレメントの先頭を返します。	FlowElement
		getFirstLeaf():FlowLeafElement このグループの最初の FlowLeafElement 下位要素を返します。	FlowGroupElement
		getLastLeaf():FlowLeafElement このグループの最後の FlowLeafElement 下位要素を返します。	FlowGroupElement
		getNextParagraph():ParagraphElement この段落に続く段落を返すか、または先に段落がない場合は null を返します。	ParagraphElement
		getNextSibling():FlowElement テキストフロー階層内の次の FlowElement 兄弟を返します。	FlowElement
		getParagraph():ParagraphElement このエレメントに関連付けられている ParagraphElement オブジェクトを返します。	FlowElement
		getPreviousParagraph():ParagraphElement この段落の手前にある段落を返すか、またはこれが TextFlow の最初の段落の場合は null を返します。	ParagraphElement
		getPreviousSibling():FlowElement テキストフロー階層内の前の FlowElement 兄弟を返します。	FlowElement
		getStyle(styleProp:String):* styleProp パラメーターによって指定されたスタイルの値を返します。これは、スタイル名を指定するもので、任意のユーザースタイル名を含むことができます。	FlowElement
		getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String [オーバーライド]	FlowGroupElement
		getTextFlow():flashx.textLayout.elements:TextFlow テキストフロー階層を遡って、エレメントのルート TextFlow オブジェクトを返します。	FlowElement
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		initialized(document:Object, id:String):void 実装オブジェクトが作成され、MXML タグに指定されたすべてのコンポーネントプロパティが初期化された後に、MXML オブジェクトに対して呼び出されます。	FlowElement
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		removeChild(child:FlowElement):FlowElement このグループから指定された子 FlowElement オブジェクトを削除します。	FlowGroupElement
		removeChildAt(index:uint):FlowElement 指定されたインデックス位置にある子 FlowElement オブジェクトを削除します。	FlowGroupElement
		replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void グループ内の子エレメントを指定された新規エレメントに置き換えます。	FlowGroupElement
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		setStyle(styleProp:String, newValue:*):void styleProp パラメーターにより指定されたスタイルの値を、newValue パラメーターで指定する値に設定します。	FlowElement
		shallowCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement この FlowElement オブジェクトのコピーを作成し、指定された 2 つの文字位置間のコンテンツをコピーします。	FlowElement
		splitAtIndex(childIndex:int):FlowGroupElement childIndex パラメーターにより指定された位置でこのオブジェクトを分割します。	FlowGroupElement
		splitAtPosition(relativePosition:int):FlowElement relativePosition パラメーターで指定された位置（このエレメントのテキストの相対位置）で、この FlowElement オブジェクトを分割します。	FlowElement
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

コンストラクターの詳細

()

コンストラクター

public function ParagraphElement()

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

コンストラクター - テキストフロー内の段落を表します。

メソッドの詳細

findNextAtomBoundary

()

メソッド

public function findNextAtomBoundary(relativePosition:int):int

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

指定された位置より先をスキャンして、テキスト内の次のアトムの位置を検出してインデックスを返します。アトムとは、グラフィックエレメントと文字（結合された文字のグループを含む）の両方、テキスト行を構成する分割できないエンティティを指す用語です。

パラメーター

relativePosition:int — テキスト内の開始位置で、0 から数えられます

戻り値

int — テキスト内の次のアトムのインデックス

関連する API エレメント

flash.text.engine.TextLine

例 ( この例の使用方法 )

この例では、段落内において指定されたオフセットの次のアトム境界を検出します。

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class ParagraphElement_findNextAtomBoundary  extends Sprite
    {
        public function ParagraphElement_findNextAtomBoundary()
        {
            // create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
            var textFlow:TextFlow = new TextFlow();
            var paragraph:ParagraphElement = new ParagraphElement();    
            var span:SpanElement = new SpanElement();
            // assign text to the span; add span to paragraph and paragraph to TextFlow
            span.text = "Hello brave, new world!";
            paragraph.addChild(span);
            textFlow.addChild(paragraph);
            // assign a controller to the stage and update it to compose and display text
            textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
            textFlow.flowComposer.updateAllControllers();
            // find the next atom boundaries from offsets 5 and 10
            var atomBoundary:int = paragraph.findNextAtomBoundary(4);                           
            trace(atomBoundary); // 5 
            atomBoundary = paragraph.findNextAtomBoundary(10);                           
            trace(atomBoundary); // 11  
        }
    }
}

findNextWordBoundary

()

メソッド

public function findNextWordBoundary(relativePosition:int):int

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

テキスト内の次の単語境界のインデックスを返します。

指定された位置より先をスキャンして、テキスト内の次の単語開始位置または単語終了位置を検出します。

パラメーター

relativePosition:int — テキスト内の開始位置で、0 から数えられます

戻り値

int — テキスト内の次の単語境界のインデックス

例 ( この例の使用方法 )

この例では、段落内において指定されたオフセットの次の単語境界を検出します。

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class ParagraphElement_findNextWordBoundary  extends Sprite
    {
        public function ParagraphElement_findNextWordBoundary()
        {
            // create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
            var textFlow:TextFlow = new TextFlow();
            var paragraph:ParagraphElement = new ParagraphElement();    
            var span:SpanElement = new SpanElement();
            // assign text to the span; add span to paragraph and paragraph to TextFlow
            span.text = "Hello brave, new world!";
            paragraph.addChild(span);
            textFlow.addChild(paragraph);
            // assign a controller to the stage and update it to compose and display text
            textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
            textFlow.flowComposer.updateAllControllers();
            // find the next word boundary from offsets 0 and 12
            var wordBoundary:int = paragraph.findNextWordBoundary(0);                           
            trace(wordBoundary); // 5 
            wordBoundary = paragraph.findNextWordBoundary(12);                           
            trace(wordBoundary); // 13        
        }
    }
}

findPreviousAtomBoundary

()

メソッド

public function findPreviousAtomBoundary(relativePosition:int):int

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

指定された位置より手前をスキャンして、テキスト内の前のアトムの位置を検出してインデックスを返します。アトムとは、グラフィックエレメントと文字（結合された文字のグループを含む）の両方、テキスト行を構成する分割できないエンティティを指す用語です。

パラメーター

relativePosition:int — テキスト内の開始位置で、0 から数えられます

戻り値

int — テキスト内の前のアトムのインデックス

関連する API エレメント

flash.text.engine.TextLine

例 ( この例の使用方法 )

この例では、段落内において指定されたオフセットの前のアトム境界を検出します。

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class ParagraphElement_findPreviousAtomBoundary  extends Sprite
    {
        public function ParagraphElement_findPreviousAtomBoundary()
        {
            // create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
            var textFlow:TextFlow = new TextFlow();
            var paragraph:ParagraphElement = new ParagraphElement();    
            var span:SpanElement = new SpanElement();
            // assign text to the span; add span to paragraph and paragraph to TextFlow
            span.text = "Hello brave, new world!";
            paragraph.addChild(span);
            textFlow.addChild(paragraph);
            // assign a controller to the stage and update it to compose and display text
            textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
            textFlow.flowComposer.updateAllControllers();
            // find the previous atom boundaries from offsets 6 and 13
            var atomBoundary:int = paragraph.findPreviousAtomBoundary(6);                           
            trace(atomBoundary); // 5 
            atomBoundary = paragraph.findPreviousAtomBoundary(13);                           
            trace(atomBoundary); // 12      
        }
    }
}

findPreviousWordBoundary

()

メソッド

public function findPreviousWordBoundary(relativePosition:int):int

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

テキスト内の前の単語境界のインデックスを返します。

指定された位置より手前をスキャンして、テキスト内の前の単語開始位置または単語終了位置を検出します。

パラメーター

relativePosition:int — テキスト内の開始位置で、0 から数えられます

戻り値

int — テキスト内の前の単語境界のインデックス

例 ( この例の使用方法 )

この例では、段落内において指定されたオフセットの前の単語境界を検出します。

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class ParagraphElement_findPreviousWordBoundary  extends Sprite
    {
        public function ParagraphElement_findPreviousWordBoundary()
        {
            // create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
            var textFlow:TextFlow = new TextFlow();
            var paragraph:ParagraphElement = new ParagraphElement();    
            var span:SpanElement = new SpanElement();
            // assign text to the span; add span to paragraph and paragraph to TextFlow
            span.text = "Hello brave, new world!";
            paragraph.addChild(span);
            textFlow.addChild(paragraph);
            // assign a controller to the stage and update it to compose and display text
            textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
            textFlow.flowComposer.updateAllControllers();
            // find the previous word boundary from offsets 0 and 12
            var wordBoundary:int = paragraph.findPreviousWordBoundary(22);                           
            trace(wordBoundary); // 17 
            wordBoundary = paragraph.findPreviousWordBoundary(11);                           
            trace(wordBoundary); // 6  
        }
    }
}

getNextParagraph

()

メソッド

public function getNextParagraph():ParagraphElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

この段落に続く段落を返すか、または先に段落がない場合は null を返します。

戻り値

ParagraphElement — 次の段落、または先に段落がない場合は null。

関連する API エレメント

getPreviousParagraph()

例 ( この例の使用方法 )

この例では、テキストの段落を xml マークアップから 3 つインポートし、getChildAtIndex(0) を使用して最初の段落にアクセスし、getNextParagraph() を使用して 2 番目の段落にアクセスします。

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class ParagraphElement_getNextParagraph  extends Sprite
    {
        public function ParagraphElement_getNextParagraph()
        {
            // create TextFlow object
            var textFlow:TextFlow = new TextFlow();        
            // create content for TextFlow using XML markup
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
                    "<flow:p>"+
                        "<flow:span>This is the first paragraph.</flow:span>"+    
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>This is the second paragraph.</flow:span>"+    
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>This is the third paragraph.</flow:span>"+ 
                    "</flow:p>"+
                "</flow:TextFlow>";
            // import the xml markup into a TextFlow object and display it on the stage
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
            textFlow.flowComposer.updateAllControllers();
            // get first paragraph
            var p:ParagraphElement = textFlow.getChildAt(0) as ParagraphElement;
            // get next paragraph and display its content
            var nextParagraph:ParagraphElement = p.getNextParagraph();
            trace("nextParagraph.text is: " + nextParagraph.getText());
        }
    }
}

getPreviousParagraph

()

メソッド

public function getPreviousParagraph():ParagraphElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

この段落の手前にある段落を返すか、またはこれが TextFlow の最初の段落の場合は null を返します。

戻り値

ParagraphElement

関連する API エレメント

getNextParagraph()

例 ( この例の使用方法 )

この例では、テキストの段落を xml マークアップから 3 つインポートし、getChildAtIndex(1) を使用して 2 番目の段落にアクセスし、getPreviousParagraph() を使用して最初の段落にアクセスします。

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class ParagraphElement_getPreviousParagraph  extends Sprite
    {
        public function ParagraphElement_getPreviousParagraph()
        {
            // create TextFlow object
            var textFlow:TextFlow = new TextFlow();        
            // create content for TextFlow using XML markup
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
                    "<flow:p>"+
                        "<flow:span>This is the first paragraph.</flow:span>"+    
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>This is the second paragraph.</flow:span>"+    
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>This is the third paragraph.</flow:span>"+ 
                    "</flow:p>"+
                "</flow:TextFlow>";
            // import the xml markup into a TextFlow object and display it on the stage
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
            textFlow.flowComposer.updateAllControllers();
            // get second paragraph (first = 0)
            var p:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
            // get  previous paragraph and display its content
            var prevParagraph:ParagraphElement = p.getPreviousParagraph();
            trace("prevParagraph.text is: " + prevParagraph.getText());
        }
    }
}

例この例の使用方法

ParagraphElementExample.as

この例では、テキストの段落を 3 つ作成して形式を設定します。

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    import flash.text.engine.FontPosture;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.formats.TextLayoutFormat;

    public class ParagraphElementExample extends Sprite {
        
        // create the TextFlow object
        private var textFlow:TextFlow = new TextFlow();
        
        // Create Strings of text for the paragraphs
        private var para1String:String = "In the first paragraph of a "
        private var para1String2:String = "cheap" 
        private var para1String3:String ="Western novel, a cowboy meets a saloon girl.";
        private var para2String:String = "In the middle of the cheap novel a really bad guy, "+
                        "who is having a relationship with the saloon girl, sees the cowboy help "+
                        "her onto her horse as she smiles at him warmly."
        private var para3String:String = "In the last paragraph of the cheap novel, the cowboy kills "+
                            "the really bad guy in a shootout in the middle of main street and "+ 
                            "then rides into the sunset with the saloon girl on the back of his horse."; 
                  
        public function ParagraphElementExample()
        {
            // create a TextLayoutFormat object to use in formatting the paragraphs
            var textLayoutFormat:TextLayoutFormat = new TextLayoutFormat();
            var paragraph1:ParagraphElement = new ParagraphElement();
            
            // create the ParagraphElement objects
            var paragraph2:ParagraphElement = new ParagraphElement();
            var paragraph3:ParagraphElement = new ParagraphElement();
            
            // create the SpanElement objects to hold the content of the paragraphs
            var p1Span1:SpanElement = new SpanElement();
            var p1Span2:SpanElement = new SpanElement();
            var p1Span3:SpanElement = new SpanElement();
            var p2Span:SpanElement = new SpanElement();
            var p3Span:SpanElement = new SpanElement();
            
            // assign the strings of text for the 1st paragraph to spans
            p1Span1.text = para1String;
            p1Span2.text = para1String2;
            p1Span2.fontStyle = FontPosture.ITALIC;  // italicize 'cheap'
            p1Span3.text = para1String3;
            
            // add spans to first paragraph
            paragraph1.addChild(p1Span1);
            paragraph1.addChild(p1Span2);
            paragraph1.addChild(p1Span3);
            
            // assign the string of text for the 2nd paragraph to a span
            // and add the span to the second paragraph
            p2Span.text = para2String;
            paragraph2.addChild(p2Span);
            
            // assign the string of text for the 3rd paragraph to a span
            // and add the span to the third paragraph
            p3Span.text = para3String;
            paragraph3.addChild(p3Span);
            
            // add the paragraphs to the TextFlow
            textFlow.addChild(paragraph1);
            textFlow.addChild(paragraph2);
            textFlow.addChild(paragraph3);
            
            // set the text formatting properties
            textLayoutFormat.fontSize = 14;
            textLayoutFormat.textIndent = 15;
            textLayoutFormat.paragraphSpaceAfter = 15;
            textLayoutFormat.paddingTop = 4;
            textLayoutFormat.paddingLeft = 4;
            
            // assign the format object to the TextFlow
            textFlow.hostFormat = textLayoutFormat;
            
            // assign a controller to the stage and update it to compose and 
            // display the text
            textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

ParagraphElementExample2.as

この例では、xml マークアップを TextFlow オブジェクトにインポートします。xml マークアップによって、前の例と同じ 3 つのテキストの段落とその形式を定義します。

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    
    public class ParagraphElementExample2 extends Sprite {
        
        // create the TextFlow object
        private var textFlow:TextFlow = new TextFlow();
        
        // xml markup that defines the attributes and contents of a text flow
        private var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>In the first paragraph of a </flow:span>"+
                        "<flow:span fontStyle=\"italic\">cheap</flow:span>"+
                        "<flow:span> Western novel, a cowboy meets a saloon girl.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>In the middle of the cheap novel a really bad guy, </flow:span>"+
                        "<flow:span>who is having a relationship with the saloon girl, sees the cowboy help </flow:span>"+
                        "<flow:span>her onto her horse as she smiles at him warmly.</flow:span>"+ 
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>In the last paragraph of the cheap novel, the cowboy kills the really </flow:span>"+ 
                        "<flow:span> bad guy in a shootout in the middle of main street and then rides into the sunset with </flow:span>"+
                        "<flow:span>the saloon girl on the back of his horse.</flow:span>" + 
                    "</flow:p>"+
                  "</flow:TextFlow>";
                  
        public function ParagraphElementExample2()
        {
            // import the xml markup into a TextFlow object and display it on the stage
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

法律上の注意 | プライバシーポリシー

ParagraphElement - AS3

パッケージx

言語エレメント

付録

パッケージ flashx.textLayout.elements