FlowGroupElement

パッケージ	flashx.textLayout.elements
クラス	public class FlowGroupElement
継承	FlowGroupElement FlowElement Object
サブクラス	ParagraphFormattedElement, SubParagraphGroupElementBase

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

FlowGroupElement クラスは、子の配列を持つことができる FlowElement オブジェクトの基本クラスです。これらのクラスには、TextFlow、ParagraphElement、DivElement および LinkElement が含まれます。

FlowGroupElement オブジェクトを直接作成することはできません。new FlowGroupElement() を呼び出すと、エラー例外がスローされます。

デフォルトの MXML プロパティmxmlChildren

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		alignmentBaseline : * TextLayoutFormat：行の基準を揃えるベースラインを指定します。	FlowElement
		backgroundAlpha : * TextLayoutFormat：背景のアルファ（透明）値です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		backgroundColor : * TextLayoutFormat：テキストの背景色です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		baselineShift : * TextLayoutFormat：ベースラインを dominantBaseline 値から移動させる量です。	FlowElement
		blockProgression : * TextLayoutFormat：垂直方向または並行方向の行配置を指定します。	FlowElement
		breakOpportunity : * TextLayoutFormat：折り返しのあるテキストを複数行に分割する際の、改行可能位置を制御します。	FlowElement
		cffHinting : * TextLayoutFormat：このテキストに使用される CFF ヒンティングのタイプです。	FlowElement
		clearFloats : * TextLayoutFormat：フロートを回り込むようにテキストを配置する方法を制御します。	FlowElement
		color : * TextLayoutFormat：テキストの色です。	FlowElement
		columnCount : * TextLayoutFormat：テキスト列の数です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		columnGap : * TextLayoutFormat：列間のふち取り領域をピクセル単位で指定します（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		columnWidth : * TextLayoutFormat：列幅（ピクセル単位）です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		computedFormat : flashx.textLayout.formats:ITextLayoutFormat [読み取り専用] このエレメントに有効な計算済みのフォーマット属性を返します。	FlowElement
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		coreStyles : Object [読み取り専用] この FlowElement の coreStyles を返します。	FlowElement
		digitCase : * TextLayoutFormat：このテキストに使用される数字の大文字小文字区別のタイプです。	FlowElement
		digitWidth : * TextLayoutFormat：このテキストに使用される数字の幅のタイプです。	FlowElement
		direction : * TextLayoutFormat：テキストブロック内のテキストのデフォルトの双方向埋め込みレベルを指定します。	FlowElement
		dominantBaseline : * TextLayoutFormat：行のエレメントの垂直座標を決定するために alignmentBaseline に吸着させるエレメントのベースラインを指定します。	FlowElement
		firstBaselineOffset : * TextLayoutFormat：コンテナ内の最初の行のベースライン位置を指定します。	FlowElement
		fontFamily : * TextLayoutFormat：使用するフォント名またはフォント名のカンマ区切りリストです。	FlowElement
		fontLookup : * TextLayoutFormat：使用するフォント参照です。	FlowElement
		fontSize : * TextLayoutFormat：テキストのサイズ（ピクセル単位）です。	FlowElement
		fontStyle : * TextLayoutFormat：テキストのスタイルです。	FlowElement
		fontWeight : * TextLayoutFormat：テキストの太さです。	FlowElement
		format : flashx.textLayout.formats:ITextLayoutFormat このエレメントに直接適用される TextLayoutFormat プロパティです。	FlowElement
		id : String エレメントに識別名を割り当て、id の参照により、エレメントへのスタイルの設定を可能にします。	FlowElement
		justificationRule : * TextLayoutFormat：段落のテキストの均等配置に使用するルールです。	FlowElement
		justificationStyle : * TextLayoutFormat：段落の均等配置に使用するスタイルです。	FlowElement
		kerning : * TextLayoutFormat：カーニングでは、読みやすくするために、特定の文字ペア間でピクセルを調整します。	FlowElement
		leadingModel : * TextLayoutFormat：行送りの基準と行送り方向の組み合わせである、行送りモデルを指定します。	FlowElement
		ligatureLevel : * TextLayoutFormat：フォントで定義された合字のうち、どの合字がテキストで使用されるかを制御します。	FlowElement
		lineBreak : * TextLayoutFormat：コンテナ内のテキスト折り返しを制御します（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		lineHeight : * TextLayoutFormat：テキストの行送りを制御します。	FlowElement
		lineThrough : * TextLayoutFormat：true の場合、打ち消し線が適用されます。打ち消し線はテキストの中央に描画される線です。	FlowElement
		linkActiveFormat : * TextLayoutFormat：通常の状態のリンクに使用されるフォーマット属性を定義します。	FlowElement
		linkHoverFormat : * TextLayoutFormat：マウスがリンクの境界内に移動されたときにホバー状態のリンクに対して使用されるフォーマット属性を定義します。	FlowElement
		linkNormalFormat : * TextLayoutFormat：通常の状態のリンクに使用されるフォーマット属性を定義します。	FlowElement
		listAutoPadding : * TextLayoutFormat：リストの始端におけるパディング値が auto である場合に、始端に対して自動インデントを指定します。	FlowElement
		listMarkerFormat : * TextLayoutFormat：フォーマット属性のリストマーカーを定義します。	FlowElement
		listStylePosition : * TextLayoutFormat：有効な値は、ListStylePosition.INSIDE、ListStylePosition.OUTSIDE、FormatValue.INHERIT です。デフォルト値は定義されていません。つまり、未設定です。カスケード時に定義されていない場合、このプロパティは祖先から値を継承します。	FlowElement
		listStyleType : * TextLayoutFormat：有効な値は、ListStyleType.UPPER_ALPHA、ListStyleType.LOWER_ALPHA、ListStyleType.UPPER_ROMAN、ListStyleType.LOWER_ROMAN、ListStyleType.NONE、ListStyleType.DISC、ListStyleType.CIRCLE、ListStyleType.SQUARE、ListStyleType.BOX、ListStyleType.CHECK、ListStyleType.DIAMOND、ListStyleType.HYPHEN、ListStyleType.ARABIC_INDIC、ListStyleType.BENGALI、ListStyleType.DECIMAL、ListStyleType.DECIMAL_LEADING_ZERO、ListStyleType.DEVANAGARI、ListStyleType.GUJARATI、ListStyleType.GURMUKHI、ListStyleType.KANNADA、ListStyleType.PERSIAN、ListStyleType.THAI、ListStyleType.URDU、ListStyleType.CJK_EARTHLY_BRANCH、ListStyleType.CJK_HEAVENLY_STEM、ListStyleType.HANGUL、ListStyleType.HANGUL_CONSTANT、ListStyleType.HIRAGANA、ListStyleType.HIRAGANA_IROHA、ListStyleType.KATAKANA、ListStyleType.KATAKANA_IROHA、ListStyleType.LOWER_ALPHA、ListStyleType.LOWER_GREEK、ListStyleType.LOWER_LATIN、ListStyleType.UPPER_ALPHA、ListStyleType.UPPER_GREEK、ListStyleType.UPPER_LATIN、FormatValue.INHERIT です。デフォルト値は定義されていません。つまり、未設定です。カスケード時に定義されていない場合、このプロパティは祖先から値を継承します。	FlowElement
		locale : * TextLayoutFormat：テキストのロケールです。	FlowElement
		mxmlChildren : Array 子の配列をこのオブジェクトに追加します。	FlowGroupElement
		numChildren : int [読み取り専用] この FlowGroupElement オブジェクトに含まれる子 FlowElement の数を返します。	FlowGroupElement
		paddingBottom : * TextLayoutFormat：下部のインセット（ピクセル単位）です。	FlowElement
		paddingLeft : * TextLayoutFormat：左側のインセット（ピクセル単位）です。	FlowElement
		paddingRight : * TextLayoutFormat：右側のインセット（ピクセル単位）です。	FlowElement
		paddingTop : * TextLayoutFormat：上部のインセット（ピクセル単位）です。	FlowElement
		paragraphEndIndent : * TextLayoutFormat：段落の終端をどれだけインデントするかを指定する数値（ピクセル単位）です。	FlowElement
		paragraphSpaceAfter : * TextLayoutFormat：段落の後に空けるスペースを指定する数値（ピクセル単位）です。	FlowElement
		paragraphSpaceBefore : * TextLayoutFormat：段落の前に空けるスペースを指定する数値（ピクセル単位）です。	FlowElement
		paragraphStartIndent : * TextLayoutFormat：段落の始端をどれだけインデントするかを指定する数値（ピクセル単位）です。	FlowElement
		parent : FlowGroupElement [読み取り専用] この FlowElement オブジェクトの親を返します。	FlowElement
		parentRelativeEnd : int [読み取り専用] 親に含まれるこの FlowElement オブジェクトの相対的な末尾を返します。	FlowElement
		parentRelativeStart : int [読み取り専用] 親に含まれるこの FlowElement オブジェクトの相対的な先頭を返します。	FlowElement
		renderingMode : * TextLayoutFormat：このテキストに使用されるレンダリングモードです。	FlowElement
		styleName : * TextLayoutFormat：エレメントに識別クラスを割り当て、styleName を参照することで、エレメントへのスタイルの設定を可能にします。	FlowElement
		styles : Object [読み取り専用] この FlowElement のスタイルを返します。	FlowElement
		tabStops : * TextLayoutFormat：段落に関連付けるタブストップを指定します。	FlowElement
		textAlign : * TextLayoutFormat：コンテナを基準とした段落内の行揃えです。	FlowElement
		textAlignLast : * TextLayoutFormat：均等配置テキストの、コンテナを基準とした段落内の最後（単一）の行の行揃えです。	FlowElement
		textAlpha : * TextLayoutFormat：テキストのアルファ（透明）値です。	FlowElement
		textDecoration : * TextLayoutFormat：テキストの装飾です。	FlowElement
		textIndent : * TextLayoutFormat：段落の一行目をどれだけインデントするかを指定する数値（ピクセル単位）です。	FlowElement
		textJustify : * TextLayoutFormat：テキストの均等配置オプションを指定します。	FlowElement
		textLength : int [読み取り専用] この FlowElement オブジェクトとその子が所有するテキストの長さの合計を返します。	FlowElement
		textRotation : * TextLayoutFormat：テキストの回転角度を決定します。	FlowElement
		tracking : Object [書き込み専用] 追跡を設定します。trackingRight プロパティと同義です。	FlowElement
		trackingLeft : * TextLayoutFormat：各文字の左側にトラッキング（または手動カーニング）をどれだけ適用するかの数値（ピクセル単位または fontSize のパーセント（120％など））です。	FlowElement
		trackingRight : * TextLayoutFormat：各文字の右側にトラッキング（または手動カーニング）をどれだけ適用するかの数値（ピクセル単位または fontSize のパーセント（120％など））です。	FlowElement
		typeName : String 各 FlowElement には typeName が含まれます。	FlowElement
		typographicCase : * TextLayoutFormat：このテキストに使用される文字の大文字小文字区別のタイプです。	FlowElement
		userStyles : Object FlowElement オブジェクトでのユーザースタイルの読み取りおよび書き込みを可能にします。	FlowElement
		verticalAlign : * TextLayoutFormat：垂直方向の行揃えまたは均等配置です（カスケード時に定義されていない場合、デフォルトの値が採用されます）。	FlowElement
		whiteSpaceCollapse : * TextLayoutFormat：テキストを TextFlow にインポートする際、空白を圧縮または保持します。	FlowElement
		wordSpacing : * TextLayoutFormat：均等配置に使用する単語間の最適間隔、最小間隔、および最大間隔（通常の間隔幅の倍数）を指定します。	FlowElement

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		FlowGroupElement() 基本クラス - 新しい FlowGroupElement() を呼び出すと、エラー例外がスローされます。	FlowGroupElement
		addChild(child:FlowElement):FlowElement 子 FlowElement オブジェクトを追加します。	FlowGroupElement
		addChildAt(index:uint, child:FlowElement):FlowElement 指定したインデックス位置に子 FlowElement オブジェクトを追加します。	FlowGroupElement
		clearStyle(styleProp:String):void styleProp パラメーターにより指定されたスタイルを、この FlowElement オブジェクトからクリアします。	FlowElement
		deepCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement この FlowElement オブジェクトのディープコピー（すべての子を含む）を作成し、指定された 2 つの文字位置間のコンテンツをコピーし、そのコピーを FlowElement オブジェクトとして返します。	FlowElement
		equalUserStyles(otherElement:FlowElement):Boolean userStyles を他の otherElement の userStyles と比較します。	FlowElement
		findChildIndexAtPosition(relativePosition:int):int テキストの相対位置が指定されると、相対位置を含む最初の子 FlowElement のインデックスを検出します。	FlowGroupElement
		findLeaf(relativePosition:int):FlowLeafElement テキストの相対位置が指定されると、位置を含むリーフエレメントを検出します。	FlowGroupElement
		getAbsoluteStart():int テキストフロー内のエレメントの開始位置を絶対インデックスとして返します。	FlowElement
		getCharAtPosition(relativePosition:int):String この FlowElement オブジェクトに対して相対的な、指定された位置の文字を返します。	FlowElement
		getCharCodeAtPosition(relativePosition:int):int この FlowElement に対して相対的な、指定された位置の文字コードを返します。	FlowElement
		getChildAt(index:int):FlowElement 指定されたインデックス位置にある子 FlowElement を返します。	FlowGroupElement
		getChildIndex(child:FlowElement):int 指定された FlowElement オブジェクトの子の中を検索し、そのインデックス位置を返します。	FlowGroupElement
		getElementRelativeStart(ancestorElement:FlowElement):int 上位エレメントに対して相対的な、このエレメントの先頭を返します。	FlowElement
		getFirstLeaf():FlowLeafElement このグループの最初の FlowLeafElement 下位要素を返します。	FlowGroupElement
		getLastLeaf():FlowLeafElement このグループの最後の FlowLeafElement 下位要素を返します。	FlowGroupElement
		getNextSibling():FlowElement テキストフロー階層内の次の FlowElement 兄弟を返します。	FlowElement
		getParagraph():ParagraphElement このエレメントに関連付けられている ParagraphElement オブジェクトを返します。	FlowElement
		getPreviousSibling():FlowElement テキストフロー階層内の前の FlowElement 兄弟を返します。	FlowElement
		getStyle(styleProp:String):* styleProp パラメーターによって指定されたスタイルの値を返します。これは、スタイル名を指定するもので、任意のユーザースタイル名を含むことができます。	FlowElement
		getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String [オーバーライド]	FlowGroupElement
		getTextFlow():flashx.textLayout.elements:TextFlow テキストフロー階層を遡って、エレメントのルート TextFlow オブジェクトを返します。	FlowElement
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		initialized(document:Object, id:String):void 実装オブジェクトが作成され、MXML タグに指定されたすべてのコンポーネントプロパティが初期化された後に、MXML オブジェクトに対して呼び出されます。	FlowElement
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		removeChild(child:FlowElement):FlowElement このグループから指定された子 FlowElement オブジェクトを削除します。	FlowGroupElement
		removeChildAt(index:uint):FlowElement 指定されたインデックス位置にある子 FlowElement オブジェクトを削除します。	FlowGroupElement
		replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void グループ内の子エレメントを指定された新規エレメントに置き換えます。	FlowGroupElement
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		setStyle(styleProp:String, newValue:*):void styleProp パラメーターにより指定されたスタイルの値を、newValue パラメーターで指定する値に設定します。	FlowElement
		shallowCopy(relativeStart:int = 0, relativeEnd:int = -1):FlowElement この FlowElement オブジェクトのコピーを作成し、指定された 2 つの文字位置間のコンテンツをコピーします。	FlowElement
		splitAtIndex(childIndex:int):FlowGroupElement childIndex パラメーターにより指定された位置でこのオブジェクトを分割します。	FlowGroupElement
		splitAtPosition(relativePosition:int):FlowElement relativePosition パラメーターで指定された位置（このエレメントのテキストの相対位置）で、この FlowElement オブジェクトを分割します。	FlowElement
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

プロパティの詳細

mxmlChildren

プロパティ

mxmlChildren:Array

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

子の配列をこのオブジェクトに追加します。replaceChildren() メソッドを使用して、配列内の各エレメントを追加します。MXML コンパイル済みのインポート時に使用されます。

実装
public function get mxmlChildren():Array
public function set mxmlChildren(value:Array):void

例外

TypeError — 配列要素が FlowElement または String でない場合

numChildren

プロパティ

numChildren:int [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

この FlowGroupElement オブジェクトに含まれる子 FlowElement の数を返します。

実装
public function get numChildren():int

コンストラクターの詳細

()

コンストラクター

public function FlowGroupElement()

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

基本クラス - 新しい FlowGroupElement() を呼び出すと、エラー例外がスローされます。

メソッドの詳細

addChild

()

メソッド

public function addChild(child:FlowElement):FlowElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

子 FlowElement オブジェクトを追加します。子リストの最後に新しい子が追加されます。

パラメーター

child:FlowElement — 追加する子エレメントです。

戻り値

FlowElement — 追加された子 FlowElement

例 ( この例の使用方法 )

この例は、addChild() を呼び出し、段落に範囲を追加して、その段落をテキストフローに追加します。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_addChildExample extends Sprite
    {        
        public function FlowGroupElement_addChildExample()
        {
            // create string for text flow
            var simpleText:String = "It was a dark and stormy night.";        
                    
            // define TextFlow, ParagraphElement, and SpanElement objects
            var textFlow:TextFlow = new TextFlow();            
            var paragraph:ParagraphElement = new ParagraphElement();
            var span:SpanElement = new SpanElement;
            span.text = simpleText;
            // add span to paragraph and add paragraph to text flow
            paragraph.addChild(span);
            textFlow.addChild(paragraph);
            // assign composer and controller and update controller to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

addChildAt

()

メソッド

public function addChildAt(index:uint, child:FlowElement):FlowElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

指定したインデックス位置に子 FlowElement オブジェクトを追加します。

パラメーター

	`index:uint` — 子エレメントを追加する位置のインデックスで、最初の位置は 0 です。

	`child:FlowElement` — 追加する子エレメントです。

戻り値

FlowElement — 追加された子 FlowElement

例外

RangeError — index は範囲外です。

例 ( この例の使用方法 )

この例は、addChildAt を呼び出し、段落に 3 つの範囲を追加します。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_addChildAtExample extends Sprite
    {        
        public function FlowGroupElement_addChildAtExample()
        {
            // define text strings for the contents of the text flow
            var textA:String = "It was a dark and stormy night. ";
            var textB:String = "The quick red fox jumped over the lazy brown dog. ";
            var textC:String = "Mary had a little lamb. ";
            // define TextFlow, ParagraphElement and SpanElement objects
            var textFlow:TextFlow = new TextFlow();            
            var paragraph:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var span3:SpanElement = new SpanElement();
            span1.text = textA;
            span2.text = textB;
            span3.text = textC;
            // add spans at specified positions
            paragraph.addChildAt(0, span2);
            paragraph.addChildAt(0, span1);
            paragraph.addChildAt(1, span3);
            textFlow.addChild(paragraph);
            // assign composer, controller, and update to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

findChildIndexAtPosition

()

メソッド

public function findChildIndexAtPosition(relativePosition:int):int

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

テキストの相対位置が指定されると、相対位置を含む最初の子 FlowElement のインデックスを検出します。長さがゼロの FlowElements があるため、複数の子に相対位置を含めることができます。

子を検証して、相対位置を含む FlowElement を検出します。指定された相対位置は、この FlowElement に対して相対的です。

パラメーター

relativePosition:int — このエレメントに対する相対位置

戻り値

int — relativePosition を含む最初の子エレメントのインデックス

例 ( この例の使用方法 )

この例は、テキストの相対位置にある子のインデックスを検出し、色を赤に設定します。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_findChildIndexAtPositionExample extends Sprite
    {        
        public function FlowGroupElement_findChildIndexAtPositionExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the index of the child containing relative offset 21; set color to red
            var index:int = textFlow.findChildIndexAtPosition(21);
            textFlow.getChildAt(index).color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

findLeaf

()

メソッド

public function findLeaf(relativePosition:int):FlowLeafElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

テキストの相対位置が指定されると、位置を含むリーフエレメントを検出します。

指定された位置を含む FlowLeafElement を検出するために、フローエレメントの階層を確認します。指定された位置は、この FlowElement オブジェクトに対して相対的です。

パラメーター

relativePosition:int — 検索対象の相対的なテキストインデックスです。

戻り値

FlowLeafElement — 相対位置を含むリーフエレメントです。

例 ( この例の使用方法 )

この例は、2 つの段落を作成し、55 の相対位置にある FlowLeafElement を検出して、色を赤に設定します。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_findLeafExample extends Sprite
    {        
        public function FlowGroupElement_findLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the FlowLeafElement object containing relative offset 55; set color to red
            var leaf:SpanElement = textFlow.findLeaf(55) as SpanElement;
            leaf.color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getChildAt

()

メソッド

public function getChildAt(index:int):FlowElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

指定されたインデックス位置にある子 FlowElement を返します。

パラメーター

index:int — FlowElement オブジェクトを検出する位置です。

戻り値

FlowElement — 指定された位置にある子 FlowElement オブジェクトです。

例 ( この例の使用方法 )

この例は、getChildAt() メソッドを使用し、テキストフロー内の段落にアクセスして、その範囲の 1 つの色を赤に変更します。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getChildAtExample extends Sprite
    {        
        public function FlowGroupElement_getChildAtExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // find the paragraph at index position 1
            var para:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
            // find the span at index position 1 of the paragraph and color it red
            para.getChildAt(1).color = 0xFF0000;
            // display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getChildIndex

()

メソッド

public function getChildIndex(child:FlowElement):int

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

指定された FlowElement オブジェクトの子の中を検索し、そのインデックス位置を返します。

パラメーター

child:FlowElement — 子の間に配置する必要がある FlowElement オブジェクト項目です。

戻り値

int — 指定された子のインデックス位置です。child が検出されない場合、-1 を返します。

getFirstLeaf

()

メソッド

public function getFirstLeaf():FlowLeafElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

このグループの最初の FlowLeafElement 下位要素を返します。

戻り値

FlowLeafElement — 最初の FlowLeafElement オブジェクトです。

例 ( この例の使用方法 )

この例は 2 つの段落を作成し、最初の FlowLeafElement オブジェクトを検出して、色を赤に設定します。

        
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getFirstLeafExample extends Sprite
    {        
        public function FlowGroupElement_getFirstLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a </flow:span>"+
                        "<flow:span fontStyle=\"italic\">dark and stormy</flow:span>"+
                        "<flow:span> night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // get first FlowLeafElement object and set its color to red
            var leaf:SpanElement = textFlow.getFirstLeaf() as SpanElement;
            leaf.color = 0xFF0000;
            // add composer and controller and update controller to display text
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getLastLeaf

()

メソッド

public function getLastLeaf():FlowLeafElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

このグループの最後の FlowLeafElement 下位要素を返します。

戻り値

FlowLeafElement — 最後の FlowLeafElement オブジェクトです。

例 ( この例の使用方法 )

この例は 2 つの段落を作成し、最後の FlowLeafElement オブジェクトを検出して、色を赤に設定します。

    
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_getLastLeafExample extends Sprite
    {        
        public function FlowGroupElement_getLastLeafExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night</flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a </flow:span>"+
                        "<flow:span fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,600,600));
            //find last leaf, set its color to red and display text
            var leaf:SpanElement = textFlow.getLastLeaf() as SpanElement;
            leaf.color = 0xFF0000;
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

getText

()

メソッド

override public function getText(relativeStart:int = 0, relativeEnd:int = -1, paragraphSeparator:String = " "):String

パラメーター

	`relativeStart:int` (default = `0`)

	`relativeEnd:int` (default = `-1`)

	`paragraphSeparator:String` (default = " ")

戻り値

String

removeChild

()

メソッド

public function removeChild(child:FlowElement):FlowElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

このグループから指定された子 FlowElement オブジェクトを削除します。

パラメーター

child:FlowElement — 削除する子エレメントです。

戻り値

FlowElement — 削除された子 FlowElement オブジェクト

例外

ArgumentError — child が見つかりません。

例 ( この例の使用方法 )

この例は、テキストフローの 2 段落目にある 3 つ目の範囲を削除します。

        
package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_removeChildExample extends Sprite
    {        
        public function FlowGroupElement_removeChildExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p id='para1'>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p id='para2'>"+
                        "<flow:span id='span2'>Peter Piper picked a </flow:span>"+
                        "<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span id='span4'>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,600,600));
            // get paragraph with ID = 'para2' and remove its child with name = 'span4'
            var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
            parent.removeChild(textFlow.getElementByID("span4"));
            // update controller to display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

removeChildAt

()

メソッド

public function removeChildAt(index:uint):FlowElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

指定されたインデックス位置にある子 FlowElement オブジェクトを削除します。

パラメーター

index:uint — この位置にある子エレメントを削除します。

戻り値

FlowElement — 指定した位置から削除された子 FlowElement オブジェクト

例外

RangeError — index は範囲外です。

例 ( この例の使用方法 )

この例は、removeChildAt() を呼び出して、3 つの段落のうちの 2 段落目を削除します。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_removeChildAtExample extends Sprite
    {        
        public function FlowGroupElement_removeChildAtExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p>"+
                        "<flow:span>It was a dark and stormy night. </flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Peter Piper picked a peck of pickle peppers. </flow:span>"+
                    "</flow:p>"+
                    "<flow:p>"+
                        "<flow:span>Mary had a little lamb. </flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
                    
            // define TextFlow, import text, add composer and controller 
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this,200,200));
            // remove child at index position 1 (with first position = 0); display text
            textFlow.removeChildAt(1);
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

replaceChildren

()

メソッド

public function replaceChildren(beginChildIndex:int, endChildIndex:int, ... rest):void

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

グループ内の子エレメントを指定された新規エレメントに置き換えます。beginChildIndex および endChildIndex パラメーターを使用して、次のように操作を管理します。

エレメントを削除する場合、置換エレメントを渡しません。
エレメントを挿入する場合は、beginChildIndex と endChildIndex に同じ値を渡します。新しいエレメントは、指定されたインデックスの前に挿入されます。
エレメントを追加する場合は、beginChildIndex と endChildIndex に numChildren を渡します。

他に、このメソッドは、指定されたエレメント、つまりbeginChildIndex から始まり endChildIndex の手前までのエレメントを置き換えます。

パラメーター

	`beginChildIndex:int` — 子配列の置換範囲の開始位置を表すインデックス値です。

	`endChildIndex:int` — 子配列の置換範囲の終了位置の次のインデックス値です。

	`... rest` — 指定された範囲のエレメントを置き換えるエレメントです。フローエレメントまたはそれらの配列かベクトルを含むシーケンスにできます。

例外

RangeError — 指定された beginChildIndex または endChildIndex は範囲外です。

例 ( この例の使用方法 )

この例は、2 段落目にある 3 つの範囲を、新しい 2 つの範囲に置換します。

package flashx.textLayout.elements.examples {    
    import flash.display.Sprite;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    
    public class FlowGroupElement_replaceChildrenExample extends Sprite
    {        
        public function FlowGroupElement_replaceChildrenExample()
        {
            // xml markup that defines the attributes and contents of a text flow
            var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
                "<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
                    "<flow:p id='para1'>"+
                        "<flow:span id='span1'>It was a dark and stormy night.</flow:span>"+
                    "</flow:p>"+
                    "<flow:p id='para2'>"+
                        "<flow:span id='span2'>Peter Piper picked a </flow:span>"+
                        "<flow:span id='span3' fontStyle=\"italic\"> peck </flow:span>"+
                        "<flow:span id='span4'>of pickle peppers.</flow:span>"+
                    "</flow:p>"+
                "</flow:TextFlow>";
            
            // define TextFlow object and import xml markup
            var textFlow:TextFlow = new TextFlow();
            textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
            // define two new SpanElement objects
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            span1.text = "Mary had a little lamb. ";
            span2.text = "And this little pig stayed home. ";
            // add composer and controller
            textFlow.flowComposer.addController(new ContainerController(this,200,600));
            // get paragraph with ID = 'para2' and replace its children with span1 and span2
            var parent:ParagraphElement = textFlow.getElementByID("para2") as ParagraphElement;
            parent.replaceChildren(0, 3, [span1, span2]);
            // update controller to display text
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

splitAtIndex

()

メソッド

public function splitAtIndex(childIndex:int):FlowGroupElement

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

Flash Player 10, AIR 1.5

childIndex パラメーターにより指定された位置でこのオブジェクトを分割します。このグループエレメントに親がある場合は、このオブジェクトのシャローコピーを作成して、そのすべての子をこのインデックスまでのエレメントで置き換えます。childIndex の後のエレメントをコピーに移します。

パラメーター

childIndex:int

戻り値

FlowGroupElement — 新しい FlowGroupElement オブジェクトです。

例外

RangeError — childIndex が子の長さより大きい値の場合に発生します。

法律上の注意 | プライバシーポリシー

FlowGroupElement - AS3

パッケージx

言語エレメント

付録

パッケージ flashx.textLayout.elements

mxmlChildren

numChildren