SimpleButton  - AS3

ボタンの「ダウン」状態用のビジュアルオブジェクトとして使用される表示オブジェクトを指定します。ダウン状態とは、ユーザーが hitTestState オブジェクトを選択したときのボタンの状態です。

関連する API エレメント

ボタンが有効であるか無効であるかを指定するブール値です。ボタンが無効になっているとき（enabled プロパティが false に設定されているとき）、ボタンは表示されますが、クリックできません。デフォルト値は true です。このプロパティは、ナビゲーションの一部を無効にする場合に便利です。例えば、現在表示されているページのボタンを無効にしてクリックできないようにすることで、ページのリロードを禁止できます。

注意：ボタンに対して mouseClick が発生しないようにするには、enabled プロパティと mouseEnabled プロパティの両方を false に設定します。

ボタンのヒットテストオブジェクトとして使用する表示オブジェクトを指定します。基本的なボタンでは、hitTestState プロパティを overState プロパティと同じ表示オブジェクトに設定します。hitTestState プロパティを設定しない場合、SimpleButton は非アクティブになります。つまり、ユーザー入力イベントに反応しません。

関連する API エレメント

ボタンのオーバー状態用のビジュアルオブジェクトとして使用される表示オブジェクトを指定します。オーバー状態とは、ボタンの上にポインターが置かれている状態のことです。

関連する API エレメント

このボタンに割り当てられた SoundTransform オブジェクトです。SoundTransform オブジェクトには、ボリューム、パン、左スピーカーの割り当て、および右スピーカーの割り当てを設定するプロパティが含まれます。この SoundTransform オブジェクトはボタンのすべての状態に適用されます。この SoundTransform オブジェクトは埋め込みサウンドのみに影響します。

関連する API エレメント

SimpleButton または MovieClip オブジェクトである他の表示オブジェクトがユーザー入力解放イベントを受け取ることができるかどうかを示します。trackAsMenu プロパティを使用してメニューを作成できます。trackAsMenu プロパティは、任意の SimpleButton または MovieClip オブジェクトに対して設定できます。trackAsMenu プロパティがない場合、デフォルトの動作は false です。

trackAsMenu プロパティは必要に応じていつでも変更できます。ボタンに対する変更は即座に反映されます。

ボタンのアップ状態用のビジュアルオブジェクトとして使用される表示オブジェクトを指定します。アップ状態とは、ボタンの上にポインターが置かれていない状態のことです。

関連する API エレメント

ポインターがボタン上に移動したときに、ハンドカーソルを表示するかどうかを示すブール値です。true に設定されると、ハンドカーソルを表示します。このプロパティを false に設定すると、代わりに矢印カーソルが表示されます。デフォルト値は true です。

useHandCursor プロパティは必要に応じていつでも変更できます。変更されたボタンでは新しいカーソルの動作が即座に使用されます。

新しい SimpleButton インスタンスを作成します。様々なボタンの状態を表す表示オブジェクトのいずれかまたはすべてを、コンストラクター内のパラメーターとして設定することができます。

1. SimpleButtonExample() コンストラクターで、SimpleButton タイプの新しい CustomSimpleButton オブジェクト（button と呼ばれる）が作成されます。これにより、CustomSimpleButton コンストラクターメソッドが呼び出されます。button オブジェクトが表示リストに追加されます。ボタンの色とサイズは、次の手順で決定されます。
2. CustomSimpleButton クラスで、インスタンスのプロパティが宣言されます。これらは、後に button のサイズと背景色を制御するために使われます。その制御は、ボタンの状態に基づいて行われ、通常の状態ではオレンジ、マウスポインターが置かれた状態では暗い黄色、マウスボタンが押された状態では明るい青色になります。button がどの状態にあるときでも、四角形のサイズは、size プロパティを使用して 80 ピクセルに設定されます。
3. CustomSimpleButton クラスのコンストラクター関数では、downState、overState、upState、hitTestState、および useHandCursor プロパティに ButtonDisplayState クラスの 4 つのインスタンスを設定します。
4. ButtonDisplayState クラスのコンストラクターでは、四角形のサイズと背景色の値を設定し、draw() メソッドを呼び出します。
5. draw() メソッドは、ボタンの状態に基づき、コンストラクターで設定されたサイズと背景色で四角形を再描画します。

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}