Video  - AS3

Indica il tipo di filtro applicato al decodificatore video nel corso del postprocessing. Il valore predefinito è 0, che consente al compressore video di applicare il filtro di deblock necessario.

La compressione video può determinare la comparsa di disturbi indesiderati. È possibile utilizzare la proprietà deblocking per impostare filtri che riducono il blocking e, per i video compressi con il codec On2, il ringing.

Il blocking è la presenza di imperfezioni visibili tra i limiti dei blocchi che compongono i singoli fotogrammi video. Il ringing è la presenza di bordi distorti attorno agli elementi di un'immagine video.

Sono disponibili due filtri di deblock: uno nel codec Sorenson e uno nel codec On2 VP6. È inoltre disponibile un filtro di deringing quando si utilizza il codec On2 VP6. Per impostare un filtro, utilizzate uno dei seguenti valori:

• 0 - Consente al compressore video di applicare il filtro di deblock necessario.
• 1 - Non utilizza un filtro di deblock.
• 2 - Utilizza il filtro di deblock Sorenson.
• 3 - Solo per i video On2, utilizza il filtro di deblock On2 ma non un filtro di deringing.
• 4 - Solo per i video On2, utilizza il filtro di deblock e di deringing On2.
• 5 - Solo per i video On2, utilizza il filtro di deblock On2 e un filtro di deringing On2 con prestazioni più elevate.

Se quando utilizzate il codec Sorenson selezionate un valore maggiore di 2 per il video, il decodificatore Sorenson imposta il valore predefinito 2.

L'uso del filtro di deblock incide sulle prestazioni complessive della riproduzione e di solito non è necessario per i video riprodotti con un'ampiezza di banda elevata. Se il sistema non è sufficientemente potente, l'attivazione di questo filtro può comportare delle difficoltà di riproduzione.

Specifica se il video debba essere attenuato (interpolato) quando viene modificato in scala. Affinché l'attenuazione funzioni, il runtime deve essere impostato sulla modalità di riproduzione di alta qualità (l'impostazione predefinita). Il valore predefinito è false (nessuna attenuazione).

Per la riproduzione video con Flash Player 9.0.115.0 e versioni successive, impostate questa proprietà su true per sfruttare l'ottimizzazione delle immagini in mipmapping.

Altre informazioni

Un numero intero che specifica l'altezza del flusso video espressa in pixel. Per lo streaming dal vivo, questo valore è lo stesso della proprietà Camera.height dell'oggetto Camera che sta catturando lo streaming video. Per i file video registrati, questo valore corrisponde all’altezza del video. L'evento NetStream.Video.DimensionChange viene inviato per i video registrati quando questo valore cambia.

Potete utilizzare questa proprietà, ad esempio, per fare in modo che l'utente visualizzi il video con le stesse dimensioni con cui è stato catturato, a prescindere dalle dimensioni effettive dell'oggetto Video sullo stage.

Elementi API correlati

Un numero intero che specifica la larghezza del flusso video espressa in pixel. Per i flussi dal vivo, questo valore è uguale a quello della proprietà Camera.width dell'oggetto Camera che sta catturando il flusso video. Per i file video registrati, questo valore corrisponde alla larghezza del video. L'evento NetStream.Video.DimensionChange viene inviato per i video registrati quando questo valore cambia.

Potete utilizzare questa proprietà, ad esempio, per fare in modo che l'utente visualizzi il video con le stesse dimensioni con cui è stato catturato, a prescindere dalle dimensioni effettive dell'oggetto Video sullo stage.

Elementi API correlati

Crea una nuova istanza Video. Se non vengono forniti valori per i parametri width e height, vengono utilizzati i valori predefiniti. Potete impostare le proprietà width (larghezza) e height (altezza) dell'oggetto Video anche dopo la costruzione iniziale mediante Video.width e Video.height. Quando viene creato un nuovo oggetto Video non è consentito specificare un valore zero per l'altezza o la larghezza; se viene passato il valore zero vengono applicati i valori predefiniti.

Dopo che è stato creato l'oggetto Video, chiamare il metodo DisplayObjectContainer.addChild() o DisplayObjectContainer.addChildAt() per aggiungerlo a un oggetto principale DisplayObjectContainer.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Specifica un flusso video proveniente da una videocamera da visualizzare all'interno dei limiti dell'oggetto Video nell'applicazione.

Utilizzate questo metodo per collegare video dal vivo acquisito dall'utente all'oggetto Video. Potete riprodurre il video dal vivo in locale sullo stesso computer o dispositivo su cui viene acquisito o inviarlo a Flash Media Server e utilizzare il server per inviarlo in streaming ad altri utenti.

Nota: in un'applicazione iOS AIR, le immagini video della fotocamera non vengono visualizzate se l'applicazione usa la modalità di rendering tramite GPU.

Parametri

Elementi API correlati

Specifica un flusso video da visualizzare all'interno dei limiti dell'oggetto Video nell'applicazione. Il flusso video è un file video riprodotto con NetStream.play(), un oggetto Camera o null. Se utilizzate un file video, potete salvarlo nel file system locale o in Flash Media Server. Se il valore dell'argomento netStream è null, il video non viene più riprodotto nell'oggetto Video.

Non è necessario utilizzare questo metodo se un file video contiene solo audio; la porzione audio dei file video viene riprodotta automaticamente quando chiamate NetStream.play(). Per controllare l'audio associato a un file video, utilizzate la proprietà soundTransform dell'oggetto NetStream che riproduce il file video.

Parametri

Elementi API correlati

Cancella l'immagine attualmente visualizzata nell'oggetto Video (non nel flusso video). Questo metodo è utile per la gestione dell'immagine corrente. Potete, ad esempio, cancellare l'ultima immagine o visualizzare le informazioni di standby senza nascondere l'oggetto Video.

Elementi API correlati

In questo esempio, il codice che crea gli oggetti Video e NetStream e chiama i metodi Video.attachNetStream() e NetStream.play() viene collocato in una funzione gestore. Il gestore viene chiamato solo se il tentativo di connessione all'oggetto NetConnection ha esito positivo; cioè quando l'evento netStatus restituisce un oggetto info con una proprietà code che indica l'esito positivo. È consigliabile attendere la riuscita della connessione prima di effettuare la chiamata a NetStream.play().

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }