Video  - AS3

Indica el tipo de filtro aplicado al vídeo descodificado como parte del proceso posterior. El valor predeterminado es 0, lo que permite al compresor de vídeo aplicar un filtro de desbloqueo si es necesario.

El resultado de la compresión de vídeo puede ser imprevisible. Puede utilizar la propiedad deblocking para ajustar los filtros que reducen el bloqueo y, en el caso de vídeo comprimido con el códec On2, las estelas.

Bloqueo es el término empleado para referirse a las imperfecciones visibles que aparecen entre los límites de los bloques que forman cada fotograma de vídeo. Estelas es el término empleado para referirse a los bordes distorsionados que aparecen alrededor de los elementos de una imagen de vídeo.

Hay dos filtros de desbloqueo disponibles: uno en códec Sorenson y uno en códec On2 VP6. Además, hay un filtro de reducción de estelas cuando se utiliza el códec On2 VP6. Para ajustar un filtro, utilice uno de estos valores:

• 0: permite que el compresor de vídeo aplique el filtro de desbloqueo si es preciso.
• 1: no utiliza ningún filtro de desbloqueo.
• 2: utilizar el filtro de desbloqueo Sorenson.
• 3: sólo en caso de vídeo On2, utiliza el filtro de desbloqueo de On2 pero ningún filtro de reducción de estelas.
• 4: sólo en caso de vídeo On2, utiliza el filtro de desbloqueo de On2 y el filtro de reducción de estelas.
• 5: sólo en caso de vídeo On2, utiliza el filtro de desbloqueo de On2 y un filtro de reducción de estelas de On2 de alto rendimiento.

Si se selecciona un valor superior a 2 para vídeo con el códec Sorenson, el descodificador Sorenson usa de forma predeterminada el modo 2.

El uso del filtro de desbloqueo tiene un efecto global en el rendimiento de la reproducción y normalmente no es necesario para vídeo de banda ancha. Si el sistema del usuario no es lo suficientemente potente, es posible que surjan dificultades para reproducir vídeo con un filtro de desbloqueo activado.

Especifica si el vídeo debe suavizarse (interpolarse) al ajustarlo a escala. Para que funcione el suavizado, el motor de ejecución debe estar en modo de alta calidad (modo predeterminado). El valor predeterminado es false (sin suavizado).

Para la reproducción de vídeo con Flash Player 9.0.115.0 y versiones posteriores, establezca esta propiedad en true para aprovechar la optimización de imágenes con los mapas MIP.

Un entero que especifica la altura del flujo de vídeo en píxeles. En el caso de flujos en vivo, este valor es el mismo que el de la propiedad Camera.height del objeto Camera que está capturando el flujo de vídeo. Para archivos de vídeo grabados, este valor es la altura del vídeo. El evento NetStream.Video.DimensionChange se distribuye en el caso de los vídeos grabados cuando cambia este valor.

Puede utilizar esta propiedad, por ejemplo, para asegurarse de que el usuario está viendo el vídeo con el mismo tamaño con el que se capturó, con independencia del tamaño real del objeto Video existente en el escenario.

Elementos de API relacionados

Un entero que especifica la anchura del flujo de vídeo en píxeles. En el caso de flujos en vivo, este valor es el mismo que el de la propiedad Camera.width del objeto Camera que está capturando el flujo de vídeo. Para archivos de vídeo grabados, este valor es la anchura del vídeo. El evento NetStream.Video.DimensionChange se distribuye en el caso de los vídeos grabados cuando cambia este valor.

Puede utilizar esta propiedad, por ejemplo, para asegurarse de que el usuario está viendo el vídeo con el mismo tamaño con el que se capturó, con independencia del tamaño real del objeto Video existente en el escenario.

Elementos de API relacionados

Crea una nueva instancia de Video. Si no se suministran valores para los parámetros width y height, se utilizan los valores predeterminados. También se pueden establecer las propiedades de anchura y altura del objeto Video después de la construcción inicial; para ello, utilice Video.width y Video.height. Al crear un nuevo objeto Video, no se permiten valores de cero para la anchura o la altura; si se transmite un cero, se aplicarán los valores predeterminados.

Una vez creado el objeto Video, llame al método DisplayObjectContainer.addChild() o DisplayObjectContainer.addChildAt() para añadir el objeto Video a un objeto DisplayObjectContainer principal.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Especifica una transmisión de vídeo de una cámara para que se muestre dentro de los límites del objeto Video en la aplicación.

Utilice este método para conectar vídeo en vivo capturado por el usuario al objeto Video. El vídeo en vivo se puede reproducir localmente en el mismo equipo o dispositivo en el que se está capturando o se puede enviar a Flash Media Server y utilizar el servidor para transmitirlo a otros usuarios.

Nota: en una aplicación de AIR para iOS, el vídeo de la cámara no se puede mostrar cuando la aplicación utiliza el modo de procesamiento de GPU.

Parámetros

Elementos de API relacionados

Especifica una transmisión de vídeo para que se muestre dentro de los límites del objeto Video en la aplicación. La transmisión de vídeo es un archivo de vídeo que se reproduce con NetStream.play(), un objeto Camera o null. Si utiliza un archivo de vídeo, se puede almacenar en el sistema de archivos local o en Flash Media Server. Si el valor del argumento netStream es null, el vídeo ya no se reproduce en el objeto Video.

No es necesario que utilice este método si el archivo de vídeo sólo contiene audio; la parte de audio de los archivos de vídeo se reproduce automáticamente cuando se llama a NetStream.play(). Para controlar el audio asociado a un archivo de vídeo, utilice la propiedad soundTransform del objeto NetStream que reproduzca el archivo de vídeo.

Parámetros

Elementos de API relacionados

Borra la imagen mostrada actualmente en el objeto Video (no el flujo de vídeo). Este método resulta útil para controlar la imagen actual. Por ejemplo, puede borrar la última imagen o mostrar información de espera sin tener que ocultar el objeto Video.

Elementos de API relacionados

En este ejemplo, el código que crea los objetos Video y NetStream y llama a los métodos Video.attachNetStream() y NetStream.play() se coloca en una función de controlador. Sólo se llamará al controlador si el intento de conexión con el objeto NetConnection se realiza correctamente; es decir, si el evento netStatus devuelve un objeto info con una propiedad a code que indica la realización correcta. Se recomienda que espere a establecer una conexión correcta antes de llamar a NetStream.play().

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }