| Paquete | flash.media |
| Clase | public final class SoundTransform |
| Herencia | SoundTransform  Object |
| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Elementos de API relacionados
flash.display.SimpleButton.soundTransform
flash.display.Sprite.soundTransform
flash.media.Microphone.soundTransform
flash.media.SoundChannel.soundTransform
flash.media.SoundMixer.soundTransform
flash.net.NetStream.soundTransform
flash.display.Sprite.soundTransform
flash.media.Microphone.soundTransform
flash.media.SoundChannel.soundTransform
flash.media.SoundMixer.soundTransform
flash.net.NetStream.soundTransform
Propiedades públicas
Ocultar propiedades públicas heredadas
Mostrar propiedades públicas heredadas| Propiedad | Definido por | ||
|---|---|---|---|
 | constructor : Object
Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada. | Object | |
| leftToLeft : Number
Un valor, entre 0 (ninguno) y 1 (todo), que especifica qué cantidad de datos de la izquierda se reproducen en el altavoz izquierdo. | SoundTransform | ||
| leftToRight : Number
Un valor, entre 0 (ninguno) y 1 (todo), que especifica qué cantidad de datos de la izquierda se reproducen en el altavoz derecho. | SoundTransform | ||
| pan : Number
El desplazamiento lateral del sonido, de izquierda a derecha, con valores comprendidos entre -1 (desplazamiento lateral total hacia la izquierda) y 1 (desplazamiento lateral total hacia la derecha). | SoundTransform | ||
| rightToLeft : Number
Un valor, entre 0 (ninguno) y 1 (todo), que especifica qué cantidad de datos de la derecha se reproducen en el altavoz izquierdo. | SoundTransform | ||
| rightToRight : Number
Un valor, entre 0 (ninguno) y 1 (todo), que especifica qué cantidad de datos de la derecha se reproducen en el altavoz derecho. | SoundTransform | ||
| volume : Number
El volumen, con valores comprendidos entre 0 (silencio) y 1 (máximo volumen). | SoundTransform | ||
Métodos públicos
| Método | Definido por | ||
|---|---|---|---|
Crea un objeto SoundTransform. | SoundTransform | ||
|
Indica si un objeto tiene definida una propiedad especificada. | Object | |
|
Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro. | Object | |
|
Indica si existe la propiedad especificada y si es enumerable. | Object | |
|
Establece la disponibilidad de una propiedad dinámica para operaciones de bucle. | Object | |
|
Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional. | Object | |
|
Devuelve la representación de cadena del objeto especificado. | Object | |
|
Devuelve el valor simple del objeto especificado. | Object | |
Información sobre propiedades
leftToLeft | propiedad |
leftToLeft:Number| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Un valor, entre 0 (ninguno) y 1 (todo), que especifica qué cantidad de datos de la izquierda se reproducen en el altavoz izquierdo.
Implementación
public function get leftToLeft():Number public function set leftToLeft(value:Number):voidleftToRight | propiedad |
leftToRight:Number| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Un valor, entre 0 (ninguno) y 1 (todo), que especifica qué cantidad de datos de la izquierda se reproducen en el altavoz derecho.
Implementación
public function get leftToRight():Number public function set leftToRight(value:Number):voidpan | propiedad |
pan:Number| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | AIR 1.0, Flash Player 9, Flash Lite 4 |
El desplazamiento lateral del sonido, de izquierda a derecha, con valores comprendidos entre -1 (desplazamiento lateral total hacia la izquierda) y 1 (desplazamiento lateral total hacia la derecha). Un valor de 0 indica que no hay desplazamiento lateral (existe equilibrio entre la derecha y la izquierda).
Implementación
public function get pan():Number public function set pan(value:Number):voidrightToLeft | propiedad |
rightToLeft:Number| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Un valor, entre 0 (ninguno) y 1 (todo), que especifica qué cantidad de datos de la derecha se reproducen en el altavoz izquierdo.
Implementación
public function get rightToLeft():Number public function set rightToLeft(value:Number):voidrightToRight | propiedad |
rightToRight:Number| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Un valor, entre 0 (ninguno) y 1 (todo), que especifica qué cantidad de datos de la derecha se reproducen en el altavoz derecho.
Implementación
public function get rightToRight():Number public function set rightToRight(value:Number):voidvolume | propiedad |
Información sobre constructores
SoundTransform | () | Información sobre |
public function SoundTransform(vol:Number = 1, panning:Number = 0)| Versión del lenguaje: | ActionScript 3.0 |
| Versiones de motor de ejecución: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Crea un objeto SoundTransform.
Parámetrosvol:Number (default = 1) | |
panning:Number (default = 0) |
Ejemplo ( Cómo utilizar este ejemplo )
En el ejemplo siguiente, el sonido sólo se reproduce desde el canal derecho y el volumen está definido en 50 por ciento.
En el constructor, se carga el sonido y se asigna a un canal de sonido (channel). También se crea un objeto SoundTranform (transform). Su primer argumento establece el volumen en el 50 por ciento (el rango está entre 0.0 y 1.0). Su segundo argumento establece el desplazamiento lateral. En este ejemplo, el desplazamiento se establece en 1.0, lo que significa que el sonido se emite únicamente desde el altavoz izquierdo. Para que esta configuración tenga efecto, se asigna el objeto transform SoundTranform a la propiedad souundTransform del canal de sonido.
Nota: hay una gestión de errores limitada escrita para este ejemplo.
package {
import flash.display.Sprite;
import flash.net.URLRequest;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundTransform;
import flash.events.IOErrorEvent;
public class SoundTransform_constructorExample extends Sprite
{
public function SoundTransform_constructorExample() {
var mySound:Sound = new Sound();
var url:URLRequest = new URLRequest("mySound.mp3");
var channel:SoundChannel;
var transform:SoundTransform = new SoundTransform(0.5, 1.0);
mySound.load(url);
channel = mySound.play();
channel.soundTransform = transform;
mySound.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
}
private function errorHandler(errorEvent:IOErrorEvent):void {
trace("The sound could not be loaded: " + errorEvent.text);
}
}
}
Ejemplos Cómo utilizar este ejemplo
SoundTransformExample.as
En el ejemplo siguiente, se carga y reproduce un archivo MP3. Durante la reproducción del archivo MP3, mueva el ratón o cualquier otro dispositivo de entrada de usuario; el volumen y el desplazamiento cambiarán a medida que mueva el dispositivo de entrada de usuario sobre el escenario. Para ejecutar el ejemplo, coloque un archivo llamado MySound.mp3 en el mismo directorio que el archivo SWF.
package {
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.*;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundTransform;
import flash.net.URLRequest;
import flash.utils.Timer;
public class SoundTransformExample extends Sprite {
private var url:String = "MySound.mp3";
private var soundFactory:Sound;
private var channel:SoundChannel;
private var positionTimer:Timer;
public function SoundTransformExample() {
stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;
var request:URLRequest = new URLRequest(url);
soundFactory = new Sound();
soundFactory.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
soundFactory.load(request);
channel = soundFactory.play();
stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
}
private function ioErrorHandler(event:Event):void {
trace("ioErrorHandler: " + event);
}
private function setPan(pan:Number):void {
trace("setPan: " + pan.toFixed(2));
var transform:SoundTransform = channel.soundTransform;
transform.pan = pan;
channel.soundTransform = transform;
}
private function setVolume(volume:Number):void {
trace("setVolume: " + volume.toFixed(2));
var transform:SoundTransform = channel.soundTransform;
transform.volume = volume;
channel.soundTransform = transform;
}
private function mouseMoveHandler(event:MouseEvent):void {
var halfStage:uint = Math.floor(stage.stageWidth / 2);
var xPos:uint = event.stageX;
var yPos:uint = event.stageY;
var value:Number;
var pan:Number;
if (xPos > halfStage) {
value = xPos / halfStage;
pan = value - 1;
} else if (xPos < halfStage) {
value = (xPos - halfStage) / halfStage;
pan = value;
} else {
pan = 0;
}
var volume:Number = 1 - (yPos / stage.stageHeight);
setVolume(volume);
setPan(pan);
}
}
}
Tue Jun 12 2018, 02:12 PM Z