SoundMixer  - AS3

Especifica el modo de reproducción de audio de todos los objetos Sound. En dispositivos móviles, esta propiedad establece las prioridades de sonido y los valores predeterminados según las plataformas. En entornos de escritorio y de TV, no existe ninguna diferencia funcional entre modos de reproducción de audio.

Los valores válidos de esta propiedad se definen en la clase AudioPlaybackMode.

Nota En iOS, si una aplicación define audioPlaybackMode=AudioPlaybackMode.VOICE, otras aplicaciones no puede cambiarlo a AudioPlaybackMode.MEDIA.

Haga el menor uso posible del modo AudioPlaybackMode.VOICE e intente cambiar al modo AudioPlaybackMode.MEDIA tan pronto como pueda tras la finalización de la llamada de voz para que otras aplicaciones puedan reproducirse en modo de medios.

Al cambiar el modo de reproducción de audio en iOS, las aplicaciones nativas que reproducen música se detienen brevemente.

El valor predeterminado es AudioPlaybackMode.MEDIA.

Elementos de API relacionados

El número de segundos que se tarda en precargar un flujo de sonido incorporado en un búfer antes de que comience a reproducirse. Un archivo SWF de un dominio distinto no puede acceder a los datos de un sonido cargado (incluido su tiempo de búfer) a no ser que implemente un archivo de política ente dominios. Para más información sobre la seguridad y los sonidos, consulte la descripción de la clase Sound. Un archivo de un dominio distinto no puede acceder a los datos de un sonido cargado por código (incluido su tiempo de búfer) a no ser que implemente un archivo de política ente dominios. Sin embargo, en el entorno limitado de seguridad de una aplicación de AIR, el código puede acceder a los datos de los archivos de sonido desde cualquier origen. Para más información sobre la seguridad y los sonidos, consulte la descripción de la clase Sound.

La propiedad SoundMixer.bufferTime solamente afecta al tiempo de búfer en los flujos de sonido incorporados de un archivo SWF y no tiene nada que ver con los objetos Sound creados dinámicamente (es decir, objetos Sound creados con ActionScript). El valor de SoundMixer.bufferTime no puede anular ni establecer el valor predeterminado del tiempo de búfer especificado en el objeto SoundLoaderContext que se transmite al método Sound.load().

Elementos de API relacionados

El objeto SoundTransform que controla las propiedades de sonido global. Un objeto SoundTransform incluye propiedades para establecer el volumen, el desplazamiento lateral, la asignación del altavoz izquierdo y la asignación del altavoz derecho. El objeto SoundTransform utilizado en esta propiedad proporciona una configuración de sonido final que se aplica a todos los sonidos, aunque se les haya aplicado previamente una configuración de sonido individual.

Elementos de API relacionados

Alterna el altavoz cuando el dispositivo se encuentra en modo de voz. De forma predeterminada, los smartphones utilizan el auricular el teléfono para la salida de audio si SoundMixer.audioPlaybackMode está ajustado en AudioPlaybackMode.VOICE. La propiedad useSpeakerphoneForVoice permite anular la salida predeterminada para que pueda implementar un botón de altavoces en una aplicación de teléfono. Esta propiedad no tiene ningún efecto en modos que no sean AudioPlaybackMode.VOICE. En entornos de escritorio y de TV, esta propiedad no tiene ningún efecto.

Nota En iOS, si su aplicación ha establecido audioPlaybackMode=VOICE y otra aplicación está participando también en modo de voz, no se puede establecer useSpeakerphoneForVoice=true.

Nota En Android, debe configurar android.permission.MODIFY_AUDIO_SETTINGS en el descriptor de la aplicación de AIR o cambiar este valor no tendrá ningún efecto. Además, la configuración es un ajuste global del dispositivo. Otras aplicaciones que se ejecutan en el dispositivo puede cambiar la configuración subyacente del dispositivo en cualquier momento.

El valor predeterminado es false.

Elementos de API relacionados

Determina si hay sonidos a los que no se puede acceder por restricciones de seguridad. Por ejemplo, no se podrá acceder a un sonido cargado desde un dominio distinto al del contenido que llama a este método si el servidor del sonido no contiene un archivo de política de URL que permita acceder al dominio de dicho dominio. Es posible seguir cargando y reproduciendo el sonido, pero no se pueden llevar a cabo operaciones de bajo nivel (como obtener metadatos ID3 del sonido) en sonidos inaccesibles.

En el caso del contenido de la aplicación de AIR del entorno limitado de seguridad, al llamar a este método siempre se devuelve false. Todos los sonidos, incluidos los cargados desde otros dominios, pueden acceder al contenido en el entorno limitado de seguridad de la aplicación.

Elementos de API relacionados

Toma una instantánea de la onda de sonido actual y la coloca en el objeto ByteArray especificado. Se da formato a los valores como valores de coma flotante normalizados, en el intervalo que va de -1.0 a 1.0. El objeto ByteArray transmitido al parámetro outputArray se sobrescribe con los nuevos valores. El tamaño del objeto ByteArray creado se fija en 512 valores de coma flotante, donde los primeros 256 valores representan el canal izquierdo y los otros 256 el canal derecho.

Nota: este método está sujeto a restricciones de seguridad de archivos locales y a restricciones de carga entre dominios. Si trabaja con archivos locales o con sonidos cargados desde un servidor de un dominio distinto al del contenido que llama, tal vez necesite abordar las restricciones del entorno limitado a través de un archivo de política entre dominios. Para más información, consulte la descripción de la clase Sound. Además, no se puede utilizar este método para extraer datos de flujos RTMP, aunque lo llame el contenido que reside en el mismo dominio que el servidor RTMP.

Este método se admite en RTMP en Flash Player 9.0.115.0 y versiones posteriores, y en Adobe AIR. Puede controlar el acceso a transmisiones en Flash Media Server en un script del lado del servidor. Para más información, consulte las propiedades Client.audioSampleAccess y Client.videoSampleAccess en la referencia del lenguaje ActionScript del servidor para Adobe Flash Media Server.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

Detiene todos los sonidos que se reproducen en ese momento.

>En Flash Professional, este método no detiene la cabeza lectora. Se reanudará la reproducción de los sonidos que deben transmitirse mientras la cabeza lectora se mueve sobre los fotogramas donde se encuentran.

Cuando utilice esta propiedad, puede ser conveniente usar el modelo de seguridad siguiente:

• De forma predeterminada, el método SoundMixer.stopAll() sólo detiene sonidos que se encuentren en el mismo entorno limitado de seguridad que el del objeto que llama al método. Los sonidos que no hayan comenzado a reproducirse desde el mismo entorno limitado de seguridad del objeto que llama no se detendrán.
• Al cargar el sonido con el método load() de la clase Sound, puede especificar un parámetro context, que es un objeto SoundLoaderContext. Si establece la propiedad checkPolicyFile del objeto SoundLoaderContext como true, Flash Player o Adobe AIR buscará un archivo de política entre dominios en el servidor desde el que se carga el sonido. Si el servidor contiene un archivo de política entre dominios y el archivo permite el dominio del contenido que realiza la llamada, el archivo puede detener el sonido mediante el método SoundMixer.stopAll(); en caso contrario, no puede.

Sin embargo, en Adobe AIR, el contenido del entorno limitado de seguridad de la aplicación (contenido instalado con la aplicación de AIR) no está limitado por estas restricciones de seguridad.

Para obtener más información, consulte el tema del Centro de desarrollo de Flash Player Seguridad.

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}