Sound  - AS3

Devuelve el número actual de bytes disponibles en el objeto de sonido. Esta propiedad suele ser útil únicamente en archivos cargados externamente.

Devuelve el número total de bytes de este objeto de sonido.

Proporciona acceso a los metadatos que forman parte de un archivo MP3.

Los archivos de sonido MP3 pueden contener etiquetas ID3 que proporcionan metadatos sobre el archivo. Si un sonido MP3 que se carga con el método Sound.load() contiene etiquetas ID3, puede consultar estas propiedades. Sólo se admiten las etiquetas ID3 que utilizan el conjunto de caracteres UTF-8.

En Flash Player 9 y versiones posteriores y en AIR se admiten etiquetas ID3 2.0, concretamente las versiones 2.3 y 2.4. En las tablas siguientes se muestran las etiquetas ID3 2.0 estándar y el tipo de contenido que representan. La propiedad Sound.id3 proporciona acceso a estas etiquetas mediante el formato my_sound.id3.COMM, my_sound.id3.TIME, etc. La primera tabla describe etiquetas a las que se puede acceder desde el nombre de propiedad de ID3 2.0 o desde el nombre de propiedad de ActionScript. La segunda tabla describe etiquetas ID3 admitidas, pero que no tienen propiedades predefinidas en ActionScript.

En la siguiente tabla se describen las etiquetas ID3 admitidas, pero que no tienen propiedades predefinidas la clase Sound. Se puede acceder a ellas llamando a mySound.id3.TFLT, mySound.id3.TIME, etc. NOTA: ninguna de estas etiquetas se admite en Flash Lite 4.

Cuando utilice esta propiedad, tenga en cuenta el modelo de seguridad de Flash Player:

• La propiedad id3 de un objeto Sound siempre está permitida para archivos SWF que se encuentren en el mismo entorno limitado de seguridad que el archivo de sonido. Para los archivos de otros entornos limitados existen comprobaciones de seguridad.
• Al cargar el sonido con el método load() de la clase Sound, puede especificar un parámetro context, que es un objeto SoundLoaderContext. Si establece la propiedad checkPolicyFile del objeto SoundLoaderContext como true, Flash Player comprobará la existencia de un archivo de política URL en el servidor desde el que se carga el sonido. Si existe un archivo de política y éste permite acceder desde el dominio del archivo SWF que se carga, el archivo podrá acceder a la propiedad id3 del objeto Sound; en caso contrario, no será posible.

Sin embargo, en Adobe AIR, el contenido del entorno limitado de seguridad de la aplicación (contenido instalado con la aplicación de AIR) no está limitado por estas restricciones de seguridad.

Para obtener más información, consulte el tema del Centro de desarrollo de Flash Player Seguridad.

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.media.Sound;
    import flash.net.URLRequest;
    import flash.media.ID3Info;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;

    public class Sound_id3Example extends Sprite {
        private var snd:Sound = new Sound();       
        private var myTextField:TextField = new TextField();

        public function Sound_id3Example() {
            snd.addEventListener(Event.ID3, id3Handler);
            snd.load(new URLRequest("mySound.mp3"));
        }
    
        private function id3Handler(event:Event):void {
            var id3:ID3Info = snd.id3;

            myTextField.autoSize = TextFieldAutoSize.LEFT;
            myTextField.border = true;

            myTextField.appendText("Received ID3 Info: \n");
              
            for (var propName:String in id3) {
                myTextField.appendText(propName + " = " + id3[propName] + "\n");
            }
 
            myTextField.appendText("\n" + "Artist: " + id3.artist + "\n");
            myTextField.appendText("Song name: " + id3.songName + "\n");
            myTextField.appendText("Album: " + id3.album + "\n\n"); 
 
            this.addChild(myTextField);
        }
    }
}

Devuelve el estado del búfer de archivos MP3 externos. Si el valor es true, se suspenderá cualquier reproducción activa mientras el objeto espera más datos.

Indica si se ha truncado la propiedad Sound.url. Cuando el valor de isURLInaccessible es true, el valor de Sound.url es sólo el dominio de la URL final desde la que se cargó el sonido. Por ejemplo, la propiedad se trunca si el sonido se carga desde http://www.adobe.com/assets/hello.mp3, y la propiedad Sound.url tiene el valor http://www.adobe.com. El valor de isURLInaccessible es true sólo cuando todos los siguientes también son true:

• Se ha producido una redirección HTTP mientras se cargaba el archivo de sonido.
• El archivo SWF que llama a Sound.load() procede de un dominio distinto que la URL final del archivo de sonido.
• El archivo SWF que llama a Sound.load() no tiene permiso para acceder al archivo de sonido. Se concede permiso para acceder al archivo de sonido del mismo modo que se concede permiso para la propiedad Sound.id3: estableciendo un archivo de política y utilizando la propiedad SoundLoaderContext.checkPolicyFile.

Nota: la propiedadisURLInaccessible se añadió en Flash Player 10.1 y en AIR 2.0. No obstante, esta propiedad está disponible para los archivos SWF de todas las versiones si el motro de ejecución de Flash lo admite. Así, utilizar determinadas herramientas de edición en “modo estricto” provoca un error de compilación. Para solucionar el error, utilice la sintaxis indirecta mySound["isURLInaccessible"] o desactive el modo estricto. Si utiliza Flash CS5 Professional o Flex SDK 4.1, puede usar y compilar esta API para motores de ejecución previos a Flash Player 10.1 y AIR 2.

Para contenido de la aplicación en AIR, el valor de esta propiedad siempre es false.

Elementos de API relacionados

Longitud del sonido actual, expresada en milisegundos.

La URL desde la que se cargó el sonido. Esta propiedad sólo se aplica a objetos Sound cargados con el método Sound.load(). En el caso de objetos Sound asociados a un activo de sonido de la biblioteca de un archivo SWF, el valor de la propiedad url es null.

Cuando se llama por primera vez a Sound.load(), la propiedad url tiene un valor inicial de null, ya que aún se desconoce la URL final. La propiedad url tendrá siempre un valor no nulo y cuando se distribuya un evento open desde el objeto Sound.

La propiedad url contiene la URL absoluta final desde la que se cargó el sonido. El valor de url suele coincidir con el valor transmitido al parámetro stream de Sound.load(). Sin embargo, si se transmitió una URL relativa a Sound.load(), el valor de la propiedad url representará la URL absoluta. Además, si la petición de URL original se redirige mediante un servidor HTTP, el valor de la propiedad url reflejará la URL final desde la que se descargo en realidad el archivo de sonido. Informar sobre una URL final absoluta equivale al comportamiento de LoaderInfo.url.

En algunos casos, el valor de la propiedad url se trunca; consulte la propiedad isURLInaccessible para obtener más detalles.

Elementos de API relacionados

Crea un objeto Sound nuevo. Si se transmite un objeto URLRequest válido al constructor Sound, éste llamará automáticamente a la función load() del objeto Sound. Si no se transmite ningún objeto URLRequest válido al constructor Sound, debe llamar a la función load() del objeto Sound explícitamente o el flujo no se cargará.

Una vez que se ha llamado a load() en un objeto Sound, no es posible cargar más adelante un archivo de sonido distinto en el objeto Sound. Para cargar un archivo de sonido distinto, cree un objeto Sound nuevo.

Cierra el flujo y provoca la detención de cualquier descarga de datos. No se pueden leer datos del flujo después de llamar al método close().

 
package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;    
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.errors.IOError;
    import flash.events.IOErrorEvent;

    public class Sound_closeExample extends Sprite {
        private var snd:Sound = new Sound();
        private var button:TextField = new TextField();
        private var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
        
        public function Sound_closeExample() {
            button.x = 10;
            button.y = 10;
            button.text = "START";
            button.border = true;
            button.background = true;
            button.selectable = false;
            button.autoSize = TextFieldAutoSize.LEFT;

            button.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(button);
        }

        private function clickHandler(e:MouseEvent):void {

            if(button.text == "START") {

                snd.load(req);
                snd.play();        

                snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);

                button.text = "STOP";
            }
            else if(button.text == "STOP") {
                    
                try {
                    snd.close();
                    button.text = "Wait for loaded stream to finish.";
                }
                catch (error:IOError) {
                    button.text = "Couldn't close stream " + error.message;    
                }
            }
        }
        
        private function errorHandler(event:IOErrorEvent):void {
                button.text = "Couldn't load the file " + event.text;
        }
    }
}

Extrae datos de sonido sin procesar de un objeto Sound.

Este método se ha diseñado para utilizarse cuando se trabaja con audio generado dinámicamente, utilizando una función asignada al evento sampleData para un objeto Sound diferente. Esto significa que puede utilizar este método para extraer sonido de un objeto Sound. Seguidamente, puede escribir los datos en el conjunto de bytes que otro objeto Sound esté utilizando para flujos de audio dinámico.

Los datos de audio se colocan en el conjunto de bytes de destino comenzando por la posición actual del conjunto. Los datos de audio siempre se exponen como Estéreo a 44100 Hz. El tipo de muestra es un punto flotante de 32 bits, el cual se puede convertir a un valor Number utilizando ByteArray.readFloat().

Parámetros

Elementos de API relacionados

var sourceSnd:Sound = new Sound();
var outputSnd:Sound = new Sound();
var urlReq:URLRequest = new URLRequest("test.mp3");

sourceSnd.load(urlReq);
sourceSnd.addEventListener(Event.COMPLETE, loaded);

function loaded(event:Event):void
{
    outputSnd.addEventListener(SampleDataEvent.SAMPLE_DATA, processSound);
    outputSnd.play();
}

function processSound(event:SampleDataEvent):void
{
    var bytes:ByteArray = new ByteArray();
    sourceSnd.extract(bytes, 4096);
    event.data.writeBytes(upOctave(bytes));
}

function upOctave(bytes:ByteArray):ByteArray
{
    var returnBytes:ByteArray = new ByteArray();
    bytes.position = 0;
    while(bytes.bytesAvailable > 0)
    {
        returnBytes.writeFloat(bytes.readFloat());
        returnBytes.writeFloat(bytes.readFloat());
        if (bytes.bytesAvailable > 0)
        {
            bytes.position += 8;
        }
    }
    return returnBytes;
}

Inicia la carga de un archivo MP3 externo desde la URL especificada. Si se proporciona un objeto URLRequest válido al constructor Sound, éste llamará a Sound.load() por el usuario. Sólo es necesario llamar a Sound.load() de forma explícita si no se transmite un objeto URLRequest válido al constructor Sound o se transmite un valor null.

Una vez que se ha llamado a load() en un objeto Sound, no es posible cargar más adelante un archivo de sonido distinto en el objeto Sound. Para cargar un archivo de sonido distinto, cree un objeto Sound nuevo.

Cuando utilice este método, puede ser conveniente usar el modelo de seguridad siguiente:

• No se admiten llamadas a Sound.load() si el archivo que realiza la llamada se encuentra en el entorno limitado local con el sistema de archivos y el sonido está en un entorno limitado de red.
• Para acceder desde el entorno limitado local de confianza o local con acceso a la red se necesitan permisos del sitio web a través de un archivo de política URL.
• No es posible conectar con puertos reservados comúnmente. Para obtener una lista completa de los puertos bloqueados, consulte la sección “Restricción de API de red” en el Guía del desarrollador de ActionScript 3.0.
• Se puede impedir que un archivo SWF utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.

En Flash Player 10 y versiones posteriores, si utiliza una estructura Content-Type de varias partes (por ejemplo, "multipart/form-data") con una acción de carga (indicada por un parámetro "filename" en un encabezado "content-disposition" dentro del cuerpo POST), la operación POST está sujeta a las reglas de seguridad aplicadas a las cargas:

• Es preciso realizar una operación POST como respuesta a una acción iniciada por el usuario, por ejemplo, un clic de ratón o la pulsación de una tecla.
• Si la operación POST afecta a varios dominios (el destino POST no se encuentra en el mismo servidor que el archivo SWF que envía la petición POST), el servidor de destino debe proporcionar un archivo de política URL que permita el acceso a varios dominios.

Asimismo, en cualquier estructura Content-Type de varias partes, la sintaxis debe ser válida (de acuerdo con la norma RFC2046). Si la sintaxis no es válida, la operación POST está sujeta a las reglas de seguridad que se aplican a las cargas.

En Adobe AIR, el contenido del entorno limitado de seguridad de la aplicación (contenido instalado con la aplicación de AIR) no está limitado por estas restricciones de seguridad.

Para obtener más información, consulte el tema del Centro de desarrollo de Flash Player Seguridad.

Parámetros

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.ProgressEvent;
    import flash.events.IOErrorEvent;
    
    public class Sound_loadExample extends Sprite {
        private var snd:Sound = new Sound();
        private var statusTextField:TextField  = new TextField();

        public function Sound_loadExample(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;
            var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
            snd.load(req);
            
            snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
 
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(ProgressEvent.PROGRESS, progressHandler);
                     
            this.addChild(statusTextField);
        }
    
        private function progressHandler(event:ProgressEvent):void {
            var loadTime:Number = event.bytesLoaded / event.bytesTotal;
            var LoadPercent:uint = Math.round(100 * loadTime);
              
            statusTextField.text = "Sound file's size in bytes: " + event.bytesTotal + "\n" 
                                 + "Bytes being loaded: " + event.bytesLoaded + "\n" 
                                 + "Percentage of sound file that is loaded " + LoadPercent + "%.\n";
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

carga datos de sonido MP3 de un objeto ByteArray en un objeto Sound. Los datos se leen desde la posición actual de ByteArray y deja la posición de ByteArray al final de la longitud de bytes especificada una vez terminado. Si los datos de sonido MP3 contienen datos ID3, se distribuirán eventos ID3 durante esta llamada a la función. Esta función emitirá una excepción si el objeto ByteArray no contiene suficientes datos.

Parámetros

Carga datos de sonido de coma flotante PCM de 32 bits de un objeto ByteArray en un objeto Sound. Los datos se leen desde la posición actual de ByteArray y la posición de ByteArray queda al final de la longitud de muestra especificada, multiplicada por 1 o 2 canales si después de terminar se establece el indicador estéreo.

A partir de Flash Player 11.8, se ha limitado la cantidad de datos de audio que pueden pasar a esta función. Para versiones de SWF >= 21, esta función emite una excepción si la cantidad de datos de audio pasados a ella es superior a 1800 segundos. Es decir, el valor de muestras/frecuencia de muestreo debería ser igual o inferior a 1800. En versiones de SWF < 21, se produce un error silencioso del motor de ejecución si la cantidad de datos de audio pasados supera los 12000 segundos. Esto solo sirve para compatibilidad con versiones anteriores.

Esta función produce una excepción si el objeto ByteArray no contiene suficientes datos.

Parámetros

Genera un nuevo objeto SoundChannel para reproducir el sonido. Este método devuelve un objeto SoundChannel al que se accede para detener el sonido y supervisar el volumen. (Para controlar el volumen, el desplazamiento lateral y el balance, acceda al objeto SoundTransform asignado al canal de sonido.)

Parámetros

Elementos de API relacionados

 
package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;
    import flash.media.Sound;;
    import flash.net.URLRequest;
    import flash.media.SoundChannel;
    import flash.events.ProgressEvent;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample1 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel = new SoundChannel();
        private var infoTextField:TextField = new TextField();
    
        public function Sound_playExample1() {

            var req:URLRequest = new URLRequest("MySound.mp3");
            
            infoTextField.autoSize = TextFieldAutoSize.LEFT;
            infoTextField.text = "Please wait for the file to be loaded.\n" 
                                + "Then select from the bar to decide where the file should start.";
            
            snd.load(req);               
            channel = snd.play();

            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(Event.COMPLETE, completeHandler);


            this.addChild(infoTextField);
        }

        private function completeHandler(event:Event):void {                
            infoTextField.text = "File is ready.";

            var bar:Sprite = new Sprite();

            bar.graphics.lineStyle(5, 0xFF0000);
            bar.graphics.moveTo(100, 100);
            bar.graphics.lineTo(200, 100);

            bar.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(bar);
        }
    
        private function clickHandler(event:MouseEvent):void {
            
                var position:uint = event.localX;
                var percent:uint = Math.round(position) - 100;   
                var cue:uint = (percent / 100) * snd.length;

                channel.stop();
                channel = snd.play(cue);    
        }

        private function errorHandler(errorEvent:IOErrorEvent):void {
            infoTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.media.Sound;
    import flash.net.URLRequest;

    public class Sound_playExample2 extends Sprite {
        private var button:Sprite = new Sprite(); 
        private var snd:Sound = new Sound();
            
        public function Sound_playExample2() {

            var req:URLRequest = new URLRequest("click.mp3");
            snd.load(req);               
     
            button.graphics.beginFill(0x00FF00);
            button.graphics.drawRect(10, 10, 50, 30);
            button.graphics.endFill();
     
            button.addEventListener(MouseEvent.CLICK, clickHandler);
            button.addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
     
            this.addChild(button);
        }

        private function clickHandler(event:MouseEvent):void {
            snd.play();            
        }

        private function doubleClickHandler(event:MouseEvent):void {
            snd.play(0, 2);        
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample3 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel;
        private var statusTextField:TextField  = new TextField();

        public function Sound_playExample3(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;

           var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
                snd.load(req);
            
                channel = snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
                    
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            addEventListener(Event.ENTER_FRAME, enterFrameHandler);
            channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
                    
            this.addChild(statusTextField);
        }
    
        private function enterFrameHandler(event:Event):void {    
            var loadTime:Number = snd.bytesLoaded / snd.bytesTotal;
            var loadPercent:uint = Math.round(100 * loadTime);
            var estimatedLength:int = Math.ceil(snd.length / (loadTime));
            var playbackPercent:uint = Math.round(100 * (channel.position / estimatedLength));
      
            statusTextField.text = "Sound file's size is " + snd.bytesTotal + " bytes.\n" 
                                   + "Bytes being loaded: " + snd.bytesLoaded + "\n" 
                                   + "Percentage of sound file that is loaded " + loadPercent + "%.\n"
                                   + "Sound playback is " + playbackPercent + "% complete.";     
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }

        private function soundCompleteHandler(event:Event):void {
            statusTextField.text = "The sound has finished playing.";
            removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }
    }
}

Se distribuye cuando los datos se han cargado correctamente.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Distribuido por un objeto Sound cuando hay datos ID3 disponibles para un sonido MP3.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando se produce un error de entrada o salida que provoca que una operación de carga se realice incorrectamente.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando se inicia la operación de carga.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye al recibirse datos mientras progresa una operación de carga.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando el motor de ejecución solicita nuevos datos de audio.

Este evento tiene las propiedades siguientes:

var mySound:Sound = new Sound();
function sineWaveGenerator(event:SampleDataEvent):void {
    for ( var c:int=0; c<8192; c++ ) {
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
    }
}

mySound.addEventListener(SampleDataEvent.SAMPLE_DATA,sineWaveGenerator);
mySound.play();

Elementos de API relacionados