URLRequest  - AS3

Especifica si deben manejarse peticiones de autenticación (true) o no (false) en esta petición. Si es false, el intento de autenticación devuelve un error HTTP.

Los métodos de autenticación admitidos son:

• Windows: HTTP Basic/Digest, Autenticación integrada de Windows (incluido NTLM y Kerberos), Autenticación de certificado SSL.
• Mac: HTTP Basic/Digest, NTLM, Autenticación de certificado SSL.

Nota: los métodos FileReference.upload(), FileReference.download() y HTMLLoader.load() no admiten la propiedad URLRequest.authenticate.

El valor predeterminado es true.

Elementos de API relacionados

Especifica si los datos correctos de respuesta de esta petición se deben guardar en la memoria caché. Si se establece en true, la aplicación de AIR utiliza la caché HTTP del sistema operativo.

Nota: el método HTMLLoader.load() no admite la propiedad URLRequest.cacheResponse.

El valor predeterminado es true.

Elementos de API relacionados

El tipo de contenido MIME del contenido de la propiedad data.

El valor predeterminado es application/x-www-form-urlencoded.

Nota: los métodos FileReference.upload(), FileReference.download() y HTMLLoader.load() no admiten la propiedad URLRequest.contentType.

Cuando se envía una petición POST, los valores de las propiedades contentType y data deben corresponderse correctamente. El valor de la propiedad contentType informa a los servidores cómo interpretar el valor de la propiedad data.

• Si el valor de la propiedad data es un objeto URLVariables, el valor de contentType debe ser application/x-www-form-urlencoded.
• Si el valor de la propiedad data es de cualquier otro tipo, el valor de contentType debe indicar el tipo de datos POST que se envían (datos binarios o de cadena en el valor de la propiedad data).
• En FileReference.upload(), el tipo de contenido de la petición se define automáticamente como multipart/form-data, y el valor de la propiedad contentType se omite.

En Flash Player 10 y versiones posteriores, si utiliza una estructura Content-Type de varias partes (por ejemplo, "multipart/form-data") con una acción de carga (indicada por un parámetro "filename" en un encabezado "content-disposition" dentro del cuerpo POST), la operación POST está sujeta a las reglas de seguridad aplicadas a las cargas:

• Es preciso realizar una operación POST como respuesta a una acción iniciada por el usuario, por ejemplo, un clic de ratón o la pulsación de una tecla.
• Si la operación POST afecta a varios dominios (el destino POST no se encuentra en el mismo servidor que el archivo SWF que envía la petición POST), el servidor de destino debe proporcionar un archivo de política URL que permita el acceso a varios dominios.

Asimismo, en cualquier estructura Content-Type de varias partes, la sintaxis debe ser válida (de acuerdo con la norma RFC2046). Si la sintaxis no es válida, la operación POST está sujeta a las reglas de seguridad que se aplican a las cargas.

Elementos de API relacionados

Un objeto que contiene datos que se van a transmitir con la petición de URL.

Esta propiedad se utiliza junto con la propiedad method. Si el valor de method es GET, el valor de data se añade al valor de URLRequest.url, utilizando la sintaxis de cadena de consulta HTTP. Si el valor de method es POST (o cualquier valor distinto a GET), el valor de data se transmite en el cuerpo de la petición HTTP.

La API URLRequest ofrece compatibilidad POST binaria y admite variables con codificación URL, así como compatibilidad con cadenas. El objeto de datos puede ser un objeto ByteArray, URLVariables o String.

El modo en que se utilicen los datos dependerá del tipo de objeto empleado:

• Si el objeto es ByteArray, los datos binarios del objeto ByteArray se utilizan como datos POST. En el caso de GET, no se admiten los datos de tipo ByteArray. Asimismo, los datos de tipo ByteArray no con compatibles con FileReference.upload() y FileReference.download().
• Si el objeto es URLVariables y el método es POST, las variables se codifican con formato x-www-form-urlencoded y la cadena resultante se utiliza como datos POST. Una excepción es la llamada a FileReference.upload(), en la que las variables se envían como campos separados en un envío multipart/form-data.
• Si el objeto es URLVariables y el método GET, el objeto URLVariables define las variables que se enviarán con el objeto URLRequest.
• En caso contrario, el objeto se convierte en una cadena y ésta se utiliza como datos POST o GET.

Los datos no se envían hasta que un método (por ejemplo, navigateToURL() o FileReference.upload()) utilice el objeto URLRequest.

Nota: el valor de contentType debe corresponder al tipo de datos en la propiedad data. Consulte la nota en la descripción de la propiedad contentType.

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Una cadena que identifica de forma unívoca el componente firmado de la plataforma de Adobe que se va a almacenar (o recuperar) en la caché de Flash Player. Un componente de plataforma de Adobe es un archivo firmado (un archivo SWZ) con contenido SWF almacenado de forma persistente en la caché en el equipo de un usuario. Todos los archivos SWZ están firmados por Adobe. Una propiedad digest corresponde a un solo archivo guardado en caché; si se realiza cualquier cambio en el archivo, su propiedad digest cambiará de forma imprevisible. Mediante la propiedad digest es posible verificar el archivo guardado en caché en varios dominios. Dos archivos con la misma propiedad digest son el mismo archivo y dos archivos con distintas propiedades digest no son el mismo archivo. En la práctica , no se puede crear un archivo para “imitar” a las propiedades digest para hacerse pasar por otras.

La propiedad digest está basada en un algoritmo de resumen de mensajes SHA-256 (longitud de 64 caracteres en formato hexadecimal).

Por ejemplo, el SDK de Flex incluye un archivo SWZ para la arquitectura de Flex (y proporciona la cadena digest para dicho archivo SWZ). Puede publicar este archivo SWZ en el servidor web y cargarlo en el archivo SWF (con el método load() de un objeto URLLoader). Si el equipo del usuario final ya contiene el archivo SWZ coincidente en la caché, la aplicación utilizará dicho archivo SWZ. (Un archivo SWZ es coincidente si su propiedad digest coincide con la suministrada por el usuario.) En caso contrario, la aplicación descarga el archivo SWZ desde la dirección URL que se especifique.

Sólo se establece el parámetro digest en un objeto URLRequest utilizado en una llamada al método URLLoader.load() para cargar un archivo SWZ. Si la propiedad digest de un objeto URLRequest se establece cuando se utiliza en otros métodos, la aplicación emite una excepción IOError.

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

Especifica si se seguirán las redirecciones (true) o no (false).

Nota: los métodos FileReference.upload(), FileReference.download() y HTMLLoader.load() no admiten la propiedad URLRequest.followRedirects.

El valor predeterminado es true.

Elementos de API relacionados

Especifica el valor de tiempo espera de inactividad (en milisegundos) en esta petición.

El tiempo espera de inactividad es el tiempo que cliente espera una respuesta del servidor, una vez establecida la conexión, antes de abandonar la petición.

Nota: el método HTMLLoader.load() no admite la propiedad URLRequest.idleTimeout. La clase HTMLLoader define su propia propiedad idleTimeout.

El valor predeterminado es initialized from the URLRequestDefaults.idleTimeout property.

Elementos de API relacionados

Especifica si la pila del protocolo HTTP debe administrar las cookies de esta petición. Si es true, las cookies se agregan a la petición y se recuerdan las cookies de la respuesta. Si es false, las cookies no se agregan a la petición y no se recuerdan, pero se pueden autoadministrar manipulando directamente los encabezados. Nota: en Windows, no es posible añadir cookies para una petición de URL manualmente cuando manageCookies se establece en true. En otros sistemas operativos, añadir las cookies con una petición es permitida independientemente de que manageCookies se establezca en true o false. Si está permitido, puede añadir las cookies a una petición manualmente agregando un objeto URLRequestHeader que contenga la cookie al conjunto requestHeaders.

En Mac OS, las cookies se comparten con Safari. Para borrar las cookies de Mac OS:

1. Abra Safari.
2. Seleccione Safari > Preferencias y haga clic en el panel Seguridad.
3. Pulse el botón Mostrar cookies.
4. Haga clic en Eliminar todo.

Para borrar las cookies en Windows:

1. En el panel de control Propiedades de Internet, haga clic en la ficha General.
2. Haga clic en el botón Eliminar cookies.

El valor predeterminado es true.

Elementos de API relacionados

Controla el formulario HTTP para el método de envío.

Para el contenido SWF que se ejecuta en Flash Player (en el navegador), esta propiedad está limitada a las operaciones GET o POST, y los valores válidos son URLRequestMethod.GET o URLRequestMethod.POST.

Para el contenido que se ejecuta en Adobe AIR, puede utilizar cualquier valor de cadena si el contenido se encuentra en el entorno limitado de seguridad de la aplicación. Por el contrario, cuando el contenido se ejecuta en Flash Player, está limitado al uso de las operaciones GET o POST.

Para contenido ejecutado en Adobe AIR, cuando utiliza la función navigateToURL(), el motor de ejecución trata un URLRequest que utiliza el método POST (uno con su propiedad method establecida en URLRequestMethod.POST ) como lo haría con el método GET.

Nota: si la ejecución se produce en Flash Player y el formulario al que se hace referencia no tiene cuerpo, Flash Player utiliza automáticamente una operación GET, aunque el método se defina como URLRequestMethod.POST. Por este motivo, se recomienda incluir siempre un cuerpo “inactivo” para garantizar que se utilice el método correcto.

El valor predeterminado es URLRequestMethod.GET.

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

El conjunto de encabezados de petición HTTP que se añadirán a la petición HTTP. El conjunto está formado por objetos URLRequestHeader. Cada objeto del conjunto debe ser un objeto URLRequestHeader que contenga una cadena de nombre y de valor, del modo siguiente:

     var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
     

Flash Player y el tiempo de ejecución de AIR imponen determinadas restricciones en los encabezados de solicitud. Para obtener más información, consulte la descripción de la clase URLRequestHeader.

No todos los métodos que aceptan los parámetros URLRequest admiten la propiedad requestHeaders; consulte la documentación del método que vaya a llamar. Por ejemplo, los métodos FileReference.upload() y FileReference.download() no admiten la propiedad URLRequest.requestHeaders.

Debido a las limitaciones del navegador, los encabezados de petición HTTP personalizados sólo se admiten para peticiones POST y no para peticiones GET.

Elementos de API relacionados

La URL que se va a solicitar.

Es importante codificar todos los caracteres descritos como no seguros en la especificación del localizador uniforme de recursos (consulte http://www.faqs.org/rfcs/rfc1738.html) o reservados en el esquema de URL del objeto URLRequest (cuando no se utilizan para su finalidad reservada). Por ejemplo, utilice "%25" como símbolo de porcentaje (%) y "%23" como signo del número (#), como a continuación "http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25".

De forma predeterminada, la URL debe estar en el mismo dominio que el archivo que realiza la llamada, a no ser que el contenido se ejecute en el entorno limitado de seguridad de la aplicación de Adobe AIR. Si necesita cargar datos desde un dominio distinto, sitúe un archivo de política URL en el servidor que aloja los datos. Para obtener más información, consulte la descripción de la clase URLRequest.

Para el contenido que se ejecuta en Adobe AIR, los archivos del entorno limitado de seguridad de la aplicación (archivos instalados con la aplicación AIR) pueden acceder a las URL mediante cualquiera de los siguientes esquemas de URL:

• http y https
• file
• app-storage
• app

Nota: IPv6 (Protocolo de Internet, versión 6) se admite en AIR y en Flash Player 9.0.115.0 y versiones posteriores. IPv6 es una versión del Protocolo de Internet que admite direcciones de 128 bits (una mejora con respecto al protocolo anterior IPv4 que admite direcciones de 32 bits). Es posible que tenga que activar IPv6 en sus interfaces de red. Para más información, consulte la Ayuda del sistema operativo que aloja los datos. Si se admite IPv6 en el sistema de host, puede especificar direcciones literales numéricas de IPv6 en las URL entre corchetes ([]), tal y como se muestra a continuación .

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.load(urlRequest);
addChild(loader);

Especifica si se debe consultar la memoria caché local antes de que URLRequest tome los datos.

Nota: el método HTMLLoader.load() no admite la propiedad URLRequest.useCache.

El valor predeterminado es true.

Elementos de API relacionados

Especifica la cadena de agente de usuario que se utiliza en la petición HTTP.

El valor predeterminado es la misma cadena de agente de usuario que utiliza Flash Player. Esta cadena no es la misma en Mac, Linux y en Windows.

Nota: esta propiedad no afecta a la cadena de agente de usuario si el objeto URLRequest object se utiliza con el método load() de un objeto HTMLLoader. Para definir la cadena de agente de usaurio de un objeto HTMLLoader, establezca la propiedad userAgent del objeto HTMLLoader o defina la propiedad estática URLRequestDefaults.userAgent.

Elementos de API relacionados

Crea un objeto URLRequest. Si System.useCodePage es true, la solicitud se codifica con la página de códigos del sistema y no con Unicode. Si System.useCodePage es false, la solicitud se codifica con Unicode, y no con la página de códigos del sistema.

Elementos de API relacionados

// Requires
// - Button symbol on Stage (or a display object, such as a MovieClip) with instance name "buttonSymbol"
//
buttonSymbol.addEventListener(MouseEvent.CLICK, buttonSymbol_click);
 
function buttonSymbol_click(evt:MouseEvent):void {
    var req:URLRequest = new URLRequest("http://www.adobe.com/");
    navigateToURL(req, "_blank");
}

Permite la sustitución de una URL redirigida desde un objeto URLRequest de origen por alguna parte de la URL en un objeto URLRequest nuevo. Una vez que se haya redirigido una solicitud inicial, esto permite que se envíen solicitudes posteriores directamente a la ubicación de redirección del servidor.

Una vez que el objeto URLRequest inicial haya finalizado, si HTTPStatusEvent.redirected es true, este método se puede invocar con la solicitud inicial como sourcerequest. De forma predeterminada, se utilizará el dominio de la URL redirigida en lugar del dominio de la URL del objeto URLRequest. Se debe establecer URLRequest.url antes de llamar a este método. El método se debe invocar antes de que se cargue el objeto URLRequest. Opcionalmente, si el parámetro wholeURL es true, se sustituirá la URL completa (a excepción del nombre de archivo) del objeto URLRequest de origen por la URL completa sin el nombre final de archivo de este objeto URLRequest. Además, quien realice la llamada puede proporcionar, de manera opcional, una cadena o expresión regular en el parámetro pattern. Se busca el patrón y se sustituye por la cadena del parámetro replace. La búsqueda y el reemplazo se llevan a cabo después de la sustitución de la URL.

Parámetros

Elementos de API relacionados

Para ejecutar el ejemplo, coloque un archivo llamado XMLFile.xml en el mismo directorio que el archivo SWF.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}