URLLoader  - AS3

Indica el número de bytes cargados hasta ese momento durante la operación de carga.

Indica el número total de bytes de los datos descargados. Esta propiedad contiene 0 si la operación de carga está en curso y se llena cuando la operación ha finalizado. Asimismo, un encabezado Content-Length que falte dará como resultado que bytesTotal sea indeterminado.

Los datos recibidos de la operación de carga. Esta propiedad se llena únicamente al finalizar la operación de carga. El formato de los datos depende del establecimiento de la propiedad dataFormat:

Si la propiedad dataFormat es URLLoaderDataFormat.TEXT, los datos recibidos son una cadena con el texto del archivo cargado.

Si la propiedad dataFormat es URLLoaderDataFormat.BINARY, los datos recibidos son un objeto ByteArray con los datos binarios sin formato.

Si la propiedad dataFormat es URLLoaderDataFormat.VARIABLES, los datos recibidos son un objeto URLVariables con las variables con codificación URL.

Elementos de API relacionados

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

Controla si los datos cargados se reciben como texto (URLLoaderDataFormat.TEXT), como datos binarios sin formato (URLLoaderDataFormat.BINARY) o como variables con codificación URL (URLLoaderDataFormat.VARIABLES).

Si el valor de la propiedad dataFormat es URLLoaderDataFormat.TEXT, los datos recibidos son una cadena con el texto del archivo cargado.

Si el valor de la propiedad dataFormat es URLLoaderDataFormat.BINARY, los datos recibidos son un objeto ByteArray con los datos binarios sin formato.

Si el valor de la propiedad dataFormat es URLLoaderDataFormat.VARIABLES, los datos recibidos son un objeto URLVariables con las variables con codificación URL.

El valor predeterminado es URLLoaderDataFormat.TEXT.

Elementos de API relacionados

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

Crea un objeto URLLoader.

Elementos de API relacionados

Registra un objeto de detector de eventos con un objeto EventDispatcher, de modo que el detector reciba la notificación de un evento. Puede registrar detectores de eventos en todos los nodos de la lista de visualización para un tipo concreto de evento, fase y prioridad.

Una vez registrado correctamente un detector de eventos, no puede cambiar su prioridad mediante llamadas adicionales a addEventListener(). Para cambiar la prioridad de un detector, en primer lugar debe llamar a removeListener(). Seguidamente, puede volver a registrar el nuevo nivel de prioridad.

Recuerde que, una vez registrado el detector, las siguientes llamadas a addEventListener() con un valor type o useCapture distinto tendrán como resultado la creación de un registro independiente del detector. Por ejemplo, si registra primero un detector con useCapture definido como true, detectará únicamente durante la fase de captura. Si vuelve a llamar a addEventListener() con el mismo objeto detector, pero con useCapture definido como false, tendrá dos detectores independientes: uno que detecta durante la fase de captura y otro que lo hace durante las fases de destino y de propagación.

No es posible registrar un detector de eventos únicamente para la fase de destino o la fase de propagación. Dichas fases se acoplan durante el registro, ya que la propagación sólo se aplica a los ascendientes del nodo de destino.

Si ya no necesita ningún detector de eventos, elimínelo llamando a removeEventListener(); de lo contrario, podrían surgir problemas de memoria. Los detectores de eventos no se eliminan automáticamente de la memoria, ya que el recolector de datos innecesarios no elimina el detector siempre que el objeto distribuido exista (a no ser que el parámetro useWeakReference se establezca en true).

Al copiar una instancia EventDispatcher no se copian los detectores de eventos asociados. (Si el nodo recién creado necesita un detector de eventos, debe asociarlo después de crear el nodo.) Sin embargo, si mueve una instancia EventDispatcher, los detectores de eventos asociados se moverán también.

Si el detector de eventos se registra en un nodo mientras se procesa un evento en dicho nodo, el detector de eventos no se desencadenará durante la fase actual, aunque sí se desencadenará en una fase posterior del flujo del evento, por ejemplo, en la fase de propagación.

Si un detector de eventos se elimina de un nodo mientras se procesa un evento en dicho nodo, las acciones actual seguirán desencadenándolo. Una vez eliminado, el detector de eventos ya no se vuelve a invocar nunca más (a no ser que se registre de nuevo para otro proceso).

Parámetros

function(evt:Event):void

Cierra la operación de carga en curso. Se detendrá inmediatamente cualquier operación de carga en curso. Si no se transmite ninguna URL en ese momento, se emitirá un error de transmisión no válida.

Envía y carga datos desde la URL especificada. Los datos se pueden recibir como texto, como datos binarios sin formato o como variables con codificación, en función del valor establecido para la propiedad dataFormat. Tenga en cuenta que el valor predeterminado de la propiedad dataFormat es text. Si quiere enviar datos a la URL especificada, puede establecer la propiedad data en el objeto URLRequest.

Nota: si un archivo que se está cargando contiene caracteres no ASCII (como ocurre en muchos idiomas, no así en inglés), se recomienda que guarde el archivo con codificación UTF-8 o UTF-16, en lugar de utilizar un formato no Unicode, como ASCII.

Es posible que un archivo SWF del entorno limitado local-con-sistema-de-archivos no cargue ni proporcione datos a un recurso que se encuentre en el entorno limitado de red.

De forma predeterminada, el archivo SWF que realiza la llamada y la URL que se carga deben estar exactamente en el mismo dominio. Por ejemplo, un archivo SWF de www.adobe.com puede cargar datos únicamente de orígenes que también estén en www.adobe.com. Para cargar datos desde un dominio distinto, coloque un archivo de política URL en el servidor que aloja los datos.

No es posible conectar con puertos reservados comúnmente. Para obtener una lista completa de los puertos bloqueados, consulte la sección “Restricción de API de red” en el Guía del desarrollador de ActionScript 3.0.

En Flash Player 10 y versiones posteriores, si utiliza una estructura Content-Type de varias partes (por ejemplo, "multipart/form-data") con una acción de carga (indicada por un parámetro "filename" en un encabezado "content-disposition" dentro del cuerpo POST), la operación POST está sujeta a las reglas de seguridad aplicadas a las cargas:

• Es preciso realizar una operación POST como respuesta a una acción iniciada por el usuario, por ejemplo, un clic de ratón o la pulsación de una tecla.
• Si la operación POST afecta a varios dominios (el destino POST no se encuentra en el mismo servidor que el archivo SWF que envía la petición POST), el servidor de destino debe proporcionar un archivo de política URL que permita el acceso a varios dominios.

Asimismo, en cualquier estructura Content-Type de varias partes, la sintaxis debe ser válida (de acuerdo con la norma RFC2046). Si la sintaxis no es válida, la operación POST está sujeta a las reglas de seguridad que se aplican a las cargas.

Para obtener más información, consulte el tema del Centro de desarrollo de Flash Player Seguridad.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Se distribuye tras decodificar y colocar todos los datos recibidos en la propiedad data del objeto URLLoader. Es posible acceder a los datos recibidos una vez distribuido este evento.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye si una llamada al método load() intenta acceder a los datos mediante HTTP y Adobe AIR puede detectar y devolver el código de estado de la petición.

La constante HTTPStatusEvent.HTTP_RESPONSE_STATUS define el valor de la propiedad type de un objeto de evento httpResponseStatus.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye si una llamada al método URLLoader.load() intenta acceder a los datos mediante HTTP. Para contenido ejecutado en Flash Player, este evento sólo se distribuye si el entorno actual de Flash Player puede detectar y devolver el código de estado de la petición. (Es posible que algunos entornos de navegador no proporcionen esta información.) Tenga en cuenta que se enviará el evento httpStatus (si existe) antes que (y además de) cualquier evento complete o error.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye si el resultado de una llamada a URLLoader.load() es un error grave que hace que la descarga finalice.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando se inicia la operación de descarga tras una llamada al método URLLoader.load().

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye al recibirse datos mientras progresa una operación de descarga.

Tenga en cuenta que con un objeto URLLoader no es posible acceder a los datos hasta que no se reciben por completo. Por tanto, el evento de progreso únicamente sirve de notificación para saber qué grado de progreso ha alcanzado la descarga. Para acceder a los datos antes de que se descarguen por completo, utilice un objeto URLStream.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye si se intenta llamar a URLLoader.load() para cargar datos de un servidor situado fuera del entorno limitado de seguridad. También se distribuye si una llamada a URLLoader.load() intenta cargar un archivo SWZ y el certificado no es válido, o si la cadena digest no coincide con el componente.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Nota: para ejecutar este ejemplo, coloque un archivo llamado urlLoaderExample.txt en el mismo directorio que el archivo SWF. Dicho archivo debe contener únicamente la siguiente línea de texto: answer=42&question=unknown

El código de ejemplo cumple las siguientes funciones:

1. La función constructora crea una instancia de URLLoader llamada loader y una instancia de URLRequest request, que contiene la ubicación y el nombre del archivo que se va a cargar.
2. El objeto loader se transfiere al método configureListeners(), que añade detectores para cada uno de los eventos URLLoader admitidos.
3. Posteriormente, el objeto request se transfiere a loader.load(), que carga el archivo de texto.
4. Cuando URLLoader finaliza la carga del archivo de texto, se activa el evento Event.COMPLETE, que activa el método completeHandler(). El método completeHandler() crea variables de URLVariables a partir del texto cargado desde el archivo. El objeto URLVariables convierte los pares nombre/valor con codificación URL en propiedades de ActionScript para facilitar la manipulación de los datos cargados.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}