FileReference  - AS3

La fecha de creación del archivo en el disco local. Si aún no se ha llenado el objeto , una llamada para obtener el valor de esta propiedad devolverá null.

Nota: Si un sistema operativo no tiene creationDate como su propiedad, en estos casos, CreationDate es igual a lastModifiedDate.

Elementos de API relacionados

Tipo de creador de Macintosh del archivo; sólo se utiliza en versiones de Mac OS anteriores a Mac OS X. En Windows o Linux, esta propiedad es null. Si aún no se ha llenado el objeto FileReference, una llamada para obtener el valor de esta propiedad devolverá null.

Elementos de API relacionados

El objeto ByteArray que representa los datos del archivo cargado tras una llamada correcta al método load().

Elementos de API relacionados

Extensión del nombre de archivo.

La extensión de un archivo es la parte del nombre situada a la derecha del punto final ("."), sin incluirlo. Si el nombre de archivo no tiene ningún punto, la extensión es null.

Nota: debe utilizar la propiedad extension para determinar el tipo de un archivo; no utilice las propiedades creator o type. A efectos prácticos, debería considerar las propiedades creator y type como desfasadas. Sólo se aplican a versiones antiguas de Mac OS.

La última fecha de modificación del archivo en el disco local. Si aún no se ha llenado el objeto FileReference, una llamada para obtener el valor de esta propiedad devolverá null.

Elementos de API relacionados

El nombre del archivo en el disco local. Si el objeto FileReference no se llenó (mediante una llamada válida a FileReference.download() o a FileReference.browse()), Flash Player emitirá un error al intentar obtener el valor de esta propiedad.

Al llamar al método browse() se llenan todas las propiedades de un objeto FileReference. A diferencia de otras propiedades FileReference, si llama al método download(), la propiedad name se llena cuando se distribuye el evento select.

Elementos de API relacionados

Determine si se le ha concedido a la aplicación el permiso para acceder al sistema de archivos.

Elementos de API relacionados

El tamaño del archivo en el disco local, expresado en bytes.

Nota: en la versión inicial de ActionScript 3.0, la propiedad size se definía como un objeto uint compatible con archivos de hasta 4 GB de tamaño. Ahora se ha implementado como un objeto Number para admitir archivos de mayor tamaño.

Elementos de API relacionados

El tipo de archivo.

En Windows o Linux, esta propiedad es la extensión del archivo. En Macintosh, esta propiedad es de tipos de archivos de cuatro caracteres, que sólo se utilizan en versiones de Mac OS anteriores a Mac OS X. Si el objeto FileReference no se llenó, la llamada para obtener el valor de esta propiedad devuelve null.

En Windows, en Linux y en Mac OS X, la extensión del archivo (la parte de la propiedad name que va a la derecha del punto (.)) identifica el tipo de archivo.

Elementos de API relacionados

Crea un nuevo objeto FileReference. Cuando está lleno, un objeto FileReference representa un archivo en el disco local del usuario.

Elementos de API relacionados

Muestra un cuadro de diálogo de búsqueda de archivos en el que el usuario puede seleccionar un archivo para la carga. El cuadro de diálogo depende del sistema operativo del usuario. El usuario puede seleccionar un archivo del equipo local o de otros sistemas, por ejemplo, a través de una ruta UNC en Windows.

Nota: la clase File, disponible en Adobe AIR, incluye métodos para acceder a cuadros de diálogo de selección de archivos del sistema más específicos. Estos métodos son File.browseForDirectory(), File.browseForOpen(), File.browseForOpenMultiple() y File.browseForSave().

Cuando se llama a este método y el usuario selecciona correctamente un archivo, las propiedades de este objeto FileReference se llenan con las propiedades de dicho archivo. Posteriormente, cada vez que se llama a al método FileReference.browse(), las propiedades del objeto FileReference se restablecen según el archivo seleccionado por el usuario en el cuadro de diálogo. Sólo se puede realizar una sesión browse() o download() cada vez (porque no se pueden invocar varios cuadros de diálogo de forma simultánea).

Con el parámetro typeFilter, se puede determinar qué archivos se mostrarán en el cuadro de diálogo.

En la actualización 5 de Flash Player 10 y Flash Player 9, es posible llamar correctamente a este método sólo como respuesta a un evento de usuario (por ejemplo, en un controlador de eventos de clic de ratón o de pulsación de tecla). En caso contrario, al llamar a este método Flash Player emite una excepción Error.

Tenga en cuenta que, debido a la nueva funcionalidad añadida a Flash Player, cuando se publica en Flash Player 10, sólo es posible activar una de las siguientes operaciones cada vez: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). En caso contrario, Flash Player emite un error de tiempo de ejecución (código 2174). Utilice FileReference.cancel() para detener una operación en curso. Esta restricción sólo se aplica a Flash Player 10. Las versiones anteriores de Flash Player no se ven afectadas por esta restricción de múltiples operaciones simultáneas.

En Adobe AIR, el diálogo de búsqueda de archivos no se muestra siempre delante de las ventanas que son “propiedad” de otra ventana (ventanas cuya propiedad owner no sea null). Para evitar problemas de ordenación de ventanas, oculte las ventanas pertenecientes antes de llamar a este método.

Parámetros

Elementos de API relacionados

Cancela la operación de carga o descarga en curso en este objeto FileReference. Al llamar a este método no se distribuye el evento cancel; dicho evento se distribuye sólo cuando el usuario cancela la operación cerrando el cuadro de diálogo de carga o de descarga de archivos.

Abre un cuadro de diálogo que permite al usuario descargar un archivo desde un servidor remoto. Aunque Flash Player no tiene restricciones con respecto al tamaño de los archivos que pueden cargarse y descargarse, oficialmente el reproductor admite cargas y descargas de un máximo de 100 MB.

Este método download() abre en primer lugar un cuadro de diálogo del sistema operativo que pide al usuario que introduzca un nombre de archivo y seleccione una ubicación en el equipo local para guardar el archivo. Cuando el usuario selecciona una ubicación y confirma la operación de descarga (por ejemplo, haciendo clic en Guardar), comienza la descarga del servidor remoto. Los detectores reciben eventos para indicar el progreso, el éxito o un error en la descarga. Para comprobar el estado del cuadro de diálogo y la operación de descarga después de llamar a download(), el código deberá detectar eventos como cancel, open, progress y complete.

Las funciones FileReference.upload() y FileReference.download() no son bloqueantes. Estas funciones se devuelven después de la llamada y antes de que finalice la transmisión del archivo. Además, si el objeto FileReference va más allá del ámbito, se cancelará cualquier carga o descarga que no haya finalizado en dicho objeto. Es importante que el objeto FileReference permanezca dentro del ámbito durante todo el tiempo de carga y descarga.

Una vez descargado el archivo correctamente, las propiedades del objeto FileReference se llenan con las propiedades del archivo local. Se distribuye el evento complete si la descarga se realiza correctamente.

Sólo se puede realizar una sesión browse() o download() cada vez (porque no se pueden invocar varios cuadros de diálogo de forma simultánea).

Este método admite la descarga de cualquier tipo de archivo, con HTTP o HTTPS.

No es posible conectar con puertos reservados comúnmente. Para obtener una lista completa de los puertos bloqueados, consulte la sección “Restricción de API de red” en el Guía del desarrollador de ActionScript 3.0.

Nota: si el servidor requiere autenticación del usuario, sólo los archivos que se ejecutan en un navegador, es decir que utilizan el plug-in de navegador o controles ActiveX, pueden mostrar un cuadro de diálogo para pedir al usuario un nombre de usuario y una contraseña para la autenticación, y sólo para las descargas. La transferencia de archivos fallará en las cargas que utilicen el plug-in o el control ActiveX, y en las cargas y descargas que utilicen el reproductor autónomo o externo.

Cuando utilice este método, tenga en cuenta el modelo de seguridad de Flash Player:

• No se admiten operaciones de carga si el archivo SWF que realiza la llamada está en un entorno limitado local que no es de confianza.
• El comportamiento predeterminado es denegar el acceso entre entornos limitados. Un sitio web puede activar el acceso a un recurso agregando un archivo de política URL.
• Asimismo, se puede impedir que un archivo SWF utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.
• En la actualización 5 de Flash Player 10 y Flash Player 9, es posible llamar correctamente a este método sólo como respuesta a un evento de usuario (por ejemplo, en un controlador de eventos de clic de ratón o de pulsación de tecla). En caso contrario, al llamar a este método Flash Player emite una excepción Error.

Sin embargo, en Adobe AIR, el contenido del entorno limitado de seguridad de la aplicación (contenido instalado con la aplicación de AIR) no está limitado por estas restricciones de seguridad.

Para obtener más información, consulte el tema del Centro de desarrollo de Flash Player Seguridad.

Cuando se descarga un archivo con este método, se marca como descargado en sistemas operativos que marcan los archivos descargados:

• Windows XP Service Pack 2 y posterior, y en Windows Vista
• Mac OS 10.5 y versiones posteriores

Algunos sistemas operativos, como Linux, no marcan los archivos descargados.

Tenga en cuenta que, debido a la nueva funcionalidad añadida a Flash Player, cuando se publica en Flash Player 10, sólo es posible activar una de las siguientes operaciones cada vez: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). En caso contrario, Flash Player emite un error de tiempo de ejecución (código 2174). Utilice FileReference.cancel() para detener una operación en curso. Esta restricción sólo se aplica a Flash Player 10. Las versiones anteriores de Flash Player no se ven afectadas por esta restricción de múltiples operaciones simultáneas.

En Adobe AIR, el diálogo de descarga no se muestra siempre delante de las ventanas que son “propiedad” de otra ventana (ventanas cuya propiedad owner no sea null). Para evitar problemas de ordenación de ventanas, oculte las ventanas pertenecientes antes de llamar a este método.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Inicia la carga de un archivo local seleccionado por un usuario. Aunque Flash Player no tiene restricciones con respecto al tamaño de los archivos que pueden cargarse, descargarse o guardarse, oficialmente admite tamaños de hasta 100 MB. Para contenido ejecutado en Flash Player, debe llamar al método FileReference.browse() o FileReferenceList.browse() antes de llamar al método load(). Sin embargo, el contenido ejecutado en AIR en el entorno limitado de la aplicación puede llamar al método load() de un objeto File sin llamar primero al método browse(). (La clase File de AIR amplía la clase FileReference.)

Los detectores reciben eventos para indicar el progreso, éxito o error en la carga. Aunque se puede utilizar el objeto FileReferenceList para que los usuarios puedan seleccionar varios archivos para cargar, se deben cargar de uno en uno. Para cargar los archivos de uno en uno, itere el conjunto FileReferenceList.fileList de objetos FileReference.

Adobe AIR también incluye la clase FileStream que proporciona más opciones para leer archivos.

Las funciones FileReference.upload(), FileReference.download(), FileReference.load() y FileReference.save() son no bloqueantes. Estas funciones se devuelven después de la llamada y antes de que finalice la transmisión del archivo. Además, si el objeto FileReference va más allá del ámbito, se cancelará cualquier transacción que no haya finalizado en dicho objeto. Es importante que el objeto FileReference permanezca dentro del ámbito durante todo el tiempo de carga, descarga y grabación.

Si el archivo finaliza la carga correctamente, su contenido se guarda como un conjunto de bytes en la propiedad data del objeto FileReference.

Se deben tener en cuenta las siguientes consideraciones de seguridad:

• No se admiten operaciones de carga si el archivo SWF que realiza la llamada está en un entorno limitado local que no es de confianza.
• El comportamiento predeterminado es denegar el acceso entre entornos limitados. Un sitio web puede activar el acceso a un recurso utilizando un archivo de política de varios dominios.
• Asimismo, se puede impedir que un archivo utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.

No obstante, estas consideraciones no se aplican a contenido de AIR en el entorno limitado de la aplicación.

Tenga en cuenta que al publicar en Flash Player 10 o en AIR 1.5, sólo puede tener una de las siguientes operaciones activas al mismo tiempo: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). En caso contrario, la aplicación emite un error de tiempo de ejecución (código 2174). Utilice FileReference.cancel() para detener una operación en curso. Esta restricción se aplica sólo a Flash Player 10 y AIR 1.5. Las versiones anteriores de Flash Player o de AIR no se ven afectadas por la restricción en operaciones simultáneas.

En Adobe AIR, el diálogo de búsqueda de archivos no se muestra siempre delante de las ventanas que son “propiedad” de otra ventana (ventanas cuya propiedad owner no sea null). Para evitar problemas de ordenación de ventanas, oculte las ventanas pertenecientes antes de llamar a este método.

Elementos de API relacionados

var buttonShape:Shape = new Shape();
buttonShape.graphics.beginFill(0x336699);
buttonShape.graphics.drawCircle(50, 50, 25);
var button = new SimpleButton(buttonShape, buttonShape, buttonShape, buttonShape);
addChild(button);

var fileRef:FileReference= new FileReference();
button.addEventListener(MouseEvent.CLICK, onButtonClick);

function onButtonClick(e:MouseEvent):void {
fileRef.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);
fileRef.addEventListener(Event.SELECT, onFileSelected);
}

function onFileSelected(e:Event):void {
fileRef.addEventListener(Event.COMPLETE, onFileLoaded);
fileRef.load();
}

function onFileLoaded(e:Event):void {
var loader:Loader = new Loader();
loader.loadBytes(e.target.data);
addChild(loader);
}

Solicita permiso para acceder al sistema de archivos.

Abre un cuadro de diálogo que permite al usuario guardar un archivo en el sistema de archivos local. Aunque Flash Player no tiene restricciones con respecto al tamaño de los archivos que pueden cargarse, descargarse o guardarse, oficialmente el reproductor admite tamaños de hasta 100 MB.

Este método save() abre en primer lugar un cuadro de diálogo del sistema operativo que pide al usuario que introduzca un nombre de archivo y seleccione una ubicación en el equipo local para guardar el archivo. Cuando el usuario selecciona una ubicación y confirma la operación de grabación (por ejemplo, haciendo clic en Guardar), se inicia el proceso de grabación. Los detectores reciben eventos para indicar el progreso, éxito o error en la operación de grabación. Para comprobar el estado del cuadro de diálogo y la operación de grabación después de llamar a save(), el código deberá detectar eventos como cancel, open, progress y complete.

Adobe AIR también incluye la clase FileStream que proporciona más opciones para guardar archivos localmente.

Las funciones FileReference.upload(), FileReference.download(), FileReference.load() y FileReference.save() son no bloqueantes. Estas funciones se devuelven después de la llamada y antes de que finalice la transmisión del archivo. Además, si el objeto FileReference va más allá del ámbito, se cancelará cualquier transacción que no haya finalizado en dicho objeto. Es importante que el objeto FileReference permanezca dentro del ámbito durante todo el tiempo de carga, descarga y grabación.

Una vez guardado correctamente el archivo, las propiedades del objeto FileReference se llenan con las propiedades del archivo local. Se distribuye el evento complete si la grabación se realiza correctamente.

Sólo se puede realizar una sesión browse() o save() cada vez (porque no se pueden invocar varios cuadros de diálogo de forma simultánea).

En Flash Player es posible llamar correctamente a este método sólo como respuesta a un evento de usuario (por ejemplo, en un controlador de eventos de clic de ratón o de pulsación de tecla). En caso contrario, al llamar a este método Flash Player emite una excepción Error. Esta restricción no está presente en el contenido de AIR en el entorno limitado de la aplicación.

En Adobe AIR, el diálogo para guardar no se muestra siempre delante de las ventanas que son “propiedad” de otra ventana (ventanas cuya propiedad owner no sea null). Para evitar problemas de ordenación de ventanas, oculte las ventanas pertenecientes antes de llamar a este método.

Parámetros

Elementos de API relacionados

var MyTextField:TextField = new TextField();
var MyButtonField:TextField = new TextField();
var MyFile:FileReference = new FileReference();

MyTextField.border = true;
MyTextField.type = TextFieldType.INPUT;

MyButtonField.background = true;
MyButtonField.backgroundColor = 0x339933;
MyButtonField.x = 150;
MyButtonField.height = 20;
MyButtonField.text = "Click here to save";

addChild(MyTextField);
addChild(MyButtonField);
MyButtonField.addEventListener(MouseEvent.CLICK, clickhandler);

function clickhandler(e:MouseEvent): void {
    MyFile.save(MyTextField.text);
}

Inicia la carga de un archivo en un servidor remoto. Aunque Flash Player no tiene restricciones con respecto al tamaño de los archivos que pueden cargarse y descargarse, oficialmente el reproductor admite cargas y descargas de un máximo de 100 MB. Se debe llamar al método FileReference.browse() o FileReferenceList.browse() para poder llamar a este método.

Para información sobre la clase File de Adobe AIR, que amplía la clase FileReference, puede utilizar el método upload() para cargar cualquier archivo. Para información sobre la la clase FileReference (utilizada en Flash Player), el usuario debe primero seleccionar un archivo.

Los detectores reciben eventos para indicar el progreso, éxito o error en la carga. Aunque se puede utilizar el objeto FileReferenceList para que los usuarios puedan seleccionar varios archivos para la carga, éstos se deben cargar de uno en uno; para ello, itere por el conjunto FileReferenceList.fileList de objetos FileReference.

Las funciones FileReference.upload() y FileReference.download() no son bloqueantes. Estas funciones se devuelven después de la llamada y antes de que finalice la transmisión del archivo. Además, si el objeto FileReference va más allá del ámbito, se cancelará cualquier carga o descarga que no haya finalizado en dicho objeto. Es importante que el objeto FileReference permanezca dentro del ámbito durante todo el tiempo de carga y descarga.

El archivo se carga en la URL pasada en el parámetro url. La URL debe ser un script de servidor configurado para aceptar cargas. Flash Player carga archivos mediante el método HTTP POST. El script de servidor que gestiona la carga espera una petición POST con los siguientes elementos:

• Content-Type de multipart/form-data
• Un elemento Content-Disposition con un atributo name establecido de forma predeterminada como "Filedata" y un atributo filename establecido como el nombre del archivo original.
• El contenido binario del archivo.

No es posible conectar con puertos reservados comúnmente. Para obtener una lista completa de los puertos bloqueados, consulte la sección “Restricción de API de red” en el Guía del desarrollador de ActionScript 3.0.

Para consultar una petición POST de ejemplo, consulte la descripción del parámetro uploadDataFieldName. Se pueden enviar parámetros POST o GET al servidor con el método upload(); consulte la descripción del parámetro request.

Si el parámetro testUpload es true, y el tamaño del archivo que se va a cargar supera los 10 KB, Flash Player (en Windows) primero envía una operación POST de carga de prueba sin contenido antes de cargar el archivo real. De esta forma, se verifica si la transmisión será correcta. A continuación, Flash Player envía una segunda operación POST que incluye el contenido del archivo real. En el caso de archivos con tamaño inferior a 10 KB, Flash Player lleva a cabo una sola operación POST de carga con el contenido del archivo real. En Macintosh, Flash Player no lleva a cabo ninguna operación POST de carga de prueba.

Nota: si el servidor requiere autenticación del usuario, sólo los archivos que se ejecutan en un navegador, es decir que utilizan el plug-in de navegador o controles ActiveX, pueden mostrar un cuadro de diálogo para pedir al usuario un nombre de usuario y una contraseña para la autenticación, y sólo para las descargas. La transferencia de archivos fallará en las cargas que utilicen el plug-in o el control ActiveX, y en las cargas y descargas que utilicen el reproductor autónomo o externo.

Cuando utilice este método, tenga en cuenta el modelo de seguridad de Flash Player:

• No se admiten operaciones de carga si el archivo SWF que realiza la llamada está en un entorno limitado local que no es de confianza.
• El comportamiento predeterminado es denegar el acceso entre entornos limitados. Un sitio web puede activar el acceso a un recurso agregando un archivo de política URL.
• Asimismo, se puede impedir que un archivo SWF utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.

Sin embargo, en Adobe AIR, el contenido del entorno limitado de seguridad de la aplicación (contenido instalado con la aplicación de AIR) no está limitado por estas restricciones de seguridad.

Para obtener más información, consulte el tema del Centro de desarrollo de Flash Player Seguridad.

Tenga en cuenta que, debido a la nueva funcionalidad añadida a Flash Player, cuando se publica en Flash Player 10, sólo es posible activar una de las siguientes operaciones cada vez: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). En caso contrario, Flash Player emite un error de tiempo de ejecución (código 2174). Utilice FileReference.cancel() para detener una operación en curso. Esta restricción sólo se aplica a Flash Player 10. Las versiones anteriores de Flash Player no se ven afectadas por esta restricción de múltiples operaciones simultáneas.

Parámetros

    Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x-- 
    

Elementos de API relacionados

Inicia la carga de un archivo en una URL sin codificación. Mientras que el método upload() codifica el archivo con envoltura de datos de formulario, el método uploadUnencoded(), por su parte, transfiere el contenido del archivo tal cual en el cuerpo de la petición HTTP. Utilice el método uploadUnencoded() si los datos que quiere enviar ya están codificados en un formato comprensible para el servidor de recepción. Normalmente, el método uploadeUnencoded() se utiliza con el método HTTP/WebDAV PUT.

Parámetros

Elementos de API relacionados

Se distribuye cuando el usuario cancela la carga o descarga de un archivo mediante el cuadro de diálogo de búsqueda de archivos. Flash Player no distribuye este evento si el usuario cancela una carga o descarga mediante otros métodos (cerrando el navegador o la aplicación actual).

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Se distribuye cuando finaliza la descarga o cuando la carga genera un código de estado HTTP de 200. En el caso de la descarga de archivos, se distribuye cuando Flash Player o de Adobe AIR finaliza la descarga del archivo completo en el disco. En el caso de la carga de archivos, este evento se distribuye después de que Flash Player o Adobe AIR hayan recibido un código de estado HTTP de 200 desde el servidor que recibe la transmisión.

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Elementos de API relacionados

Se distribuye si una llamada a los métodos upload() o uploadUnencoded() intenta acceder a los datos mediante HTTP y Adobe AIR puede detectar y devolver el código de estado de la petición.

La constante HTTPStatusEvent.HTTP_RESPONSE_STATUS define el valor de la propiedad type de un objeto de evento httpResponseStatus.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando la carga falla y hay un código de estado HTTP disponible para describir el error. El evento httpStatus siempre se distribuye, seguido de un evento ioError.

El evento httpStatus se distribuye sólo cuando se producen errores de carga. Para contenido ejecutado en Flash Player, este evento no se aplica a errores de descarga. Si falla una descarga debido a un error HTTP, el error se transmite como error de E/S.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando falla la carga o la descarga. La transferencia de archivos puede fallar por uno de los siguientes motivos:

• Se produce un error de entrada/salida durante la lectura, escritura o transmisión del archivo.
• El archivo SWF intenta cargar un archivo en un servidor que requiere autenticación, como un nombre de usuario y contraseña. Durante la carga, Flash Player o Adobe AIR no proporcionan un medio para que los usuarios introduzcan contraseñas. Si un archivo SWF intenta cargar un archivo en un servidor que requiere autenticación, se produce un error en la carga.
• El archivo SWF intenta descargar un archivo desde un servidor que requiere autenticación, en el reproductor autónomo o externo. Durante la descarga, los reproductores autónomos y externos no proporcionan un medio para que los usuarios introduzcan contraseñas. Si un archivo SWF de estos reproductores intenta descargar un archivo en un servidor que requiere autenticación, se produce un error en la descarga. La descarga de archivos se realizará correctamente sólo en el control ActiveX, en los reproductores de plug-in del navegador y en el motor de ejecución de Adobe AIR.
• El valor transferido al parámetro url en el método upload() contiene un protocolo no válido. Los protocolos válidos son HTTP y HTTPS.

Importante: sólo las aplicaciones que se ejecutan en un navegador, es decir, que emplean el plug-in del navegador o un control ActiveX y cuyo contenido se ejecuta en Adobe AIR, pueden mostrar un cuadro de diálogo para solicitar al usuario que indique un nombre de usuario y contraseña para la autenticación y, además, sólo para descargas. La transferencia de archivos fallará en las cargas que utilicen el plug-in o la versión del control ActiveX de Flash Player, y en las cargas y descargas que utilicen el reproductor autónomo o externo.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando se inicia una operación de carga o descarga.

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Elementos de API relacionados

Se distribuye cuando la aplicación pide permiso para acceder al sistema de archivos. Compruebe el valor del estado de la propiedad para determinar si el permiso se ha concedido o denegado

Elementos de API relacionados

Se distribuye periódicamente durante la operación de carga o descarga de archivos. El evento progress se distribuye mientras Flash Player transmite bytes a un servidor y se distribuye de forma periódica durante la transmisión, aunque no finalice correctamente. Para determinar si la transmisión realmente es correcta y completa, detecte el evento complete.

En algunos casos, no se reciben eventos progress. Por ejemplo, si el archivo que se transmite es muy pequeño o si la carga o la descarga se producen muy rápido, es posible que no se distribuya un evento progress.

El progreso de carga de archivos no puede determinarse en plataformas Macintosh anteriores a OS X 10.3. Durante la operación de carga, se llama al evento progress, pero el valor de la propiedad bytesLoaded del evento de progreso es -1, lo que indica que no es posible determinar el progreso.

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Elementos de API relacionados

Se distribuye cuando una llamada al método FileReference.upload() o FileReference.download() intenta cargar un archivo en un servidor u obtener un archivo de un servidor que se encuentra fuera del entorno limitado de seguridad del elemento que realiza la llamada. El valor de la propiedad de texto que describe el error específico ocurrido suele ser "securitySandboxError". Es posible que el archivo SWF que realiza la llamada haya intentado acceder a un archivo SWF fuera de su dominio y no tenga permiso para hacerlo. Puede intentar solucionar este error utilizando un archivo de política URL.

En Adobe AIR, estas restricciones de seguridad no se aplican al contenido del entorno limitado de seguridad de la aplicación.

En Adobe AIR, estas restricciones de seguridad no se aplican al contenido del entorno limitado de seguridad de la aplicación.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando el usuario selecciona un archivo para la carga o descarga en el cuadro de diálogo de búsqueda de archivos. (Este cuadro de diálogo se abre cuando llama a los métodos FileReference.browse(), FileReferenceList.browse() o FileReference.download().) Cuando el usuario selecciona un archivo y confirma la operación (por ejemplo, haciendo clic en Aceptar), se llenan las propiedades del objeto FileReference.

Para contenido ejecutado en Flash Player o fuera del entorno limitado de seguridad de la aplicación en el motor de ejecución de Adobe AIR, el comportamiento del evento select cambia ligeramente en función del método que lo invoque. Cuando se distribuye el evento select después de una llamada a browse(), Flash Player o la aplicación de AIR pueden leer todas las propiedades del objeto FileReference, ya que el archivo seleccionado por el usuario está en el sistema de archivos local. Cuando se distribuye el evento select después de una llamada a download(), Flash Player o la aplicación de AIR sólo pueden leer la propiedad name, debido a que el archivo no se ha descargado todavía en el sistema local de archivos en el momento de distribuir el evento select. Una vez que se haya descargado el archivo y se haya distribuido el evento complete, Flash Player o la aplicación de AIR pueden leer todas las demás propiedades del objeto FileReference.

Este evento tiene las propiedades siguientes:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Se distribuye cuando se han recibido datos del servidor tras una carga correcta. Este evento no se distribuye si no se devuelven datos desde el servidor.

Este evento tiene las propiedades siguientes:

Nota: para ejecutar este ejemplo, cambie la propiedad uploadURL.url para que señale a una URL real, y no a la URL ficticia del ejemplo. La URL debe señalar a un archivo llamado yourUploadHandlerScript.cfm en el directorio raíz web de la URL especificada. Según la configuración, también podría ser necesario compilar el archivo SWF con la opción Seguridad de reproducción local establecida como Acceder sólo a la red o actualizar la configuración de seguridad de Flash Player para que permita el acceso de este archivo a la red.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}