File  - AS3

Carpeta que contiene los archivos instalados con la aplicación.

La propiedad url de este objeto utiliza el esquema de URL storage (no el esquema de URL file). Esto significa que la cadena url se especifica comenzando por "app:" (no por "file:"). Asimismo, si se crea un objeto File relativo al directorio File.applicationDirectory (con el método resolvePath()), la propiedad url del objeto File también utiliza el esquema de URL app.

Nota: no es posible escribir en archivos o directorios que tengan rutas con el esquema de URL app. Tampoco se pueden eliminar o crear archivos o carpetas con rutas que utilicen el esquema de URL app. Modificar el contenido en el directorio de la aplicación es una mala práctica, por razones de seguridad, y está bloqueada por el sistema operativo en algunas plataformas. Si quiere almacenar datos específicos de las aplicaciones, utilice el directorio de almacenamiento de la aplicación (File.applicationStorageDirectory). Si quiere obtener ese contenido (en el directorio de almacenamiento de la aplicación) para tener acceso a funciones de la aplicación con privilegios (API de AIR), puede acceder a dicha funcionalidad mediante un puente de entorno limitado.

La propiedad applicationDirectory permite hacer referencia al directorio de la aplicación de forma que funcione en todas las plataformas. Si establece un objeto File para que haga referencia al directorio de la aplicación con la propiedad nativePath o url, sólo funcionará correctamente en la plataforma para la que dicha ruta sea válida.

En Android, la propiedad nativePath de un objeto File que apunta al directorio de la aplicación es una cadena vacía. Utilice la propiedad url para acceder a los archivos de la aplicación.

Elementos de API relacionados

El directorio de almacenamiento privado de la aplicación.

Cada aplicación de AIR tiene un directorio exclusivo de almacenamiento persistente de la aplicación que se crea al acceder a File.applicationStorageDirectory por primera vez. Este directorio es exclusivo para cada aplicación y usuario. El directorio es una ubicación adecuada para almacenar datos específicos de la aplicación o del usuario.

Al desinstalar una aplicación de AIR, si el programa de desinstalación elimina el directorio de almacenamiento de la aplicación y sus archivos depende de la plataforma.

La propiedad url de este objeto utiliza el esquema de URL app-storage (no el esquema de URL file). Esto significa que la cadena url se especifica comenzando por "app-storage:" (no por "file:"). Asimismo, si se crea un objeto File relativo al directorio File.applicationStoreDirectory (con el método resolvePath()), la url del objeto File también utiliza el esquema de URL app-storage URL (como en el ejemplo).

La propiedad applicationStorageDirectory permite hacer referencia al directorio de almacenamiento de la aplicación de forma que funcione en todas las plataformas. Si establece un objeto File para que haga referencia al directorio de almacenamiento de la aplicación con la propiedad nativePath o url, sólo funcionará correctamente en la plataforma para la que dicha ruta sea válida.

Nota (solo Mac OS): para cumplir con los requisitos del App Store de Apple, la ubicación física de este directorio cambia entre AIR 3.2 y AIR 3.3:

• Espacio de nombres 3.2 y anterior: ~/Library/Preferences/appid/Local Store/
• Espacio de nombres 3.3 y posterior: ruta de acceso/Library/Application Support/appid/Local Store/, donde ruta de acceso es ~/Library/Containers/bundle-id/Data (dentro de un entorno limitado de seguridad) o ~ (si se ejecuta fuera del entorno limitado de seguridad)

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

El directorio de memoria caché de la aplicación.

La propiedad cacheDirectory permite hacer referencia al directorio de caché. La aplicación debería usar el directorio de caché para almacenar archivos descargados de un servidor o que se pueden volver a generar. Ejemplos de archivos que podrían guardarse en el directorio de caché son archivos de caché de base de datos y contenido descargable, como el usado en aplicaciones de mapas, revistas y periódicos.

Si establece un objeto File para que haga referencia al directorio de memoria caché con la propiedad nativePath o url, solo funcionará correctamente en plataformas para las que dicha ruta sea válida.

Si el sistema operativo no admite un directorio de caché, cacheDirectory tiene valor null

Directorio del escritorio del usuario.

La propiedad desktopDirectory permite hacer referencia al directorio del escritorio de forma que funcione en todas las plataformas. Si establece un objeto File para que haga referencia al directorio del escritorio con la propiedad nativePath o url, sólo funcionará correctamente en la plataforma para la que dicha ruta sea válida.

Si un sistema operativo no admite un directorio del escritorio, se utiliza en su lugar un directorio que se encuentre en el sistema de archivos.

Los dispositivos de AIR para TV no tienen el concepto de un directorio del escritorio del usuario. Por ello, la propiedad desktopDirectory hace referencia a la misma ubicación de directorio que la propiedad File.userDirectory. El directorio de usuarios es exclusivo de la aplicación.

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

El directorio de documentos del usuario.

En Windows es el directorio Mis documentos (por ejemplo, C:\Documents and Settings\NombreUsuario\Mis documentos). En Mac OS, la ubicación predeterminada es /Usuarios/Usuario/Documentos. En Linux, la ubicación predeterminada es /home/nombreUsuario/Documents (en un sistema operativo en inglés), y la propiedad sigue la configuración de xdg-user-dirs.

La propiedad documentsDirectory permite hacer referencia al directorio de documentos de forma que funcione en todas las plataformas. Si establece un objeto File para que haga referencia al directorio de documentos con la propiedad nativePath o url, sólo funcionará correctamente en la plataforma para la que dicha ruta sea válida.

Si un sistema operativo no admite un directorio de documentos, se utiliza en su lugar un directorio que se encuentre en el sistema de archivos.

Los dispositivos de AIR para TV no tienen el concepto de un directorio de documentos del usuario. Por ello, la propiedad documentsDirectory hace referencia a la misma ubicación de directorio que la propiedad File.userDirectory. El directorio de usuarios es exclusivo de la aplicación.

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Indica si el archivo o directorio al que se hace referencia se ha descargado (de Internet) o no.

Esta propiedad sólo es significativa en sistemas operativos en los que se pueden identificar archivos descargados:

• Windows XP Service Pack 2 y posterior, y en Windows Vista
• Mac OS 10.5 y versiones posteriores

En los sistemas que tienen archivos identificados como descargados, como es el caso de Linux, la propiedad no es significativa (y se establece como false).

Elementos de API relacionados

Indica si existe el archivo o directorio al que se hace referencia. El valor es true si el objeto File apunta a un archivo o directorio existente; en caso contrario, el valor es false.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Un objeto Icon que contiene los iconos definidos para el archivo. Un objeto Icon es un conjunto de objetos BitmapData correspondientes a los distintos estados del icono. En Linux, el objeto Icon no contiene iconos. En Android, la propiedad icon es null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Indica si se hace referencia a un directorio. El valor es true si el objeto File apunta a un directorio; en caso contrario, el valor es false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Indica si el archivo o directorio al que se hace referencia está "oculto". El valor es true si el archivo o directorio al que se hace referencia está oculto; en caso contrario, el valor es false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Indica si el directorio al que hace referencia es un paquete.

El valor es true si el directorio al que se hace referencia es un paquete; en caso contrario, el valor es false. Tenga en cuenta que la clase File no permite crear paquetes directamente.

• En Mac OS, los directorios se pueden asignar como paquetes y se muestran en el Finder como un solo archivo, no como un directorio. Esta propiedad se establece como true si el directorio al que hace referencia es un paquete; devuelve false si el archivo no es un directorio, si no existe o si no es un paquete.
• En otros sistemas operativos, la propiedad siempre se establece como false.

Indica si la referencia es un vínculo simbólico.

El valor es true si el objeto File apunta a un vínculo simbólico; en caso contrario, el valor es false. Tenga en cuenta que la clase File no permite crear vínculos simbólicos directamente.

Los vínculos simbólicos permiten que un archivo apunte a otro archivo o directorio del disco. Aunque son parecidos, los vínculos simbólicos no son lo mismo que los alias de Mac OS o los accesos directos de Windows. Un alias o un acceso directo siempre se considera un archivo (no un directorio), y leer o escribir en un alias o en un acceso directo nunca afecta al archivo o directorio original al que apunta. Por otro lado, un vínculo simbólico se comporta generalmente como el archivo o directorio al que apunta. Se puede notificar como archivo o directorio, y la lectura o escritura en un vínculo simbólico afecta al archivo o directorio al que apunta y no al propio vínculo simbólico. Al eliminar un enlace simbólico, se borra el enlace, no el destino del enlace.

Mac^® OS^®, Linux y Windows^® Vista^® admiten enlaces simbólicos. Además, en Windows, la propiedad isSymbolicLink de un objeto File que hace referencia a un punto de unión (utilizados en el sistema de archivos NTFS) se establece como true.

La secuencia de caracteres de final de línea utilizada por el sistema operativo.

En Mac OS y Linux, el carácter de salto de línea (código hexadecimal 0x0A). En Windows, el carácter de retorno de carro (código hexadecimal 0x0D) seguido del carácter de salto de línea (código hexadecimal 0x0A).

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

La ruta completa de la representación del sistema operativo. En Mac OS y Linux, se utiliza el carácter de barra diagonal (/) como separador de rutas. Sin embargo, en Windows puede definir la propiedad nativePath con el carácter de barra diagonal o el de barra diagonal inversa (\) como separador de rutas: AIR reemplaza automáticamente las barras diagonales por barras diagonales inversas si es necesario.

Antes de escribir código para definir la propiedad nativePath directamente, analice si hacerlo requerirá escribir código específico de alguna plataforma. Por ejemplo, una ruta nativa como "C:\\Documents and Settings\\pedro\\Escritorio" sólo es válida en Windows. Es mucho mejor utilizar las siguientes propiedades estáticas que representan lo directorios más utilizados y que son válidas en todas las plataformas:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Puede utilizar el método resolvePath() para obtener una ruta relativa a estos directorios.

Algunas API de Flex, como la propiedad origen de la clase SWFLoader, utilizan una dirección URL (la propiedad url de un objeto File), no una ruta nativa (la propiedad nativePath).

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

El directorio que contiene el archivo o el directorio al que hace referencia este objeto File.

Si el archivo o directorio no existe, la propiedad parent sigue devolviendo el objeto File que apunta al directorio que lo contiene (incluso si dicho directorio no existe).

Esta propiedad es idéntica al valor devuelto por resolvePath("..") con la salvedad de que el directorio principal de un directorio raíz es null.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Determine si se le ha concedido a la aplicación el permiso para acceder al sistema de archivos.

Elementos de API relacionados

Indica si el motor de ejecución impide la copia de seguridad en la nube de este objeto de archivo.

Si esta propiedad está establecida en true, no se crea automáticamente una copia de seguridad en la nube en plataformas que ofrecen ese servicio. El valor predeterminado de esta propiedad es false.

Carácter separador de componentes de ruta del sistema operativo.

En Mac OS y Linux es el carácter de barra diagonal (/). En Windows es el carácter de barra diagonal inversa (\).

Nota: si utiliza el carácter de barra diagonal inversa en un literal de cadena, no olvide escribir el carácter dos veces (por ejemplo, "directory\\file.ext"). Cada pareja de barras diagonales inversas de un literal de cadena representa una única barra diagonal inversa de la cadena.

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

El espacio disponible para el uso en esta ubicación de File, en bytes.

Si el objeto File hace referencia a un directorio, spaceAvailable indica el espacio que pueden utilizar los archivos en el directorio. Si el archivo File hace referencia a un archivo, spaceAvailable indica el espacio que puede aumentar el archivo. Si no existe la ubicación del archivo, spaceAvailable se establece en 0. Si el objeto File hace referencia a un vínculo simbólico, spaceAvailable indica el espacio disponible en la ubicación a la que apunta el vínculo simbólico.

Normalmente, el espacio disponible para un archivo o un directorio es el mismo que existe en el volumen que los contiene. Sin embargo, el espacio disponible puede tener en cuenta cuotas y límites por directorio.

Añadir un archivo o un directorio a un volumen, suele requerir más espacio que el tamaño real del archivo o el tamaño del contenido del directorio. Por ejemplo, el sistema operativo puede requerir más espacio para almacenar la información de los índices. O los sectores de disco requeridos pueden usar espacio adicional. También debemos recordar que el espacio disponible cambia dinámicamente. Por ello, no se puede esperar asignar todo el espacio para almacenamiento de archivos.

Codificación predeterminada utilizada por el sistema operativo.

Algunos de los valores posibles son "windows-1252" "shift-jis", "cn-gb", "iso-8859-1". Para obtener una lista completa, consulte los juegos de caracteres admitidos.

Puede utilizar este valor con los métodos readMultiByte() y writeMultiByte() de la clase FileStream.

Elementos de API relacionados

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

URL de esta ruta de archivo.

Si es una referencia a una ruta del directorio de almacenamiento de la aplicación, el esquema URL es "app-storage"; si se trata de una referencia a una ruta en el directorio de aplicaciones, el esquema URL es "app"; en cualquier otro caso, el esquema es "file".

Puede utilizar caracteres de espacio en blanco (en vez de "%20") al asignar un valor a la propiedad url; AIR codificará automáticamente las cadenas (por ejemplo, convierte los espacios en blanco en "%20").

Elementos de API relacionados

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

El directorio del usuario.

En Windows es el directorio principal de Mis documentos (por ejemplo, C:\Documents and Settings\NombreUsuario). En Mac OS es /Users/NombreUsuario. En Linux, es /home/nombreUsuario.

La propiedad userDirectory permite hacer referencia al directorio del usuario de forma que funcione en todas las plataformas. Si establece la propiedad nativePath o url de un objeto File directamente, sólo funcionará correctamente en la plataforma para la que dicha ruta sea válida.

Si un sistema operativo no admite un directorio de usuario, se utiliza en su lugar un directorio que se encuentre en el sistema de archivos.

En dispositivos de AIR para TV, la propiedad userDirectory hace referencia a un directorio de usuarios que es único para la aplicación.

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

La función constructora de la clase File.

Si transfiere un argumento path, el objeto File apunta a la ruta especificada y las propiedades nativePath y url se definen para reflejar dicha ruta.

Aunque puede transferir un argumento path para especificar una ruta de archivo, debe analizar si hacerlo requerirá código específico de una plataforma. Por ejemplo, una ruta nativa como puede ser "C:\\\\Documents and Settings\\pedro\\Escritorio" o una dirección URL como "file:///C:/Documents%20and%20Settings/pedro/Escritorio" sólo es válida en Windows. Es mucho mejor utilizar las siguientes propiedades estáticas que representan lo directorios más utilizados y que son válidas en todas las plataformas:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Seguidamente puede utilizar el método resolvePath() para obtener una ruta relativa a estos directorios. Por ejemplo, el siguiente código define un objeto File para que apunte al archivo settings.xml del directorio de almacenamiento de la aplicación:

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Importante: si pasa una cadena URL en el parámetro path, la URL se descodifica para resolver la ruta de archivo. Por ejemplo, la sentencia new File("file:///c:/test/demo%20file%201%2e0.txt") crea un objeto File con ruta nativa "c:\test\demo file 1.0.txt". (Una URL utiliza los prefijos de esquema file:, app:, o app-storage:.) Sin embargo, si se omiten los prefijos válidos de URL, la cadena de ruta se trata como una ruta nativa y no tiene lugar descodificación alguna. Se debe tener en cuenta este comportamiento al validar trazados derivados de fuentes que potencialmente no son de confianza. Si simplemente valida la cadena de entrada, la descodificación de URL puede permitir que un atacante esquive los controles de validación. Valide siempre la ruta final del objeto File del que se ha creado una instancia:

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Elementos de API relacionados

Muestra un cuadro de diálogo de selección de directorios donde el usuario puede elegir un directorio. Cuando el usuario selecciona el directorio, se distribuye el evento select. La propiedad target del evento select es el objeto File que apunta al directorio seleccionado.

El diálogo de selección de directorios no se muestra siempre delante de las ventanas que son “propiedad” de otra ventana (ventanas cuya propiedad owner no sea null). Para evitar problemas de ordenación de ventanas, oculte las ventanas pertenecientes antes de llamar a este método.

Nota: en dispositivos Android, el método browseForDirectory() no se admite. El objeto File distribuye un evento cancel inmediatamente.

Parámetros

Elementos de API relacionados

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Muestra el cuadro de diálogo Abrir archivo, donde el usuario puede seleccionar un archivo para abrirlo.

Cuando el usuario selecciona el archivo, se distribuye el evento select. La propiedad target del evento select es el objeto File que apunta al archivo seleccionado.

El diálogo Abrir archivo no se muestra siempre delante de las ventanas que son “propiedad” de otra ventana (ventanas cuya propiedad owner no sea null). Para evitar problemas de ordenación de ventanas, oculte las ventanas pertenecientes antes de llamar a este método.

Nota: en dispositivos Android, el título del diálogo del archivo no se puede establecer. El parámetro title se omite.

Parámetros

Elementos de API relacionados

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Muestra el cuadro de diálogo Abrir archivo, donde el usuario puede seleccionar uno o varios archivos para abrirlos.

Cuando el usuario selecciona los archivos, se distribuye el evento selectMultiple. La propiedad target del evento select es este objeto File. Al contrario que con el método browseForOpen(), con el método browseForOpenMultiple() este objeto File no se actualiza con ninguna referencia a los archivos seleccionados. En su lugar, el evento selectMultiple resultante contiene el conjunto de los archivos seleccionados.

El diálogo Abrir archivo no se muestra siempre delante de las ventanas que son “propiedad” de otra ventana (ventanas cuya propiedad owner no sea null). Para evitar problemas de ordenación de ventanas, oculte las ventanas pertenecientes antes de llamar a este método.

Nota: en dispositivos Android, el título del diálogo del archivo no se puede establecer. El parámetro title se omite.

Parámetros

Elementos de API relacionados

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Muestra el cuadro de diálogo Guardar archivo, donde el usuario puede seleccionar un archivo para guardarlo.

Cuando el usuario selecciona el archivo, se distribuye el evento select. La propiedad target del evento select es el objeto File que apunta al destino de grabación seleccionado.

El diálogo Guardar archivo no se muestra siempre delante de las ventanas que son “propiedad” de otra ventana (ventanas cuya propiedad owner no sea null). Para evitar problemas de ordenación de ventanas, oculte las ventanas pertenecientes antes de llamar a este método.

Nota: en dispositivos Android, el título del diálogo del archivo no se puede establecer. El parámetro title se omite.

Parámetros

Elementos de API relacionados

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Cancela cualquier operación asíncrona pendiente.

Estandariza la ruta de File.

Si el objeto File representa un archivo o directorio existente, la estandarización ajusta la ruta para que coincida exactamente con el nombre real del directorio o del archivo. Si el objeto File es un vínculo simbólico, la estandarización ajusta la ruta para que coincida con la del archivo o directorio al que apunta el vínculo, exista o no el directorio o el archivo al que se apunta. En los sistemas de archivos que distinguen entre mayúsculas y minúsculas (como Linux), cuando existen varios archivos con nombres que difieren únicamente en las mayúsculas y minúsculas, el método canonicalize() ajusta la ruta para que coincida con el primer archivo encontrado (en un orden que determina el sistema de archivos).

Además, la canonización convierte los nombres de archivo largos en nombres cortos en Windows.

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Devuelve una copia de este objeto File. Los registros de eventos no se copian.

Nota: este método en realidad no copia el archivo. Simplemente hace una copia de la instancia de ActionScript del objeto File. Para copiar un archivo, utilice el método copyTo().

Copia el archivo o el directorio en la ubicación especificada por este objeto File y especificada por el parámetro newLocation. El proceso de copia crea los directorios principales necesarios (si es posible). Al sobrescribir archivos con copyTo (), los atributos de archivo también se sobrescriben.

Parámetros

Elementos de API relacionados

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Comienza a copiar el archivo o el directorio en la ubicación especificada por este objeto File y especificada por el parámetro destination.

Una vez finalizado el proceso, se distribuye un evento complete (si la operación se ha realizado correctamente) o un evento ioError (en caso de error). El proceso de copia crea los directorios principales necesarios (si es posible).

Parámetros

Elementos de API relacionados

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Crea el directorio especificado y los directorios principales necesarios. Si el directorio ya existe, no se realiza ninguna acción.

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Devuelve una referencia a un nuevo directorio temporal. Un nuevo directorio de la ruta del directorio temporal del sistema de archivos.

Este método permite identificar un nuevo directorio exclusivo sin necesidad de consultar al sistema para ver si el directorio es nuevo y exclusivo.

Elimine el directorio temporal antes de cerrar la aplicación, ya que no se elimina automáticamente en algunos dispositivos.

Elementos de API relacionados

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Devuelve una referencia a un nuevo archivo temporal. Un nuevo archivo de la ruta del directorio temporal del sistema de archivos.

Este método permite identificar un nuevo archivo exclusivo sin necesidad de consultar al sistema para ver si el archivo es nuevo y exclusivo.

Elimine el archivo temporal antes de cerrar la aplicación, ya que no se elimina automáticamente.

Elementos de API relacionados

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Elimina el directorio. Si este archivo es en realidad un enlace simbólico a un directorio, se eliminará el enlace, no el directorio.

Parámetros

Elementos de API relacionados

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Elimina el directorio de forma asíncrona. Si este archivo es en realidad un enlace simbólico a un directorio, se eliminará el enlace, no el directorio.

Parámetros

Elementos de API relacionados

Elimina el archivo. Si este archivo es en realidad un enlace simbólico, se eliminará el enlace, no el archivo.

Elementos de API relacionados

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Elimina el archivo de forma asíncrona. Si este archivo es en realidad un enlace simbólico, se eliminará el enlace, no el archivo.

Elementos de API relacionados

Devuelve un conjunto de objetos File correspondientes a los archivos y directorios representados por este objeto File. Este método no explora el contenido de los subdirectorios.

Elementos de API relacionados

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Recupera asíncronamente un conjunto de objetos File correspondientes al contenido del directorio representado por este objeto File.

Elementos de API relacionados

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Busca la ruta relativa entre dos rutas de File.

La ruta relativa es la lista de componentes a la que se puede añadir (resolver) esta referencia para localizar la segunda referencia (parámetro). La ruta relativa se devuelve con el carácter separador "/".

Opcionalmente, las rutas relativas pueden contener referencias ".." aunque estas rutas no traspasan límites de volúmenes importantes.

Parámetros

Devuelve un conjunto de objetos File con una lista de los directorios raíz del sistema de archivos.

Por ejemplo, en Windows es una lista de volúmenes, como la unidad C: y D:. No se incluye ninguna unidad vacía (por ejemplo, una unidad de CD o de DVD sin ningún disco insertado) en este conjunto. En Mac OS y Linux, este método siempre produce como resultado el directorio raíz exclusivo del ordenador (el directorio "/").

En sistemas de archivos en los que la raíz no se puede leer, como el sistema de archivos Android, las propiedades del objeto File devuelto no siempre reflejan el valor exacto. Por ejemplo, en Android, la propiedad spaceAvailable informa 0.

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Mueve el archivo o el directorio a la ubicación especificada por este objeto File y especificada por el parámetro destination.

Para renombrar un archivo, defina el parámetro destination para que apunte a una ruta dentro del directorio del archivo, pero con un nombre de archivo distinto.

El proceso de mover crea los directorios principales necesarios (si es posible).

Parámetros

Elementos de API relacionados

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Comienza a mover el archivo o el directorio en la ubicación especificada por este objeto File y especificada por el parámetro newLocation.

Para renombrar un archivo, defina el parámetro destination para que apunte a una ruta dentro del directorio del archivo, pero con un nombre de archivo distinto.

El proceso de mover crea los directorios principales necesarios (si es posible).

Parámetros

Elementos de API relacionados

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Mueve un archivo o directorio a la papelera.

Nota: en sistemas operativos que no admiten el concepto de carpeta de papelera recuperable, los archivos se eliminan inmediatamente.

Elementos de API relacionados

Mueve un archivo o directorio a la papelera asíncronamente.

Nota: en sistemas operativos que no admiten el concepto de carpeta de papelera recuperable, los archivos se eliminan inmediatamente.

Elementos de API relacionados

Abre el archivo en la aplicación registrada por el sistema operativo para abrir este tipo de archivo.

AIR le impide utilizar el método File.openWithDefaultApplication() para abrir determinados archivos. En Windows, AIR impide abrir archivos que tienen determinados tipos de archivo (archivos con extensiones específicas enumeradas a continuación). En Mac OS y en Linux, AIR impide abrir archivos que inician aplicaciones específicas, especificadas a continuación. Intentar abrir uno de estos archivos con el métoido openWithDefaultApplication() producirá una excepción. Sin embargo, las aplicaciones de AIR instaladas con un instalador nativo (aplicaciones de perfil ampliado de escritorio) no tienen niguna de estas limitaciones: pueden abrir archivos de cualquier tipo.

No se pueden abrir documentos desde el directorio de la aplicación.

Las siguientes tablas muestran las extensiones de archivo permitidas en Windows, así como las aplicaciones que no se pueden abrir en en Mac OS y en Linux:

Elementos de API relacionados

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Solicita permiso para acceder al sistema de archivos.

Crea un nuevo objeto File con una ruta relativa a la ruta del objeto File. Se basa en el parámetro path (una cadena).

Puede utilizar una ruta relativa o una ruta absoluta como parámetro path.

Si especifica una ruta relativa, el parámetro path dado se "añade" a la ruta del objeto File. No obstante, el uso de ".." en el parámetro path puede devolver una ruta resultante que no dependa del objeto File. La referencia resultante no necesita hacer referencia a una ubicación real de sistema de archivos.

Si especifica una referencia absoluta de archivo, el método devuelve el objeto File que apunta a dicha ruta. La referencia absoluta de archivo debe utilizar la sintaxis nativa válida de rutas del sistema operativo del usuario (por ejemplo, "C:\\test" en Windows). No utilice una URL (como "file:///c:/test") como parámetro path.

Todas las rutas resultantes se normalizan del siguiente modo:

• Any "." se omite.
• Any ".." consume su entrada principal.
• No ".." que llega a la raíz del sistema de archivos o la raíz de almacenamiento persistente de la aplicación pasa dicho nodo; se omite.

Siempre se debe utilizar el carácter de barra inclinada ( / ) como separador de ruta. En Windows, también puede utilizar el carácter de barra diagonal invertida (\), pero no se recomienda. Usar el carácter de barra diagonal invertida puede hacer que las aplicaciones no funcionen en otras plataformas.

En Linux, los nombres de archivos y de directorios distinguen entre mayúsculas y minúsculas.

Parámetros

Se distribuye cuando se cancela una operación asíncrona pendiente.

Este evento tiene las propiedades siguientes:

Se distribuye cuando finaliza una operación asíncrona.

Este evento tiene las propiedades siguientes:

Se distribuye si hay una lista de directorios disponible como resultado de una llamada al método getDirectoryListingAsync().

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye cuando se produce un error durante una operación asíncrona de archivos.

Este evento tiene las propiedades siguientes:

Se distribuye cuando la aplicación pide permiso para acceder al sistema de archivos. Compruebe el valor del estado de la propiedad para determinar si el permiso se ha concedido o denegado

Elementos de API relacionados

Se distribuye si una operación viola una restricción de seguridad.

Este evento tiene las propiedades siguientes:

Se distribuye cuando el usuario selecciona un archivo o un directorio en un cuadro de diálogo de búsqueda de archivos o directorios.

Este evento tiene las propiedades siguientes:

Se distribuye cuando el usuario selecciona archivos en el cuadro de diálogo abierto al llamar al método browseForOpenMultiple().

Elementos de API relacionados