Camera  - AS3

La cantidad de movimiento detectado por la cámara. El rango de valores válidos es de 0 (no se detecta movimiento) a 100 (se detecta gran cantidad de movimiento). El valor de esta propiedad puede ayudarle a determinar si es preciso pasar un valor de configuración para el método setMotionLevel().

Si la cámara está disponible pero aún no se utiliza porque no se ha llamado al método Video.attachCamera(), esta propiedad se establece en -1.

Si está reproduciendo sin interrupción vídeo local sin comprimir, esta propiedad sólo se establece si ha asignado una función al controlador de eventos. En caso contrario, no está definida.

Elementos de API relacionados

La cantidad máxima de ancho de banda, expresada en bytes, que puede utilizar la salida de vídeo actual. El valor 0 indica que la salida puede utilizar el ancho de banda que sea necesario para mantener la calidad de fotogramas deseada.

Para definir esta propiedad, utilice el método setQuality().

Elementos de API relacionados

Velocidad a la que está capturando datos la cámara, expresada en fotogramas por segundo. Esta propiedad no puede establecerse; sin embargo, puede utilizar el método setMode() para establecer una propiedad relacionada (fps) que especifique la velocidad de fotogramas máxima con la que desea que la cámara capture datos.

Elementos de API relacionados

La velocidad máxima a la que la cámara puede capturar los datos, expresada en fotogramas por segundo. La velocidad máxima posible depende de las capacidades de la cámara; es posible que no se llegue a alcanzar esta velocidad de fotogramas.

• Para establecer el valor que desee para esta propiedad, utilice el método setMode().
• Para determinar la velocidad a la que la cámara está capturando datos, use la propiedad currentFPS.

Elementos de API relacionados

Altura de captura actual, expresada en píxeles. Para establecer el valor de esta propiedad, utilice el método setMode().

Elementos de API relacionados

Un índice basado en cero que especifica la posición de la cámara en el conjunto Camera.names, en el que se muestran todas las cámaras disponibles.

Elementos de API relacionados

La propiedad isSupported se establece en true si la clase Camera se admite en la plataforma actual; en caso contrario, se establece en false.

El número de fotogramas de vídeo que se transmiten completamente (denominados fotogramas clave) en vez de interpolarlos con el algoritmo de compresión de vídeo. El valor predeterminado es 15, lo que significa que cada decimoquinto fotograma es un fotograma clave. El valor de 1 indica que cada fotograma es un fotograma clave. Los valores permitidos van del 1 al 300.

Elementos de API relacionados

Indica si una vista local de lo que está capturando la cámara se comprime y se descomprime (true) del mismo modo que con la transmisión en vivo mediante Flash Media Server, o si no se comprime (false). El valor predeterminado es false.

Aunque una transmisión comprimida es útil para pruebas, como cuando se obtienen vistas previas de la configuración de la calidad de vídeo, supone un importante coste de procesamiento. La vista local se comprime, se edita para la transmisión como si fuese para una conexión en vivo y luego se descomprime para la vista local.

Para definir este valor, utilice Camera.setLoopback(). Para establecer el grado de compresión empleado cuando la propiedad es true, utilice Camera.setQuality().

Elementos de API relacionados

La cantidad de movimiento necesario para distribuir el evento activity. Admite valores comprendidos entre 0 y 100. El valor predeterminado es 50.

Puede mostrarse vídeo con independencia del valor de la propiedad motionLevel. Para más información, consulte setMotionLevel().

Elementos de API relacionados

Número de milisegundos que transcurren entre el momento en que la cámara deja de detectar movimiento y la invocación del evento activity. El valor predeterminado es 2000 (2 segundos).

Para definir este valor, utilice setMotionLevel().

Elementos de API relacionados

Valor booleano que indica si el usuario ha denegado el acceso a la cámara (true) o lo ha permitido (false) en el cuadro de diálogo Privacidad de Flash Player. Cuando cambia el valor, se distribuye el evento status.

Elementos de API relacionados

El nombre de la cámara actual, tal y como lo ha devuelto el hardware de la cámara.

Elementos de API relacionados

Un conjunto de cadenas que incluye los nombres de todas las cámaras disponibles. El acceso a este conjunto no mostrará el cuadro de diálogo Privacidad de Flash Player. Este conjunto proporciona el índice basado en cero de cada cámara y el número de cámaras del sistema (por medio de names.length).

Llamar a la propiedad names exige un examen exhaustivo del hardware. En la mayoría de los casos, podrá utilizar simplemente la cámara predeterminada.

Elementos de API relacionados

Determine si se le ha concedido a la aplicación el permiso para usar la cámara.

Elementos de API relacionados

Especifica el lado del dispositivo en el que se sitúa la cámara.

Utilice la propiedad position para determinar si una cámara en un dispositivo móvil se encuentra en la parte frontal o en la posterior del dispositivo. La siguiente función comprueba cada cámara disponible hasta que encuentra una cámara con la posición deseada. Si no hay ninguna cámara en la posición deseada, se devuelve la cámara predeterminada.

     function getCamera( position:String ):Camera
     {
       var camera:Camera;
       var cameraCount:uint = Camera.names.length;
      for ( var i:uint = 0; i < cameraCount; ++i )
      {
        camera = Camera.getCamera( String(i) );
        if ( camera.position == position ) return camera;
      }
      return Camera.getCamera();
     
     

En dispositivos móviles, la posición de la cámara normalmente es CameraPosition.FRONT o CameraPosition.BACK. Si no se puede determinar la posición de la cámara, se envía como CameraPosition.UNKNOWN. En plataformas de escritorio, la posición es siempre CameraPosition.UNKNOWN.

Las constantes de los valores válidos de esta propiedad se definen en la clase CameraPosition

Elementos de API relacionados

El nivel necesario de la calidad de imagen, tal y como lo determina la cantidad de compresión aplicada a cada fotograma de vídeo. Los valores de calidad admitidos van del 1 (la calidad más baja, máxima compresión) al 100 (la calidad más alta, sin compresión). El valor predeterminado es 0, que hace que la calidad de imagen varíe si es preciso para no superar el ancho de banda disponible.

Para definir esta propiedad, utilice el método setQuality().

Elementos de API relacionados

Anchura de captura actual, expresada en píxeles. Para establecer el valor que desee para esta propiedad, utilice el método setMode().

Elementos de API relacionados

Rellena un conjunto de bytes de una zona rectangular de datos de píxeles

Escribe un entero sin signo (un valor de píxeles de 32 bits no multiplicado) para cada píxel de la matriz de bytes. El tamaño del conjunto se ajusta a la cantidad necesaria de bytes para albergar todos los píxeles.

Parámetros

Elementos de API relacionados

Rellena un vector de una zona rectangular de datos de píxeles.

Escribe un entero sin signo (un valor de píxeles de 32 bits no multiplicado) para cada píxel del vector. El tamaño del vector se ajusta a la cantidad necesaria de entradas para albergar todos los píxeles.

Parámetros

Elementos de API relacionados

Copia el último fotograma en un mapa de bits.

Este método copia el contenido del último fotograma en una instancia de BitmapData.

Parámetros

Elementos de API relacionados

Devuelve una referencia a un objeto Camera para capturar vídeo. Para comenzar a capturar vídeo, debe asociar el objeto Camera a un objeto Video (consulte Video.attachCamera() ). Para transmitir vídeo a Flash Media Server, llame a NetStream.attachCamera() para asociar el objeto Camera a un objeto NetStream.

Varias llamadas al método getCamera() hacen referencia al mismo controlador de la cámara. Por tanto, si el código incluye elementos como firstCam:Camera = getCamera() y secondCam:Camera = getCamera(), tanto firstCam como secondCam hacen referencia a la misma cámara, que es la predeterminada del usuario.

En dispositivos móviles con cámara frontal y trasera, sólo se puede capturar vídeo desde una cámara a la vez.

En general, no debe pasar ningún valor para el parámetro name; simplemente utilice getCamera() para devolver una referencia a la cámara predeterminada. A través del panel de configuración Cámara (descrito posteriormente en esta sección), el usuario puede especificar la cámara predeterminada que debe utilizar.

No es posible utilizar ActionScript para definir la configuración del permiso la denegación de acceso a la cámara, pero sí se puede mostrar el cuadro de diálogo de configuración de la cámara de Adobe Flash Player Settings donde el usuario puede definir los permisos. Si un archivo SWF que utilice el método attachCamera() intenta asociar la cámara devuelta por el método getCamera() a un objeto Video o NetStream, Flash Player muestra un cuadro de diálogo donde el usuario puede permitir o denegar el acceso a la cámara. (Asegúrese de que el tamaño de la ventana de la aplicación sea de al menos 215 x 138 píxeles; éste es el tamaño mínimo que exige Flash Player para mostrar el cuadro de diálogo.) Cuando el usuario responde a este cuadro de diálogo de configuración de la cámara, Flash Player devuelve un objeto de información en el evento status que indica la respuesta del usuario: Camera.muted indica que el usuario ha denegado el acceso a una cámara; Camera.Unmuted indica que el usuario ha permitido el acceso a una cámara. Para determinar si el usuario ha denegado o autorizado el acceso a la cámara sin procesar el evento status, utilice la propiedad muted.

En Flash Player, el usuario puede especificar una configuración de privacidad permanente para un dominio concreto haciendo clic con el botón derecho del ratón (Windows y Linux) o haciendo clic con la tecla Control presionada (Macintosh) mientras se reproduce un archivo SWF, seleccionando Configuración, abriendo el cuadro de diálogo Privacidad y seleccionando Recordar. Si el usuario selecciona Recordar, Flash Player ya no solicitará al usuario que permita o deniegue el acceso a la cámara de archivos SWF de este dominio.

Nota: el método attachCamera() no invoca el cuadro de diálogo para permitir o denegar el acceso a la cámara si el usuario ha denegado el acceso seleccionando Recordar en el cuadro de diálogo de configuración de Flash Player. En ese caso, puede solicitar al usuario que cambie los parámetros de acceso y denegación mediante el panel Privacidad de Flash Player con Security.showSettings(SecurityPanel.PRIVACY).

Si getCamera() devuelve el valor null, indicará que la cámara está siendo utilizada por otra aplicación o que no hay cámaras instaladas en el sistema. Para comprobar si hay cámaras instaladas, utilice la propiedad names.length. Para ver el panel de configuración de la cámara de Flash Player, en el que el usuario puede elegir la cámara a la que hará referencia getCamera(), utilice Security.showSettings(SecurityPanel.CAMERA).

La exploración del hardware en busca de cámaras lleva tiempo. Cuando el motor de ejecución encuentra al menos una cámara, el hardware no vuelve a explorarse durante toda la vida de la instancia del reproductor. No obstante, si el motor de ejecución no encuentra ninguna cámara, la buscará cada vez que se llame a getCamera. Esto resulta útil si hay una cámara presente pero desactivada; si el archivo SWF ofrece un botón Intentar de nuevo que llama a getCamera, Flash Player podrá localizar la cámara sin que el usuario tenga que reiniciar el archivo SWF.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);
        
        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            if (Camera.isSupported)
            {
                cam = Camera.getCamera();
                
                 if (!cam) {
                    myTextField.text = "No camera is installed.";
                    
                } else if (cam.muted) {
                    myTextField.text = "To enable the use of the camera,\n"
                                     + "please click on this text field.\n" 
                                     + "When the Flash Player Settings dialog appears,\n"
                                     + "make sure to select the Allow radio button\n" 
                                     + "to grant access to your camera.";
    
                    myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
    
                }else {
                    myTextField.text = "Connecting";
                    connectCamera(); 
                }
       
                addChild(myTextField);
    
                t.addEventListener(TimerEvent.TIMER, timerHandler);
            }else {
                myTextField.text = "The Camera class is not supported on this device.";
            }
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

Solicite el permiso de cámara para la aplicación.

Especifica qué fotogramas de vídeo se transmiten completamente (denominados fotogramas clave) en vez de interpolarlos con el algoritmo de compresión de vídeo. Este método sólo es aplicable si está transmitiendo vídeo mediante Flash Media Server.

El algoritmo de compresión de vídeo de Flash comprime vídeo transmitiendo solamente lo que ha cambiado desde el último fotograma; estos fragmentos reciben el nombre de fotogramas interpolados. Los fotogramas de un vídeo se pueden interpolar según el contenido del fotograma anterior. Sin embargo, un fotograma clave es un fotograma de vídeo completo; no está interpolado a partir de fotogramas anteriores.

Para determinar el modo de establecer un valor para el parámetro keyFrameInterval, tenga en cuenta el uso del ancho de banda y la accesibilidad de la reproducción de vídeo. Por ejemplo, al especificar un valor más alto para keyFrameInterval (mediante el envío menos frecuente de fotogramas clave) se reduce el uso del ancho de banda. Sin embargo, esto puede aumentar la cantidad de tiempo necesario para colocar la cabeza lectora en un punto determinado del vídeo; puede que sea necesario interpolar los fotogramas de vídeo más antiguos para que el vídeo pueda seguir reproduciéndose.

Por el contrario, al especificar un valor más bajo para keyFrameInterval (mediante el envío más frecuente de fotogramas clave) se aumenta el uso del ancho de banda, ya que se transmiten fotogramas de vídeo completos con mayor frecuencia, pero puede reducir la cantidad de tiempo necesaria para buscar un fotograma de vídeo concreto en la grabación.

Parámetros

Elementos de API relacionados

Especifica si se utilizará un flujo de vídeo comprimido para una visualización local de la cámara. Este método sólo es aplicable si está transmitiendo vídeo mediante Flash Media Server; al establecer compress en true, es posible ver de forma más precisa cómo aparecerá el vídeo cuando se vea en tiempo real.

Aunque un flujo comprimido resulta útil para realizar comprobaciones (como previsualizar la configuración de calidad del vídeo), supone un coste de procesamiento significativo, ya que la visualización local no sólo está comprimida: está comprimida, editada para su transmisión como si se produjese una conexión en vivo y, posteriormente, descomprimida para la visualización local.

Para establecer el grado de compresión empleado al definir compress como true, utilice Camera.setQuality().

Parámetros

Elementos de API relacionados

Establece el modo de captura de cámara con el modo nativo que mejor se adapte a los requisitos especificados. Si la cámara no dispone de ningún modo nativo que coincida con todos los parámetros que ha transferido, el tiempo de ejecución seleccionará el modo de captura que mejor sintetice el modo solicitado. Esta manipulación puede implicar el recorte de la imagen y la eliminación de fotogramas.

De manera predeterminada, el tiempo de ejecución elimina los fotogramas que sean necesarios para mantener el tamaño de la imagen. Para minimizar el número de fotogramas eliminados, aunque ello implique la reducción del tamaño de la imagen, pase el valor false para el parámetro favorArea.

Al elegir un modo nativo, el tiempo de ejecución intenta mantener la proporción solicitada siempre que sea posible. Por ejemplo, si emite el comando myCam.setMode(400, 400, 30) y los valores máximos de anchura y altura disponibles en la cámara son 320 y 288, el tiempo de ejecución establece tanto la anchura como al altura en 288; al establecer estas propiedades con el mismo valor, el tiempo de ejecución mantiene la proporción 1:1 solicitada.

Para determinar los valores asignados a estas propiedades después de que el tiempo de ejecución seleccione el modo más próximo a los valores que ha solicitado, utilice las propiedades width, height y fps.

Si utiliza Flash Media Server, puede también capturar fotogramas únicos o crear fotografía a intervalos. Para más información, consulte NetStream.attachCamera().

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.events.MouseEvent;
    import flash.display.StageScaleMode;

    public class Camera_setModeExample extends Sprite {
        private var cam:Camera;
        private var vid:Video;

        public function Camera_setModeExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;

            cam = Camera.getCamera();
            
            if (!cam) {
                trace("No camera is installed.");
            }else {
                connectCamera();
            }
        }

        private function connectCamera():void {
            vid = new Video();
            vid.width = cam.width;
            vid.height = cam.height; 
            vid.attachCamera(cam);
            addChild(vid);    

            stage.addEventListener(MouseEvent.CLICK, clickHandler);
        }
    
        private function clickHandler(e:MouseEvent):void {

            switch (cam.width) {
                case 160:
                cam.setMode(320, 240, 10); 
                break;
                case 320:
                cam.setMode(640, 480, 5); 
                break;
                default:
                cam.setMode(160, 120, 15); 
                break;
            } 

            removeChild(vid);           
            connectCamera();
        }
    }
}

Especifica la cantidad de movimiento necesaria para distribuir el evento activity. Opcionalmente, establece el número de milisegundos que deben transcurrir sin que exista actividad para que el tiempo de ejecución considere que el movimiento se ha detenido y distribuya el evento.

Nota: puede mostrarse vídeo con independencia del valor del parámetro motionLevel. Este parámetro sólo determina cuándo y en qué circunstancias debe distribuirse el evento (no determina si realmente se está capturando o mostrando vídeo).

Para evitar que la cámara detecte movimiento, transmita el valor 100 para el parámetro motionLevel; el evento activity nunca se distribuirá. (Tal vez utilice este valor solamente para realizar pruebas; por ejemplo, para desactivar temporalmente cualquier controlador que, en condiciones normales, se desencadenaría al distribuir el evento).

Para determinar la cantidad de movimiento que está detectando actualmente la cámara, utilice la propiedad activityLevel. Los valores de sensibilidad al movimiento se corresponden directamente con los valores de actividad. La ausencia total de movimiento tiene un valor de actividad 0. El movimiento constante total tiene un valor de actividad 100. El valor de actividad es inferior al valor de sensibilidad de movimiento si no se está moviendo; al moverse, los valores de actividad suelen ser mayores que el valor de sensibilidad de movimiento.

Este método tiene una finalidad similar a la del método Microphone.setSilenceLevel(); ambos se utilizan para especificar cuándo debe distribuirse el evento activity. No obstante, estos métodos tienen efectos muy distintos en la publicación de flujos:

• Microphone.setSilenceLevel() está diseñado para optimizar el ancho de banda. Cuando se considera que un flujo de audio está en silencio, no se envían datos de audio. Por el contrario, se envía un único mensaje que indica que el silencio ha comenzado.
• Camera.setMotionLevel() está diseñado para detectar movimiento y no afecta al uso del ancho de banda. Aunque un flujo de vídeo no detecte movimiento, el vídeo continúa enviándose.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.ActivityEvent;

    public class Camera_setMotionLevelExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_setMotionLevelExample() {
            myTextField = new TextField();
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            cam = Camera.getCamera();
            
            if (!cam) {
                myTextField.text = "No camera is installed.";

            }else {
                myTextField.text = "Waiting to connect.";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                cam.setMotionLevel(5, 1000);
                cam.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
        }

        private function activityHandler(e:ActivityEvent):void {
            if (e.activating == true) {
                t.start();    
            } else {
                myTextField.text = "Everything is quiet.";
                t.stop();
            }    
        }

        private function timerHandler(event:TimerEvent):void {
             myTextField.x = 10;
             myTextField.y = cam.height + 20;
             myTextField.text = "There is some activity. Level: " + cam.activityLevel;
        }
    }
}

Establece la cantidad máxima de ancho de banda por segundo o la calidad de imagen requerida para la salida de vídeo actual. Este método sólo es aplicable con carácter general si está transmitiendo vídeo mediante Flash Media Server.

Utilice este método para especificar qué elemento de la salida de vídeo es más importante para su aplicación: el uso del ancho de banda o la calidad de imagen.

• Para indicar que el uso del ancho de banda tiene prioridad, pase un valor para bandwidth y 0 para quality. El tiempo de ejecución transmite vídeo con la máxima calidad posible dentro del ancho de banda especificado. Si es preciso, el tiempo de ejecución reduce la calidad de imagen para evitar superar el ancho de banda especificado. En general, a mayor movimiento, menor calidad.
• Para indicar que la calidad tiene prioridad, pase 0 para bandwidth y un valor numérico para quality. El tiempo de ejecución utiliza el ancho de banda que sea necesario para mantener la calidad especificada. Si es preciso, el tiempo de ejecución reduce la velocidad de fotogramas para mantener la calidad de imagen. En general, a mayor movimiento, mayor uso del ancho de banda.
• Para especificar que el uso del ancho de banda y la calidad tienen idéntica importancia, pase valores numéricos para ambos parámetros. El tiempo de ejecución transmite vídeo con la calidad especificada sin superar el ancho de banda indicado. Si es preciso, el tiempo de ejecución reduce la velocidad de fotogramas para mantener la calidad de imagen sin superar el ancho de banda especificado.

Parámetros

Elementos de API relacionados

Se distribuye cuando una cámara inicia o finaliza una sesión. Llame a Camera.setMotionLevel() para especificar la cantidad de movimiento necesario para activar un evento activity con un valor activating de true, o el tiempo sin actividad que debe transcurrir antes de activar un evento activity con un valor activating de false.

Este evento tiene las propiedades siguientes:

Se distribuye cuando la aplicación pide permiso para utilizar la cámara en el dispositivo. Compruebe el valor del estado de la propiedad para determinar si el permiso se ha concedido o denegado.

Elementos de API relacionados

Se distribuye cuando una cámara informa sobre su estado. Antes de acceder a una cámara, el tiempo de ejecución muestra un cuadro de diálogo Privacidad para permitir o denegar a los usuarios el acceso a su cámara. Si el valor de la propiedad code es "Camera.muted", el usuario ha impedido el acceso del archivo SWF a la cámara del usuario. Si el valor de la propiedad code es "Camera.Unmuted", el usuario ha permitido el acceso del archivo SWF a la cámara del usuario.

Nota: este evento no se distribuye en la plataforma AIR. Sólo se utiliza en Flash Player.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Se distribuye después de haberse procesado un nuevo fotograma en el tiempo de ejecución y está disponible para su copia.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Nota: debe tener una cámara conectada al ordenador para que este ejemplo funcione correctamente.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Camera;
    import flash.media.Video;

    public class CameraExample extends Sprite {
        private var video:Video;
        
        public function CameraExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var camera:Camera = Camera.getCamera();
            
            if (camera != null) {
                camera.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
                video = new Video(camera.width * 2, camera.height * 2);
                video.attachCamera(camera);
                addChild(video);
            } else {
                trace("You need a camera.");
            }
        }
        
        private function activityHandler(event:ActivityEvent):void {
            trace("activityHandler: " + event);
        }
    }
}