Bitmap  - AS3

O objeto BitmapData que está sendo referenciado.

Controla se o objeto Bitmap é ou não encaixado no pixel mais próximo. A classe PixelSnapping inclui valores possíveis:

• PixelSnapping.NEVER — o encaixe de pixel não ocorre.
• PixelSnapping.ALWAYS — a imagem é sempre encaixada ao pixel mais próximo, independentemente da transformação.
• PixelSnapping.AUTO — a imagem será encaixada no pixel mais próximo se for desenhada sem giro ou inclinação e em um fator de escala de 99,9% a 100,1%. Se essas condições forem atendidas, a imagem bitmap será desenhada em escala de 100% e encaixada no pixel mais próximo. Internamente, esse valor permite que a imagem seja desenhada da forma mais rápida possível usando o renderizador de vetores.

Controla se o bitmap é ou não suavizado quando dimensionado. Se true, o bitmap é suavizado quando dimensionado. Se false, o bitmap não é suavizado quando dimensionado.

Inicializa um objeto Bitmap para fazer referência ao objeto BitmapData especificado.

	bitmapData:BitmapData (default = null) — O objeto BitmapData que está sendo referenciado.
	pixelSnapping:String (default = "auto") — Se o objeto Bitmap é ou não encaixado no pixel mais próximo.
	smoothing:Boolean (default = false) — Se o bitmap é ou não suavizado quando dimensionado. Por exemplo, os exemplos a seguir mostram o mesmo bitmap redimensionado por um fator de 3, com a suavização definida como false (esquerda) e true (direita):

const IMAGE_URL:String = "http://www.helpexamples.com/flash/images/logo.png";
 
var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldr_complete);
ldr.load(new URLRequest(IMAGE_URL));
 
var bitmap1:Bitmap;
var bitmap2:Bitmap;
var bitmap3:Bitmap;
var bitmap4:Bitmap;
 
function ldr_complete(evt:Event):void {
    var bmp:Bitmap = ldr.content as Bitmap;
 
    bitmap1 = new Bitmap(bmp.bitmapData);
    bitmap1.x = 100;
    bitmap1.y = 100;
    bitmap1.rotation = 0;
    addChild(bitmap1);
 
    bitmap2 = new Bitmap(bmp.bitmapData);
    bitmap2.x = 200;
    bitmap2.y = 100;
    bitmap2.rotation = 90;
    addChild(bitmap2);
 
    bitmap3 = new Bitmap(bmp.bitmapData);
    bitmap3.x = 300;
    bitmap3.y = 100;
    bitmap3.rotation = 180;
    addChild(bitmap3);
 
    bitmap4 = new Bitmap(bmp.bitmapData);
    bitmap4.x = 400;
    bitmap4.y = 100;
    bitmap4.rotation = 270;
    addChild(bitmap4);
}

1. Uma propriedade url é criada, representando a localização e o nome do arquivo de imagem
2. O construtor de classe chama o método configureAssets(), que, por sua vez, chama o método completeHandler().
3. configureAssets() cria um objeto Loader, que então instancia um ouvinte de evento que é despachado quando completeHandler() completa a manipulação da imagem.
4. Em seguida, o método buildChild() cria uma nova ocorrência de um objeto URLRequest, request, com a url transmitida para que o nome e a localização do arquivo sejam conhecidos.
5. O objeto request é transmitido ao método loader.load(), que carrega a imagem na memória por meio de um objeto de exibição.
6. A imagem é então inserida na lista de exibição, que a exibe imediatamente nas coordenadas x = 0, y = 0 da tela.
7. O método completeHandler() realiza as seguintes tarefas:
   1. Cria um segundo objeto Loader, junto com um objeto Bitmap, que é inicializado com o objeto Loader.
   2. Cria um segundo objeto Bitmap, duplicate, que, por sua vez, chama o método duplicateImage(), que cria uma duplicata da imagem original.
   3. Cria um objeto BitmapData, que é atribuído ao objeto BitmapData do objeto duplicate.
   4. Cria um novo objeto Rectangle inicializado com as mesmas coordenadas, largura e altura que a imagem original.
   5. Cria um novo objeto Point, que assume como padrão x = 0, y = 0.
   6. Cria as seguintes variáveis:
      • operation: operation: aplica a nova cor quando o valor de limite é >= o original.
      • limite: threshold: o valor com base no qual cada pixel é comparado é definido como cinza-claro com um alfa de 0xCC.
      • color color: a cor com a qual serão definidos os pixels que passarem no teste de limite, que é amarelo sólido nesse caso.
      • mask: mask: defina como o oposto exato da cor, (azul transparente).
      • copySource: copySource: defina como "false", indicando que os valores de pixel não são copiados no caso de o valor de limite não passar no teste. Esse valor não tem significado, já que a imagem é duplicada e somente os pixels que passarem no teste de limite serão alterados.
   7. Chama o método threshold() usando as variáveis anteriores. A equação de limite resultante é a seguinte: se (Valor de pixel atual & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) defina o pixel como 0xFFFFFF00.

Observações:

• Você precisará compilar o arquivo SWF com "Segurança de reprodução local" definida como "Acessar somente arquivos locais".
• Esse exemplo requer que um arquivo denominado Image.gif seja inserido no mesmo diretório que o seu arquivo SWF.
• Convém usar uma imagem com até 80 pixels de largura.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}