Video  - AS3

Geeft het type filter aan dat op gedecodeerde video wordt toegepast als onderdeel van nabewerking. De standaardwaarde is 0, waarbij de videocompressor zo nodig een deblockingfilter toepast.

Compressie van video kan leiden tot ongewenste artefacten. U kunt de eigenschap deblocking gebruiken om filters in te stellen die blocking, en voor video die met de On2-codec is gecomprimeerd, ringing verminderen.

Blocking verwijst naar zichtbare oneffenheden tussen de grenzen van de blokken waaruit elk videoframe bestaat. Ringing verwijst naar vervormde randen rondom elementen in een videobeeld.

Er zijn twee deblockingfilters beschikbaar: een in de Sorenson-codec en een in de On2 VP6-codec. Daarnaast is een deringingfilter beschikbaar wanneer u de On2 VP6-codec gebruikt. U stelt een filter in door een van de volgende waarden te gebruiken:

• 0 - De videocompressor past zo nodig het deblockingfilter toe.
• 1 - Er wordt geen deblockingfilter gebruikt.
• 2 - Het Sorenson-deblockingfilter wordt gebruikt.
• 3 - Alleen voor On2-video; het On2-deblockingfilter wordt wel gebruikt, het deringingfilter wordt niet gebruikt.
• 4 - Alleen voor On2-video; het On2-deblockingfilter en -deringingfilter worden gebruikt.
• 5 - Alleen voor On2-video; het On2-deblockingfilter en een krachtiger On2-deringingfilter worden gebruikt.

Wanneer een waarde groter dan 2 wordt geselecteerd voor video wanneer u de Sorenson-codec gebruikt, wordt de Sorenson-decoder standaard ingesteld op 2.

Het gebruik van een deblockingfilter is van invloed op de algehele prestaties van de weergave en is gewoonlijk niet noodzakelijk voor video met een hoge bandbreedte. Wanneer het systeem van een gebruiker niet krachtig genoeg is, kan deze problemen ondervinden met de videoweergave wanneer een deblockingfilter is ingeschakeld.

Geeft op of de video vloeiend (geïnterpoleerd) moet worden bij schaling. Het runtime-programma moet in de modus hoge kwaliteit worden uitgevoerd om ervoor te zorgen dat het vloeiend maken correct werkt (standaard). De standaardwaarde is false (niet vloeiend maken).

Stel deze eigenschap voor het afspelen van video met Flash Player 9.0.115.0 en hoger in op true om gebruik te maken van beeldoptimalisatie met mipmapping.

Een geheel getal dat de hoogte van de videostream opgeeft, in pixels. Deze waarde is voor live streams gelijk aan de eigenschap Camera.height van het object Camera dat de videostream vastlegt. Bij vastgelegde videobestanden staat deze waarde voor de hoogte van de video. De NetStream.Video.DimensionChange-gebeurtenis wordt verzonden in het geval van opgenomen video's wanneer deze waarde wijzigt.

U kunt deze eigenschap bijvoorbeeld gebruiken om ervoor te zorgen dat de gebruiker de video ziet in hetzelfde formaat als waarmee deze is vastgelegd, ongeacht de daadwerkelijke grootte van het object Video in het werkgebied.

Verwante API-elementen

Een geheel getal dat de breedte van de videostream opgeeft, in pixels. Deze waarde is voor live streams gelijk aan de eigenschap Camera.width van het object Camera dat de videostream vastlegt. Bij vastgelegde videobestanden staat deze waarde voor de breedte van de video. De NetStream.Video.DimensionChange-gebeurtenis wordt verzonden in het geval van opgenomen video's wanneer deze waarde wijzigt.

U kunt deze eigenschap bijvoorbeeld gebruiken om ervoor te zorgen dat de gebruiker de video ziet in hetzelfde formaat als waarmee deze is vastgelegd, ongeacht de daadwerkelijke grootte van het object Video in het werkgebied.

Verwante API-elementen

Maakt een nieuwe instantie Video. Wanneer geen waarden voor de parameters width en height zijn opgegeven, worden de standaardwaarden gebruikt. U kunt de eigenschappen voor breedte en hoogte van het object Video ook instellen nadat dit is gemaakt, met behulp van Video.width en Video.height. Wanneer een nieuw object Video wordt gemaakt, is de waarde nul voor de breedte of de hoogte niet toegestaan. Wanneer u nul doorgeeft, worden de standaardwaarden toegepast.

Nadat de video is gemaakt, roept u de methode DisplayObjectContainer.addChild() of DisplayObjectContainer.addChildAt() aan om het object Video aan een bovenliggend object DisplayObjectContainer toe te voegen.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Geeft een videostream van een camera op die binnen de grenzen van het object Video in de toepassing moet worden weergegeven.

Met deze methode kunt u live video die is vastgelegd door de gebruiker koppelen aan het Video-object. U kunt de live video lokaal afspelen op dezelfde computer of apparaat waar deze wordt vastgelegd, of u kunt de video naar Flash Media Server verzenden en de server gebruiken om deze naar andere gebruikers te streamen.

Opmerking: Bij een iOS AIR-toepassing kan de video die door de camera wordt vastgelegd, niet worden weergegeven wanneer de toepassing gebruikmaakt van de GPU-rendermodus.

Parameters

Verwante API-elementen

Geeft een videostream op die binnen de grenzen van het object Video in de toepassing moet worden weergegeven. De videostream is een videobestand dat met NetStream.play() wordt afgespeeld, een Camera-object of null. Wanneer u een videobestand gebruikt, kan dit worden opgeslagen op het lokale bestandssysteem of op Flash Media Server. Wanneer de waarde van het argument netStream null is, wordt de video niet meer binnen het Video-object afgespeeld.

U hoeft deze methode niet te gebruiken wanneer het videobestand alleen audio bevat. Het audiogedeelte van videobestanden wordt automatisch afgespeeld wanneer u NetStream.play() aanroept. Wanneer u controle wilt hebben over de audio die aan een videobestand is gekoppeld, gebruikt u de eigenschap soundTransform van het NetStream-object dat het videobestand afspeelt.

Parameters

Verwante API-elementen

Wist het beeld dat op dit moment in het Video-object wordt weergegeven (niet de videostream). Deze methode is nuttig voor de afhandeling van het huidige beeld. U kunt het laatste beeld bijvoorbeeld wissen of standby-informatie weergeven zonder het Video-object te verbergen.

Verwante API-elementen

In dit voorbeeld wordt de code die de objecten Video en NetStream maakt en de methoden Video.attachNetStream() en NetStream.play() aanroept, in een handlerfunctie geplaatst. De handler wordt alleen aangeroepen wanneer verbinding wordt gemaakt met het object NetConnection, dat wil zeggen, wanneer de gebeurtenis netStatus een object info retourneert waarvan de eigenschap code aangeeft dat de verbinding is gelukt. Het wordt aanbevolen te wachten totdat verbinding is gemaakt voordat u NetStream.play() aanroept.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }