Camera  - AS3

Hoeveelheid beweging die de camera detecteert. Mogelijke waarden lopen van 0 (er wordt geen beweging gedetecteerd) tot en met 100 (er wordt zeer veel beweging gedetecteerd). Met de waarde van deze eigenschap kunt u bepalen of u een instelling moet doorgeven aan de methode setMotionLevel().

Wanneer de camera beschikbaar is maar niet wordt gebruikt omdat de methode Video.attachCamera() niet is aangeroepen, wordt deze eigenschap ingesteld op -1.

Wanneer u alleen ongecomprimeerde lokale videostreams streamt, wordt deze eigenschap alleen ingesteld wanneer u een functie aan de gebeurtenishandler hebt toegewezen. Anders is deze functie ongedefinieerd.

Verwante API-elementen

De maximale hoeveelheid bandbreedte in bytes die de huidige uitgaande videofeed kan gebruiken. De waarde 0 houdt in dat de feed zoveel bandbreedte kan gebruiken als nodig is om de gewenste framekwaliteit te behouden.

Gebruik de methode setQuality() om deze eigenschap in te stellen.

Verwante API-elementen

De snelheid waarmee de camera gegevens vastlegt, in frames per seconde. Deze eigenschap kan niet worden ingesteld. U kunt echter de methode setMode() gebruiken om een verwante eigenschap, fps, in te stellen die de maximale framesnelheid opgeeft waarmee u wilt dat de camera gegevens vastlegt.

Verwante API-elementen

De maximale snelheid waarmee de camera gegevens kan vastleggen, in frames per seconde. De maximale snelheid hangt mogelijk af van de mogelijkheden van de camera, deze framesnelheid wordt mogelijk niet bereikt.

• Wanneer u een gewenste waarde voor deze eigenschap wilt instellen, gebruikt u de methode setMode().
• Gebruik de eigenschap currentFPS om de snelheid te bepalen waarmee de camera momenteel gegevens vastlegt.

Verwante API-elementen

De huidige vastleggingshoogte, in pixels. Wanneer u een waarde voor deze eigenschap wilt instellen, gebruikt u de methode setMode().

Verwante API-elementen

Een op nul gebaseerde index die de positie van de camera opgeeft in de array Camera.names die alle beschikbare camera's opsomt.

Verwante API-elementen

De eigenschap isSupported wordt ingesteld op true als de Camera-klasse op het huidige platform wordt ondersteund. Als dit niet het geval is, wordt de eigenschap ingesteld op false.

Het aantal videoframes dat volledig wordt verzonden (als hoofdframes) in plaats van te worden geïnterpoleerd door het algoritme voor videocompressie. De standaardwaarde is 15, wat betekent dat elk 15e frame een hoofdframe is. De waarde 1 betekent dat elk frame een hoofdframe is. De toegestane waarden zijn 1 tot en met 300.

Verwante API-elementen

Geeft aan of een lokale weergave van hetgeen de camera vastlegt, wordt gecomprimeerd en gedecomprimeerd (true), zoals bij live-verzending via Flash Media Server, of niet wordt gecomprimeerd (false). De standaardwaarde is false.

Hoewel een gecomprimeerde stream handig is voor testdoeleinden, zoals de kwaliteitsinstellingen van video vooraf bekijken, kost dit zeer veel verwerkingskracht. De lokale weergave wordt gecomprimeerd, bewerkt voor verzending zoals via een live-verbinding en vervolgens weer gedecomprimeerd voor lokale weergave.

Gebruik Camera.setLoopback() om deze waarde in te stellen. Wanneer u de hoeveelheid compressie wilt instellen die wordt gebruikt wanneer deze eigenschap is ingesteld op true, gebruikt u Camera.setQuality().

Verwante API-elementen

De hoeveelheid beweging die nodig is om de gebeurtenis activity aan te roepen. Acceptabele waarden lopen van 0 tot 100. De standaardwaarde is 50.

Video kan worden weergegeven, ongeacht de waarde van de eigenschap motionLevel. Zie setMotionLevel() voor meer informatie.

Verwante API-elementen

Het aantal milliseconden tussen het moment dat de camera stopt met het detecteren van beweging en het moment dat de gebeurtenis activity wordt aangeroepen. De standaardwaarde is 2000 (2 seconden).

Gebruik setMotionLevel() om deze waarde in te stellen.

Verwante API-elementen

Een Booleaanse waarde die aangeeft of de gebruiker toegang tot de camera heeft geweigerd (true) of heeft toegestaan (false) via het dialoogvenster Flash Player Privacy. Wanneer deze waarde verandert, wordt de gebeurtenis status verzonden.

Verwante API-elementen

De naam van de huidige camera, zoals geretourneerd door de camerahardware.

Verwante API-elementen

Een array van tekenreeksen die de namen van alle beschikbare camera's bevat. Het dialoogvenster Flash Player Privacy-dialoogvenster wordt niet weergegeven wanneer u deze array opent. Deze array biedt de op nul gebaseerde index van elke camera en het aantal camera's op het systeem (met behulp van names.length).

Het aanroepen van de eigenschap names vereist een uitvoerige controle van de hardware. In de meeste gevallen kunt u de standaardcamera gebruiken.

Verwante API-elementen

Hiermee bepaalt u of toestemming is verleend aan de toepassing om de camera te gebruiken.

Verwante API-elementen

Geeft de zijde van een apparaat op waarop de camera zich bevindt.

Gebruik de eigenschap property om te bepalen of een camera van een mobiel apparaat zich op de voor- of achterzijde van het apparaat bevindt. De volgende functie controleert elke beschikbare camera tot een camera met de gewenste positie wordt gevonden. Als er geen camera met de gewenste positie wordt gevonden, wordt de standaardcamera geretourneerd.

     function getCamera( position:String ):Camera
     {
       var camera:Camera;
       var cameraCount:uint = Camera.names.length;
      for ( var i:uint = 0; i < cameraCount; ++i )
      {
        camera = Camera.getCamera( String(i) );
        if ( camera.position == position ) return camera;
      }
      return Camera.getCamera();
     
     

Op mobiele apparaten is de positie van de camera normaal ofwel CameraPosition.FRONT of CameraPosition.BACK. Als de positie van de camera niet kan worden bepaald, wordt de positie gerapporteerd als CameraPosition.UNKNOWN. Op bureaubladplatformen is de positie altijd CameraPosition.UNKNOWN.

Constanten voor de geldige waarden voor deze eigenschap worden gedefinieerd in de klasse CameraPosition.

Verwante API-elementen

Het vereiste niveau van de afbeeldingskwaliteit, zoals is bepaald door de hoeveelheid compressie die op elk videoframe wordt toegepast. Acceptabele waarden liggen tussen 1 (laagste kwaliteit, maximale compressie) en 100 (hoogste kwaliteit, geen compressie). De standaardwaarde is 0, wat betekent dat de beeldkwaliteit kan worden gevarieerd als dit nodig is om te voorkomen dat de beschikbare bandbreedte wordt overschreden.

Gebruik de methode setQuality() om deze eigenschap in te stellen.

Verwante API-elementen

De huidige vastleggingsbreedte, in pixels. Wanneer u een gewenste waarde voor deze eigenschap wilt instellen, gebruikt u de methode setMode().

Verwante API-elementen

Vult een bytearray uit een rechthoekig gebied met pixelgegevens

Schrijft voor elke pixel een geheel getal zonder teken (een niet-vermenigvuldigde 32-bits pixelwaarde) in de bytearray. De array wordt aangepast aan het vereiste aantal bytes om alle pixels te houden.

Parameters

Verwante API-elementen

Vult een vector uit een rechthoekig gebied met pixelgegevens.

Schrijft voor elke pixel een geheel getal zonder teken (een niet-vermenigvuldigde 32-bits pixelwaarde) in de vector. De vector wordt aangepast aan het vereiste aantal vermeldingen om alle pixels te houden.

Parameters

Verwante API-elementen

Kopieert het laatste frame naar een bitmap.

Deze methode kopieert de inhoud van het laatste frame naar een BitmapData-instantie.

Parameters

Verwante API-elementen

Retourneert een verwijzing naar een object Camera voor het vastleggen van video. Als u wilt beginnen met het vastleggen van video, koppelt u het object Camera aan een object Video (zie Video.attachCamera()). Roep NetStream.attachCamera() aan om het object Camera aan een object NetStream te koppelen als u video naar Flash Media Server wilt verzenden.

Meerdere aanroepen van de methode getCamera() verwijzen naar hetzelfde camerastuurprogramma. Wanneer uw code bijvoorbeeld code bevat zoals firstCam:Camera = getCamera() en secondCam:Camera = getCamera(), verwijzen firstCam ensecondCam beide naar dezelfde camera, de standaardcamera van de gebruiker.

Bij mobiele apparaten met zowel een camera aan de voorzijde als aan de achterzijde kunt u alleen videobeelden van één camera tegelijkertijd vastleggen.

U geeft over het algemeen geen waarde door aan de parameter name. U kunt getCamera() gebruiken om een verwijzing naar de standaardcamera te retourneren. In het deelvenster Camera (dat verderop in deze sectie wordt besproken) kan de gebruiker de standaardcamera opgeven.

U kunt ActionScript niet gebruiken om de bevoegdheid van een gebruiker voor toegang tot de camera in te stellen op Allow of Deny, maar u kunt wel het dialoogvenster voor camera-instellingen in Adobe Flash Player Settings weergeven, waarin de gebruiker de camerabevoegdheden kan instellen. Wanneer een SWF-bestand dat de methode attachCamera() gebruikt om de camera die wordt geretourneerd door de methode getCamera() te koppelen aan een object Video of NetStream, geeft Flash Player een dialoogvenster weer waarin de gebruiker toegang tot de camera kan toestaan of weigeren. (Zorg dat het toepassingsvenster ten minste 215 x 138 pixels groot is; dit is de minimale grootte die Flash Player nodig heeft om het dialoogvenster weer te geven.) Wanneer de gebruiker op het dialoogvenster voor camera-instellingen reageert, retourneert de gebeurtenishandler status een informatieobject dat het antwoord van de gebruiker aangeeft: Camera.muted geeft aan dat de gebruiker toegang tot een camera heeft geweigerd; Camera.Unmuted geeft aan dat de gebruiker toegang tot een camera heeft toegestaan. Gebruik de eigenschap muted om te bepalen of de gebruiker het gebruik van de camera heeft toegestaan of geweigerd zonder de gebeurtenis status te verwerken.

In Flash Player kan de gebruiker permanente privacyinstellingen voor een bepaald domein opgeven door bij uitvoering van een SWF-bestand met de rechtermuisknop te klikken (Windows en Linux) of de Control-toets ingedrukt te houden en te klikken (Macintosh) en Instellingen te selecteren, het dialoogvenster Privacy te openen en Onthouden te selecteren. Wanneer de gebruiker Remember selecteert, vraagt Flash Player de gebruiker niet meer of SWF-bestanden uit dit domein wel of geen toegang hebben tot de camera.

Opmerking: De methode attachCamera() zal het dialoogvenster niet aanroepen om de toegang tot de camera toe te staan of te weigeren als de gebruiker de toegang heeft geweigerd door Remember te selecteren in het dialoogvenster van Flash Player Settings. In dit geval kunt u de gebruiker vragen de instelling Allow of Deny te wijzigen door het deelvenster Flash Player Privacy voor de gebruiker weer te geven met Security.showSettings(SecurityPanel.PRIVACY).

Wanneer getCamera() de waarde null retourneert, wordt de camera gebruikt door een andere toepassing of zijn er geen camera’s op het systeem geïnstalleerd. Als u wilt bepalen of er camera’s zijn geïnstalleerd, gebruikt u de eigenschap names.length. Wanneer u het deelvenster Camera van Flash Player Settings wilt weergeven, waarin de gebruiker de camera kan kiezen waarnaar wordt verwezen door getCamera(), gebruikt u Security.showSettings(SecurityPanel.CAMERA).

Het scannen van de hardware op camera’s neemt tijd in beslag. Wanneer het runtime-programma ten minste één camera vindt, wordt de hardware niet opnieuw gescand gedurende de levensduur van de spelerinstantie. Wanneer het runtime-programma echter geen camera's vindt, wordt de hardware elke keer gescand wanneer getCamera wordt aangeroepen. Dit is nuttig wanneer de camera aanwezig is, maar is uitgeschakeld. Wanneer uw SWF-bestand een knop Opnieuw bevat die getCamera aanroept, kan Flash Player de camera vinden zonder dat de gebruiker het SWF-bestand opnieuw hoeft te openen.

Parameters

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);
        
        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            if (Camera.isSupported)
            {
                cam = Camera.getCamera();
                
                 if (!cam) {
                    myTextField.text = "No camera is installed.";
                    
                } else if (cam.muted) {
                    myTextField.text = "To enable the use of the camera,\n"
                                     + "please click on this text field.\n" 
                                     + "When the Flash Player Settings dialog appears,\n"
                                     + "make sure to select the Allow radio button\n" 
                                     + "to grant access to your camera.";
    
                    myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
    
                }else {
                    myTextField.text = "Connecting";
                    connectCamera(); 
                }
       
                addChild(myTextField);
    
                t.addEventListener(TimerEvent.TIMER, timerHandler);
            }else {
                myTextField.text = "The Camera class is not supported on this device.";
            }
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

Hiermee wordt door de toepassing toestemming gevraagd voor de camera.

Geeft op welke videoframes volledig worden verzonden (hoofdframes) in plaats van te worden geïnterpoleerd door het algoritme voor videocompressie. Deze methode is alleen van toepassing wanneer u video verzendt via Flash Media Server.

Het Flash-algoritme voor videocompressie comprimeert video door alleen datgene te verzenden wat is gewijzigd sinds het vorige videoframe; deze delen worden beschouwd als geïnterpoleerde frames. Frames van een video kunnen worden geïnterpoleerd op basis van de inhoud van het vorige frame. Een hoofdframe is echter een volledig videoframe dat niet is geïnterpoleerd op basis van voorgaande frames.

Als u wilt bepalen welke waarde u het beste kunt instellen voor parameter keyFrameInterval parameter, moet u rekening houden met het bandbreedtegebruik en de toegankelijkheid tijdens het afspelen van video. Wanneer u bijvoorbeeld een hogere waarde opgeeft voor keyFrameInterval (er worden minder vaak hoofdframes verzonden), neemt het bandbreedtegebruik af. Hierdoor kan het echter langer duren om de afspeelkop op een bepaald punt in de video te plaatsen aangezien mogelijk meer voorafgaande videoframes moeten worden geïnterpoleerd voordat de video kan worden hervat.

Wanneer u daarentegen een lagere waarde opgeeft voor keyFrameInterval (er worden vaker hoofdframes verzonden), neemt het bandbreedtegebruik toe omdat vaker gehele videoframes worden verzonden. Het kan echter minder tijd kosten om een bepaald videoframe in de opgenomen video te vinden.

Parameters

Verwante API-elementen

Geeft op of een gecomprimeerde videostream moet worden gebruikt voor een lokale weergave van de camera. Deze methode is alleen van toepassing wanneer u video verzendt via Flash Media Server. Wanneer ucompress op true instelt, kunt u nauwkeuriger nagaan hoe de video eruitziet voor gebruikers die deze in realtime bekijken.

Hoewel een gecomprimeerde stream handig is voor testdoeleinden, zoals de kwaliteitsinstellingen van video vooraf bekijken, kost dit zeer veel verwerkingskracht aangezien de lokale weergave niet eenvoudig wordt gecomprimeerd. Deze wordt namelijk gecomprimeerd, bewerkt voor verzending zoals via een live-verbinding en vervolgens weer gedecomprimeerd voor lokale weergave.

Wanneer u de hoeveelheid compressie wilt instellen die wordt gebruikt wanneer u compress op true instelt. gebruikt uCamera.setQuality().

Parameters

Verwante API-elementen

Stelt de cameravastleggingsmodus in op de native modus die het beste overeenkomt met de opgegeven vereisten. Wanneer de camera geen native modus heeft die overeenstemt met alle doorgegeven parameters, selecteert de runtime een vastleggingsmodus die het meest overeenkomt met de gevraagde modus. Dit kan ertoe leiden dat het beeld wordt bijgesneden en dat frames wegvallen.

De runtime laat standaard zo nodig frames vallen om de afbeeldingsgrootte te handhaven. Geef false door voor de parameter favorArea om het aantal verwijderde frames te minimaliseren, zelfs als dit betekent dat u de grootte van de afbeelding moet beperken.

Wanneer de runtime een native modus kiest, wordt geprobeerd waar mogelijk de gevraagde hoogte-breedteverhouding te handhaven. Wanneer u bijvoorbeeld de opdracht myCam.setMode(400, 400, 30) gebruikt en de maximale waarden voor de breedte en hoogte op de camera 320 en 288 zijn, stelt de runtime zowel de breedte als de hoogte in op 288. Wanneer u deze instellingen op dezelfde waarden instelt, behoudt de runtime de hoogte-breedteverhouding 1:1 die u hebt aangevraagd.

Gebruik de eigenschappen width, height en fps om de waarden te bepalen die zijn toegewezen aan deze eigenschappen nadat de runtime de modus heeft geselecteerd die het meest overeenkomt met de aangevraagde waarden.

Wanneer u Flash Media Server gebruikt, kunt u ook afzonderlijke frames vastleggen of een fotosequentie maken. Zie NetStream.attachCamera() voor meer informatie.

Parameters

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.events.MouseEvent;
    import flash.display.StageScaleMode;

    public class Camera_setModeExample extends Sprite {
        private var cam:Camera;
        private var vid:Video;

        public function Camera_setModeExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;

            cam = Camera.getCamera();
            
            if (!cam) {
                trace("No camera is installed.");
            }else {
                connectCamera();
            }
        }

        private function connectCamera():void {
            vid = new Video();
            vid.width = cam.width;
            vid.height = cam.height; 
            vid.attachCamera(cam);
            addChild(vid);    

            stage.addEventListener(MouseEvent.CLICK, clickHandler);
        }
    
        private function clickHandler(e:MouseEvent):void {

            switch (cam.width) {
                case 160:
                cam.setMode(320, 240, 10); 
                break;
                case 320:
                cam.setMode(640, 480, 5); 
                break;
                default:
                cam.setMode(160, 120, 15); 
                break;
            } 

            removeChild(vid);           
            connectCamera();
        }
    }
}

Geeft op hoeveel beweging nodig is om de gebeurtenis activity te verzenden. Stelt optioneel het aantal milliseconden in dat zonder activiteit moet verstrijken voordat de runtime de beweging als gestopt beschouwt en de gebeurtenis verzendt.

Opmerking: video kan worden weergegeven ongeacht de waarde van de parameter motionLevel. Deze parameter bepaalt alleen wanneer en onder welke omstandigheden de gebeurtenis wordt verzonden, niet of video daadwerkelijk wordt vastgelegd of afgespeeld.

Als u wilt voorkomen dat de camera beweging detecteert, geeft u de waarde 100 door voor de parametermotionLevel; hierdoor wordt de gebeurtenis activity nooit verzonden. (U zou deze waarde waarschijnlijk alleen voor testdoeleinden gebruiken, bijvoorbeeld om eventuele handlers, die normaal worden geactiveerd wanneer de gebeurtenis wordt verzonden, tijdelijk uit te schakelen.)

Gebruik de eigenschap activityLevel om de hoeveelheid beweging te bepalen die de camera momenteel detecteert. Waarden voor bewegingsgevoeligheid komen direct overeen met activiteitwaarden. Een volledig gebrek aan beweging komt overeen met de activiteitwaarde 0. Voortdurende beweging komt overeen met de activiteitwaarde 100. Uw activiteitwaarde is lager dan de waarde voor bewegingsgevoeligheid wanneer u niet beweegt. Wanneer u beweegt, overschrijden de activiteitwaarden vaak de waarde voor bewegingsgevoeligheid.

Het doel van deze methode lijkt op de methode Microphone.setSilenceLevel(). Beide methoden worden gebruikt om op te geven wanneer de gebeurtenis activity moet worden verzonden. Deze methoden hebben echter een ander effect op het publiceren van streams:

• Microphone.setSilenceLevel() is ontworpen om de bandbreedte te optimaliseren. Wanneer een audiostream als stil wordt beschouwd, worden geen audiogegevens verzonden. Er wordt in plaats daarvan één bericht verzonden dat aangeeft dat een stilte is gestart.
• Camera.setMotionLevel() is ontworpen om beweging te detecteren en heeft geen effect op het bandbreedtegebruik. Zelfs wanneer een videostream geen beweging detecteert, wordt video verzonden.

Parameters

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.ActivityEvent;

    public class Camera_setMotionLevelExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_setMotionLevelExample() {
            myTextField = new TextField();
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            cam = Camera.getCamera();
            
            if (!cam) {
                myTextField.text = "No camera is installed.";

            }else {
                myTextField.text = "Waiting to connect.";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                cam.setMotionLevel(5, 1000);
                cam.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
        }

        private function activityHandler(e:ActivityEvent):void {
            if (e.activating == true) {
                t.start();    
            } else {
                myTextField.text = "Everything is quiet.";
                t.stop();
            }    
        }

        private function timerHandler(event:TimerEvent):void {
             myTextField.x = 10;
             myTextField.y = cam.height + 20;
             myTextField.text = "There is some activity. Level: " + cam.activityLevel;
        }
    }
}

Stelt de maximale bandbreedte per seconde of de vereiste beeldkwaliteit van de huidige uitgaande videofeed in. Deze methode is gewoonlijk alleen van toepassing wanneer u video verzendt via Flash Media Server.

Gebruik deze methode om op te geven welk element van de uitgaande videofeed belangrijker is voor de toepassing: bandbreedtegebruik of beeldkwaliteit.

• Geef een waarde door voor bandwidth en 0 voor quality om aan te geven dat het gebruik van bandbreedte voorrang heeft. De runtime verzendt video op de hoogst mogelijke kwaliteit binnen de opgegeven bandbreedte. De runtime vermindert zo nodig de beeldkwaliteit om te voorkomen dat de opgegeven bandbreedte wordt overschreden. In het algemeen neemt de kwaliteit af naarmate de beweging toeneemt.
• Geef 0 door voor bandwidth en een numerieke waarde voor quality om aan te geven dat kwaliteit voorrang heeft. De runtime gebruikt zoveel bandbreedte als vereist is om de opgegeven kwaliteit te handhaven. De runtime verlaagt zo nodig de framesnelheid om de beeldkwaliteit te handhaven. In het algemeen neemt het bandbreedtegebruik toe wanneer de beweging toeneemt.
• Wanneer u wilt opgeven dat zowel de bandbreedte als de kwaliteit even belangrijk zijn, geeft u numerieke waarden door voor beide parameters. De runtime verzendt video met de opgegeven kwaliteit die de opgegeven bandbreedte niet overschrijdt. De runtime verlaagt zo nodig de framesnelheid om de beeldkwaliteit te handhaven zonder de opgegeven bandbreedte te overschrijden.

Parameters

Verwante API-elementen

Wordt verzonden wanneer een camera een sessie begint of eindigt. Roep Camera.setMotionLevel() aan om het aantal bewegingen op te geven dat nodig is om een gebeurtenis activity met de activating-waarde true te activeren, of de tijd die moet verstrijken zonder activiteit voordat een gebeurtenis activity met de activating-waarde false wordt geactiveerd.

Deze gebeurtenis heeft de volgende eigenschappen:

Wordt verzonden wanneer de toepassing toestemming vraagt de camera op het apparaat te gebruiken. Controleer de waarde van de eigenschap status om te bepalen of de toestemming is verleend of geweigerd

Verwante API-elementen

Wordt verzonden wanneer een camera de status meldt. Voordat u de camera opent, geeft de runtime een dialoogvenster Privacy weer, waarmee gebruikers toegang tot hun camera kunnen toestaan of weigeren. Wanneer de waarde van de eigenschap code Camera.Muted is, heeft de gebruiker het SWF-bestand de toegang tot de camera van de gebruiker geweigerd. Wanneer de waarde van de eigenschap code "Camera.Unmuted" is, heeft de gebruiker het SWF-bestand de toegang tot de camera van de gebruiker toegestaan.

Opmerking: deze gebeurtenis wordt niet verzonden op het AIR-platform. Deze wordt alleen gebruikt in Flash Player.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Verzonden nadat een nieuw cameraframe wordt verwerkt door de runtime en beschikbaar is om te worden gekopieerd.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Opmerking: dit voorbeeld werkt alleen correct wanneer een camera op uw computer is aangesloten.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Camera;
    import flash.media.Video;

    public class CameraExample extends Sprite {
        private var video:Video;
        
        public function CameraExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var camera:Camera = Camera.getCamera();
            
            if (camera != null) {
                camera.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
                video = new Video(camera.width * 2, camera.height * 2);
                video.attachCamera(camera);
                addChild(video);
            } else {
                trace("You need a camera.");
            }
        }
        
        private function activityHandler(event:ActivityEvent):void {
            trace("activityHandler: " + event);
        }
    }
}