TextLine  - AS3

행에서 가장 높은 문자의 맨 위와 기준선 사이의 픽셀 수를 지정합니다. 그래픽 요소만 포함하고 있는 TextLine의 경우 ascent는 0으로 설정됩니다.

줄의 아톰 수, 즉 개별 요소의 수입니다. 여기에는 공백과 그래픽 요소가 포함됩니다.

행에서 가장 아래까지 내려가는 문자의 맨 밑과 기준선 사이의 픽셀 수를 지정합니다. 그래픽 요소만 포함하고 있는 TextLine의 경우 descent는 0으로 설정됩니다.

텍스트 행에 그래픽 요소가 포함되어 있는지 여부를 나타냅니다.

관련 API 요소

텍스트 줄에 탭이 포함되어 있는지 여부를 나타냅니다.

행과 연관된 TextLineMirrorRegion 객체를 포함하는 Vector입니다. 이러한 객체가 없을 경우 null입니다.

관련 API 요소

TextBlock의 이전 TextLine이거나, 현재 줄이 블록의 마지막 줄이거나 줄의 유효성이 TextLineValidity.STATIC인 경우 null입니다.

관련 API 요소

TextBlock의 이전 TextLine이거나, 이 줄이 블록의 첫 번째 줄이거나 줄의 유효성이 TextLineValidity.STATIC인 경우 null입니다.

관련 API 요소

행의 일부이지만 표시되지 않는 그래픽 요소 및 모든 후행 공백을 나타내는 U+FDEF 문자를 비롯하여 행이 된 텍스트 블록에 있는 원시 텍스트의 길입니다.

관련 API 요소

행을 만들 때 TextBlock.createTextLine() 메서드에 지정된 폭입니다. 이 값은 변경에 따라 행을 다시 줄바꿈해야 할지 결정하는 데 유용합니다.

관련 API 요소

이 텍스트 줄을 포함하는 TextBlock이거나, 줄의 유효성이 TextLineValidity.STATIC인 경우 null(줄과 TextBlock 사이의 연결이 끊어졌음을 의미함)입니다.

관련 API 요소

텍스트 블록의 원시 텍스트에 있는 행의 첫 번째 문자 인덱스입니다.

관련 API 요소

텍스트 줄의 논리적 높이입니다. 이 값은 ascent와 descent를 더한 것과 같습니다. 잉크로 그린 높이를 가져오려면 상속된 height 속성에 액세스합니다.

TextBlock.baselineZero가 표의 문자인지 여부에 따라 표의 문자 맨 위/맨 아래 또는 어센트/디센트로 행의 경계를 이루는 기준선 사이의 간격을 기반으로 하여 값이 계산됩니다. 이러한 기준선을 계산할 때 그래픽 요소는 고려 대상에서 제외됩니다.

관련 API 요소

텍스트 행의 논리적 폭(텍스트 엔진에서 행을 배치하는 데 사용하는 폭)입니다. 상속된 width 속성에 액세스하여 그려진 모든 픽셀의 경계 상자의 실제 폭을 가져옵니다.

관련 API 요소

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

줄에서 가장 높은 문자 또는 그래픽의 맨 위와 기준선 사이의 픽셀 수를 지정합니다.

줄에서 가장 아래까지 내려가는 문자 또는 그래픽의 맨 밑과 기준선 사이의 픽셀 수를 지정합니다.

텍스트 줄의 총 논리적 높이입니다. 이 값은 totalAscent와 totalDescent를 더한 것과 같습니다.

정렬되지 않은 경우의 줄 폭입니다. 텍스트가 정렬되지 않은 경우 이 값은 textWidth와 같습니다. 텍스트가 정렬된 경우 이 값은 정렬되지 않았을 때의 길이이며, textWidth는 실제 행 폭을 나타냅니다. 예를 들어 다음 String을 정렬하여 폭을 500으로 하고 TextBlock.createTextLine()에 전송하면 실제 폭은 500이고 정렬되지 않은 폭은 268.9921875입니다.

관련 API 요소

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

임의 데이터를 텍스트 줄과 연관시키는 방법을 응용 프로그램에 제공합니다.

텍스트 줄의 현재 유효성을 지정합니다. 이 속성의 값은 TextLineValidity 클래스의 멤버에서 찾을 수 있습니다. 이 속성을 설정하기 위한 규칙은 다음과 같습니다.

TextLineValidity의 멤버가 아닌 문자열로 유효성이 설정된 경우 줄은 USER_INVALID로 간주됩니다. USER_INVALID는 이러한 값을 나타내기 위해 여기에 사용되는 추상화입니다.

TextBlock의 내용이 수정된 경우 Flash 런타임은 영향을 받은 텍스트 줄, 이전 줄 및 그 뒤의 모든 줄을 INVALID로 표시합니다. 변경 후에 그 영향을 받은 첫 번째 행에 있던 내용 중 일부를 이전 행에 포함할 수 있도록 하려면 이전 행을 유효하지 않은 것으로 표시해야 합니다.

새로 줄바꿈한 행은 항상 VALID입니다. Flash 런타임은 이후 줄을 VALID에서 POSSIBLY_INVALID 또는 INVALID로 변경할 수 있습니다. 줄 바꿈이 일치할 경우 POSSIBLY_INVALID 줄을 VALID로 변경하고 그렇지 않을 경우 INVALID로 변경할 수 있습니다.

응용 프로그램 코드에서는 VALID 줄을 INVALID 또는 USER_INVALID로 표시하고 USER_INVALID 줄을 VALID로 표시할 수 있습니다. 응용 프로그램 코드에서는 줄을 POSSIBLY_INVALID로 표시할 수 없습니다.

응용 프로그램 코드에서는 모든 줄을 STATIC으로 표시할 수 있습니다. 이렇게 하면 block 멤버가 null이 됩니다. STATIC 텍스트 줄의 모든 그래픽 요소는 STATIC 텍스트 줄이 원래 파생되었던 텍스트 블록에서 줄 바꿈된 새 텍스트 줄의 일부인 경우 제거된 다음 다시 부모가 됩니다.

관련 API 요소

TextLine의 기본 내용을 XML 문자열로 덤프합니다. 이는 자동화된 테스트에 유용할 수 있으며 텍스트, 서식 및 레이아웃 정보를 포함합니다.

다음에는 출력에 대한 설명이 나와 있습니다.

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

참고: 이 메서드의 출력 내용과 형식은 나중에 변경될 수 있습니다. Adobe에서는 이 메서드가 이전 버전과 호환된다고 보장하지 않습니다.

관련 API 요소

이 메서드는 더 이상 사용되지 않으며 아무런 영향을 주지 않습니다. 아톰 데이터는 압축되므로 메모리 효율성을 관리하는 데 주요한 고려 사항이 되지 않습니다.

관련 API 요소

지정된 인덱스에 있는 아톰의 양방향 수준을 가져옵니다. TextBlock.bidiLevel과 행을 구성하는 문자의 유니코드 양방향 속성의 조합에 의해 결정됩니다.

예를 들어 히브리어 텍스트로 텍스트 블록을 시작하면 TextBlock.bidiLevel이 1로 설정되어 오른쪽에서 왼쪽이 기본 방향으로 사용됩니다. 텍스트 내에 영어 인용문(왼쪽에서 오른쪽)이 있으면 해당 텍스트의 AtomBidiLevel은 2입니다. 영어 내에 아랍어 부분(오른쪽에서 왼쪽)이 있으면 해당 부분의 AtomBidiLevel은 3이 됩니다. 아랍어 내에 숫자(왼쪽에서 오른쪽)가 있으면 숫자의 AtomBidiLevel이 4로 설정됩니다. 아톰이 끝나는 행에 관계없이 히브리어 아톰은 AtomBidiLevel이 1이고, 영어 아톰은 AtomBidiLevel이 2이고, 아랍어 아톰은 AtomBidiLevel이 3이고, 숫자 아톰은 AtomBidiLevel이 4입니다.

매개 변수

관련 API 요소

텍스트 행을 기준으로 지정된 인덱스에 있는 아톰의 경계를 가져옵니다. 지정된 아톰의 경계는 줄에서의 가로 위치(x), 줄에서의 세로 위치(y), 폭(w) 및 높이(h)로 구성됩니다. 모든 값의 단위는 픽셀입니다.

매개 변수

지정된 인덱스에 있는 기준선을 따라 측정된 아톰의 중심을 가져옵니다.

매개 변수

지정된 인덱스에 있는 아톰의 그래픽을 가져오거나 아톰이 문자인 경우 null을 가져옵니다.

매개 변수

charIndex 매개 변수에 의해 지정된 문자를 포함하는 아톰의 인덱스를 반환하거나 문자가 행의 아톰에 포함되지 않은 경우 -1을 반환합니다. charIndex는 행을 포함하는 텍스트 블록의 전체 내용을 기준으로 합니다.

매개 변수

x 및 y 매개 변수에 의해 지정된 점에 있는 아톰의 인덱스를 반환하거나 해당 점에 아톰이 없는 경우 -1을 반환합니다.

이 메서드는 전역 좌표를 취하므로 MouseEvent.stageX 및 MouseEvent.stageY 속성을 이 메서드에 쉽게 사용할 수 있습니다.

매개 변수

지정된 인덱스에 있는 아톰의 텍스트 블록 시작 인덱스를 가져옵니다.

매개 변수

지정된 인덱스에 있는 아톰의 텍스트 블록 끝 인덱스를 가져옵니다.

매개 변수

지정된 인덱스에 있는 아톰의 회전을 가져옵니다. 이 속성에는 TextRotation 상수가 사용됩니다. 아톰의 회전은 요소 및 행의 누적 회전입니다. 주요 용도는 TextLine과 상호 작용할 때 캐럿(커서)의 방향을 설정하는 것입니다.

매개 변수

관련 API 요소

지정된 인덱스에 있는 아톰의 왼쪽에 단어 경계를 설정할지 여부를 지정합니다. 단어 경계는 행을 이루는 문자의 유니코드 속성을 기반으로 결정됩니다.

매개 변수

TextBlock.baselineZero를 기준으로 지정된 기준선의 위치를 가져옵니다.

매개 변수

관련 API 요소

해당 mirror 속성이 mirror 매개 변수에 지정된 값과 일치하는 행의 첫 번째 TextLineMirrorRegion을 반환하거나 일치하는 항목이 없을 경우 null을 반환합니다.

양방향 수준 및 줄바꿈 여부에 따라서는 TextElement 한 개로 하나 이상의 행에 여러 TextLineMirrorRegion 객체가 만들어질 수 있습니다. nextRegion 및 previousRegion 속성은 텍스트 요소 하나에서 생성된 모든 미러 영역을 연결합니다.

매개 변수

관련 API 요소

텍스트 행의 최대 요청 폭(픽셀 단위)입니다. TextBlock.createTextLine() 메서드는 width 매개 변수에 값이 지정되지 않은 경우 이 상수를 기본값으로 사용합니다.

관련 API 요소

1. 라이브러리에 NumericStepper 구성 요소를 추가합니다.
2. 이 코드를 FLA와 같은 디렉토리에 TextLineExample.as로 저장합니다.
3. FLA의 속성 창에서 클래스를 TextLineExample로 설정합니다.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}