TextBlock  - AS3

WYSIWYG(What-You-See-Is-What-You-Get) 인쇄 품질을 낮추는 대신 화면의 표시 품질을 높이도록 지정합니다. 장치 글꼴 렌더링 중 하위 픽셀 글리프 위치 지정을 지원하지 않지만 비선형 크기 조절을 지원하는 플랫폼 및 글꼴의 경우, 이 속성을 true로 설정하면 WYSIWYG 인쇄 품질이 낮아지는 대신(특히 포인트 크기가 작을 때) 해당 메트릭을 사용할 수 있습니다. 비선형 글꼴 크기 조절은 각 글리프의 폭을 선별적으로 조절하여 픽셀 물리기로 발생하는 보기 좋지 않은 간격을 숨기는 방식으로 이루어집니다.

하위 픽셀 글리프 위치 지정을 지원하는 플랫폼에서는 이 플래그가 무시됩니다.

이 플래그는 포함된 글꼴 렌더링에는 아무런 영향을 주지 않습니다.

기본값은 true입니다.

내용에 관계없이 블록에서 만든 모든 행에 대한 기준선을 결정하는 데 사용되는 글꼴입니다. 기준선은 글꼴 및 글꼴 크기에 따라 달라집니다.

기본값은 null입니다. 기준선 글꼴이 null이면 기준선 글꼴 크기가 무시되고 모든 줄의 기준선은 해당 줄에서 가장 큰 텍스트의 글꼴과 크기에 따라 결정됩니다. baselineFontDescription과 baselineFontSize를 모두 지정하면 내용에 상관없이 텍스트 블록의 모든 줄에 대한 기준선을 결정하는 데 이러한 속성 사용됩니다. 이 조합은 주로 아시아권 언어의 입력 체계에 유용합니다.

관련 API 요소

블록에서 만든 행의 기준선을 계산하는 데 사용되는 글꼴 크기입니다. 기준선은 글꼴 및 글꼴 크기에 따라 달라집니다.

기본값은 12입니다. 기준선 글꼴이 null이면 기준선 글꼴 크기가 무시되고 모든 줄의 기준선은 해당 줄에서 가장 큰 텍스트의 글꼴과 크기에 따라 결정됩니다.

관련 API 요소

이 블록에서 만든 행에 대해 y=0인 위치에 배치할 기준선을 지정합니다. 이 속성에 사용할 수 있는 값은 TextBaseline 클래스의 멤버입니다.

기본값은 TextBaseline.ROMAN입니다.

이 속성의 값을 설정하려면 다음 문자열 값을 사용합니다.

관련 API 요소

텍스트 블록의 양방향 단락 포함 수준을 지정합니다. 일반적으로 LTR 단락(영어, 일본어 등)에 0을 사용하고 RTL 단락(아랍어, 히브리어 등)에 1을 사용합니다. 0 또는 1이 아닌 값은 특수한 경우에 사용하도록 예약되어 있습니다. 자세한 내용은 UAX#9, "Unicode Bidirectional Algorithm"(http://www.unicode.org/reports/tr9/)을 참조하십시오.

기본값은 0입니다.

bidiLevel을 수정하면 이전에 줄바꿈했던 모든 행의 유효성이 TextLineValidity.INVALID로 변경됩니다. bidiLevel을 변경하고 나면 firstInvalidLine 속성이 firstLine 속성과 같아지며 TextBlock에서 모든 줄을 다시 줄 바꿈해야 합니다.

관련 API 요소

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

텍스트 블록의 내용을 보유합니다. ContentElement는 기본 클래스이므로 ContentElement의 하위 클래스인 TextElement, GraphicElement 또는 GroupElement의 인스턴스를 content에 할당합니다. TextElement 객체에는 String이 포함되고, GraphicElement 객체에는 DisplayObject가 포함되고, GroupElement에는 한 개 이상의 TextElement, GraphicElement 또는 다른 GroupElement 객체가 들어 있는 Vector 객체가 포함됩니다. TextElement는 텍스트로만 이루어진 단락에 사용하고, GraphicElement는 그래픽에 사용하고, GroupElement는 텍스트와 그래픽 요소 또는 이러한 요소의 여러 인스턴스 및 다른 GroupElement 객체의 조합에 사용합니다.

기본값은 null입니다.

content 속성을 수정하면 이전에 만든 모든 줄의 유효성이 TextLineValidity.INVALID로 변경됩니다. content를 변경하고 나면 firstInvalidLine 속성이 firstLine 속성과 같아지며 TextBlock의 모든 줄을 다시 줄 바꿈해야 합니다.

관련 API 요소

텍스트 블록에서 TextLine.validity가 TextLineValidity.VALID가 아닌 첫 줄을 식별합니다.

기본값은 null입니다.

관련 API 요소

TextBlock의 첫 번째 TextLine입니다(있을 경우).

기본값은 null입니다.

관련 API 요소

TextBlock의 마지막 TextLine입니다(있을 경우).

기본값은 null입니다.

관련 API 요소

텍스트 블록의 여러 텍스트 줄을 한꺼번에 회전합니다. 이를 적용하려면 관련 lineRotation을 설정한 후에 createTextLine() 메서드를 호출합니다. 기본값은 TextRotation.ROTATE_0입니다.

모든 글리프의 최종 회전은 ElementFormat.textRotation, ContentElement.textRotation 및 TextBlock.lineRotation의 값에 따라 결정됩니다.

TextBlock.lineRotation은 일반적으로 아시아권 언어 텍스트에 사용됩니다. 세로 방향 일본어 텍스트의 단락을 만들려면 다음을 수행합니다.

1. TextBlock.lineRotation 속성을 TextRotation.ROTATE_90으로 설정합니다.
2. 내용의 ElementFormat.textRotation 속성을 기본값인 TextRotation.AUTO로 둡니다.

TextRotation 클래스에 정의되어 있는 다음 상수를 사용하여 이 속성의 값을 설정합니다.

관련 API 요소

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

텍스트 블록의 텍스트에 대한 탭 정지를 TabStop 객체의 Vector 형태로 지정합니다.

기본값은 탭 정지가 지정되지 않았음을 나타내는 null입니다. 탭 정지가 지정되지 않았거나 삽입점이 마지막으로 지정된 탭 정지를 벗어나는 경우 런타임에서 기본적으로 0.5인치 탭을 만듭니다.

tabStops 속성을 설정한 경우 TextBlock이 내부 용도로 Vector의 복사본을 만듭니다. 원본 Vector 또는 내용을 수정해도 TextBlock에 영향을 주지 않습니다. tabStops 속성을 쿼리하면 내부 Vector 복사본이 반환됩니다. 이번에도 반환된 벡터 또는 그 내용을 수정해도 TextBlock에 영향을 주지 않습니다.

관련 API 요소

줄을 만들 때 사용할 TextJustifier를 지정합니다.

기본값은 생성된 기본 TextJustifier 객체입니다.

textJustifier 속성을 설정한 경우 TextBlock이 내부 용도로 객체의 복사본을 만듭니다. 원래 객체를 수정해도 TextBlock에 영향을 주지 않습니다. textJustifier 속성을 쿼리하면 내부 객체 복사본이 반환됩니다. 이번에도 반환된 객체를 수정해도 TextBlock에 영향을 주지 않습니다.

관련 API 요소

createTextLine() 작업의 결과를 나타냅니다. 블록의 내용을 변경하면 이전에 줄 바꿈한 줄이 무효화되고 이 속성이 null로 재설정됩니다.

기본값은 null입니다.

이 속성의 값은 TextLineCreationResult에 있습니다.

관련 API 요소

임의 데이터를 텍스트 블록과 연관시키는 방법을 응용 프로그램에 제공합니다. 이 데이터는 수정 날짜나 제작자 이름과 같이 내용에 관련된 참조 정보일 수도 있고 처리 과정에서 사용되는 캐시된 데이터일 수도 있습니다.

TextBlock 객체를 만듭니다.

관련 API 요소

previousLine 매개 변수에 지정된 점에서 시작하고 width 매개 변수에 지정된 점에서 줄 바꿈하여 해당 내용으로부터 텍스트 행을 만들도록 텍스트 블록에 지시합니다. 텍스트 줄은 TextLine 객체이며 이를 표시 목록에 추가할 수 있습니다.

이미 줄바꿈된 텍스트 블록 범위에 줄바꿈을 적용하면 줄바꿈이 발생하는 영역 및 그 외의 영역에서 행의 유효성이 변경될 수 있습니다. 행의 상태가 VALID에서 INVALID 또는 POSSIBLY_INVALID로 변경될 수 있습니다. 이전에 줄바꿈했고 상태가 POSSIBLY_INVALID인 행과 새로 줄바꿈한 행이 완벽하게 정렬되는 경우 이전에 줄바꿈한 행과 이후의 모든 POSSIBLY_INVALID 행이 VALID 상태로 다시 변경됩니다. TextLineValidity의 멤버가 아닌 값으로 설정된 행의 유효성은 VALID로 변경되지 않으며 INVALID로 변경될 수 있습니다. 텍스트 행의 줄바꿈을 시작하거나 계속할 위치를 확인하려면 텍스트 블록이 변경된 후 firstInvalidLine 속성을 검사해야 합니다.

텍스트에 유니코드 ZWSP(Zero Width Space) 문자를 삽입하여 단어를 인위적으로 분할할 수 있습니다. 이는 올바른 줄바꿈을 위해 사전이 필요한 태국어와 같은 언어에 유용할 수 있습니다. Flash 런타임에는 이러한 사전이 포함되어 있지 않습니다.

메모리 오버헤드를 줄이기 위해서는 원하는 줄이 모두 생성되면 컨테이너 크기 조정 등으로 인해 줄을 반복적으로 다시 줄 바꿈해야 하는 경우를 제외하고 releaseLineCreationData() 메서드를 호출하여 텍스트 블록에서 줄 바꿈과 연관된 임시 데이터를 지워야 합니다.

매개 변수

관련 API 요소

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

TextBlock의 기본 내용을 XML 문자열로 덤프합니다. 이는 자동화된 테스트에 유용할 수 있으며 텍스트, 서식 및 레이아웃 정보를 포함합니다.

다음에는 출력에 대한 설명이 나와 있습니다.

	 >block<
	 	[0-N LINE]
	 >/block<
	 

각 줄의 출력에 대한 설명은 TextLine.dump() 메서드를 참조하십시오.

참고: 출력의 내용과 형식은 나중에 변경될 수 있습니다. Adobe에서는 이 메서드가 이전 버전과 호환된다고 보장하지 않습니다.

관련 API 요소

지정된 인덱스의 문자는 제외하고, 지정된 문자 인덱스 뒤에 나오는 다음 번 아톰 경계의 인덱스를 찾습니다. 아톰 경계 사이의 문자들이 결합하여 TextLine에서 'e'와 결합 양음 악센트 같은 한 개의 아톰을 형성합니다.

매개 변수

관련 API 요소

지정된 인덱스의 문자를 포함하지 않고 지정된 문자 인덱스 뒤에 나오는 다음 번 단어 경계의 인덱스를 찾습니다. 단어 경계는 문자의 유니코드 속성을 기반으로 결정됩니다.

매개 변수

지정된 인덱스의 문자를 포함하지 않고 지정된 문자 인덱스 앞에 나오는 이전 아톰 경계의 인덱스를 찾습니다. 아톰 경계 사이의 문자들이 결합하여 TextLine에서 'e'와 결합 양음 악센트 같은 한 개의 아톰을 형성합니다.

매개 변수

관련 API 요소

지정된 인덱스의 문자를 포함하지 않고 지정된 문자 인덱스 앞에 나오는 이전 단어 경계의 인덱스를 찾습니다. 단어 경계는 문자의 유니코드 속성을 기반으로 결정됩니다.

매개 변수

charIndex 매개 변수에 의해 지정된 문자를 포함하는 TextLine을 반환합니다.

매개 변수

기존 텍스트 줄을 다시 사용하여 해당 내용에서 텍스트 줄을 만들도록 텍스트 블록에 지시합니다(previousLine 매개 변수에 지정된 점에서 시작하여 width 매개 변수에 지정된 점에서 줄 바꿈됨). 텍스트 줄은 TextLine 객체이며 이를 표시 목록에 추가할 수 있습니다. 기존 텍스트 줄을 다시 사용하면 객체 생성이 감소되므로 성능이 향상됩니다.

다시 만들어지는 textLine은 이를 포함하는 모든 텍스트 블록(있는 경우)에서 해제됩니다. 또한 DisplayObjectContainer, InteractiveObject 및 DisplayObject에서 상속된 속성을 포함한 모든 속성은 기본값으로 재설정됩니다. 마지막으로 그래픽 요소 및 다른 장식을 포함하여 줄의 모든 자식은 제거되고, 줄의 모든 이벤트 리스너도 제거됩니다. 성능을 높이기 위해, 이 완료 재설정의 유일한 예외는 줄 자체가 부모에서 제거되지 않는다는 것입니다.

이미 줄바꿈된 텍스트 블록 범위에 줄바꿈을 적용하면 줄바꿈이 발생하는 영역 및 그 외의 영역에서 행의 유효성이 변경될 수 있습니다. 행의 상태가 VALID에서 INVALID 또는 POSSIBLY_INVALID로 변경될 수 있습니다. 이전에 줄바꿈했고 상태가 POSSIBLY_INVALID인 행과 새로 줄바꿈한 행이 완벽하게 정렬되는 경우 이전에 줄바꿈한 행과 이후의 모든 POSSIBLY_INVALID 행이 VALID 상태로 다시 변경됩니다. TextLineValidity의 멤버가 아닌 값으로 설정된 행의 유효성은 VALID로 변경되지 않으며 INVALID로 변경될 수 있습니다. 텍스트 행의 줄바꿈을 시작하거나 계속할 위치를 확인하려면 텍스트 블록이 변경된 후 firstInvalidLine 속성을 검사해야 합니다.

텍스트에 유니코드 ZWSP(Zero Width Space) 문자를 삽입하여 단어를 인위적으로 분할할 수 있습니다. 이는 올바른 줄바꿈을 위해 사전이 필요한 태국어와 같은 언어에 유용할 수 있습니다. Flash 런타임에는 이러한 사전이 포함되어 있지 않습니다.

메모리 오버헤드를 줄이기 위해서는 원하는 줄이 모두 생성되면 컨테이너 크기 조정 등으로 인해 줄을 반복적으로 다시 줄 바꿈해야 하는 경우를 제외하고 releaseLineCreationData() 메서드를 호출하여 텍스트 블록에서 줄 바꿈과 연관된 임시 데이터를 지워야 합니다.

매개 변수

관련 API 요소

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

텍스트 줄 생성과 연관된 모든 임시 데이터를 해제하도록 텍스트 블록에 지시합니다. 응용 프로그램의 메모리 사용량을 최소화하려면 텍스트 블록에서의 텍스트 줄 생성을 완료한 후 releaseLineCreationData() 메서드를 호출해야 합니다. 하지만 컨테이너의 크기를 조정하는 경우에서와 같이 줄 다시 바꿈을 위한 성능을 최대화하려면 releaseLineCreationData() 메서드를 호출하면 안 됩니다. 메모리와 성능의 균형을 어떻게 맞춰야 하는지는 응용 프로그램에 따라 다릅니다.

변경하지 않을 텍스트에 권장되는 프로세스는 텍스트 블록을 초기화하고 createTextLine() 메서드를 원하는 출력을 생성하는 데 필요한 만큼 호출한 다음 releaseLineCreationData() 메서드를 호출하는 것입니다.

관련 API 요소

TextBlock을 통해 유지 관리되는 행의 목록에서 텍스트 행의 범위를 제거합니다. 이렇게 하면 다른 참조가 없는 경우 행이 가비지 수집됩니다.

제거된 줄의 textBlock, nextLine 및 previousLine 멤버를 null로 설정합니다. 제거된 줄과 TextBlock에서 제거된 줄 다음에 나오는 모든 줄의 validity를 TextLineValidity.INVALID로 설정합니다.

매개 변수

관련 API 요소