Video  - AS3

事後処理中に、デコードされたビデオに適用されるフィルターのタイプを示します。デフォルト値の 0 に設定すると、ビデオコンプレッサは必要に応じて非ブロックフィルターを適用します。

ビデオの圧縮によって、好ましくない生成結果となる場合があります。deblocking プロパティを使用して、ブロッキングと、On2 コーデックを使用して圧縮されたビデオのリンギングを低減するフィルターを設定できます。

ブロッキングとは、各ビデオフレームを構成するブロックの境界と境界の間に見られる不具合のことです。リンギングとは、ビデオイメージ内の要素の周囲が歪曲することです。

次の 2 つの非ブロックフィルターを使用できます。1 つは Sorenson コーデックにあり、もう 1 つは On2 VP6 コーデックにあります。さらに、On2 VP6 コーデックを使用する際にはリンギング除去フィルターを使用できます。フィルターを設定するには、次のいずれかの値を使用します。

• 0 - ビデオコンプレッサは必要に応じて非ブロックフィルターを適用します。
• 1 - 非ブロックフィルターを使用しません。
• 2 - Sorenson 非ブロックフィルターを使用します。
• 3 - On2 ビデオにのみ、On2 非ブロックフィルターを使用し、リンギング除去フィルターは使用しません。
• 4 - On2 ビデオにのみ、On2 非ブロックフィルターとリンギング除去フィルターを使用します。
• 5 - On2 ビデオにのみ、On2 非ブロックフィルターとパフォーマンスが向上した On2 リンギング除去フィルターを使用します。

Sorenson コーデックの使用時にビデオに 2 より大きい値を選択すると、Sorenson デコーダはデフォルトで 2 になります。

非ブロックフィルターを使用すると、全体的な再生のパフォーマンスに影響します。高帯域幅のビデオには、通常は必要ありません。非ブロックフィルターを有効にしたビデオは、処理能力の低いシステムでは再生が困難なことがあります。

ビデオを拡大 / 縮小する際にスムージング（補間）するかどうかを指定します。スムージングを行うには、ランタイムが高品質モード（デフォルト）である必要があります。デフォルト値は false（スムージングなし）です。

Flash Player 9.0.115.0 以降のバージョンを使用するビデオ再生では、このプロパティを true に設定して、ミップマッピングイメージ最適化を利用します。

ビデオストリームの高さをピクセル単位で指定する整数です。ライブストリームの場合、この値はビデオストリームをキャプチャしている Camera オブジェクトの Camera.height プロパティと同じです。録画済みビデオファイルの場合、この値はビデオの高さです。NetStream.Video.DimensionChange イベントは、録画済みビデオの場合に、この値が変更されると送出されます。

このプロパティは、ステージ上の実際の Video オブジェクトのサイズとは関係なく、キャプチャしたのと同じサイズでユーザーに対してビデオを表示する場合などに使用します。

関連する API エレメント

ビデオストリームの幅をピクセル単位で指定する整数です。ライブストリームの場合、この値はビデオストリームをキャプチャしている Camera オブジェクトの Camera.width プロパティと同じです。録画済みビデオファイルの場合、この値はビデオの幅です。NetStream.Video.DimensionChange イベントは、録画済みビデオの場合に、この値が変更されると送出されます。

このプロパティは、ステージ上の実際の Video オブジェクトのサイズとは関係なく、キャプチャしたのと同じサイズでユーザーに対してビデオを表示する場合などに使用します。

関連する API エレメント

新しい Video インスタンスを作成します。width パラメーターと height パラメーターの値が指定されていない場合は、デフォルト値が使用されます。Video オブジェクトの初期構築後に、Video.width と Video.height を使用して幅と高さのプロパティを設定することもできます。新しい Video オブジェクトを作成する際に、幅または高さに 0 は設定できません。0 を渡すと、デフォルト値が適用されます。

Video オブジェクトの作成後、DisplayObjectContainer.addChild() メソッドまたは DisplayObjectContainer.addChildAt() メソッドを呼び出して、親 DisplayObjectContainer オブジェクトに Video オブジェクトを追加できます。

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

アプリケーション内の Video オブジェクトの境界内に表示するカメラからのビデオストリームを指定します。

このメソッドは、ユーザーがキャプチャしたライブビデオを Video オブジェクトに添付するために使用します。ライブビデオをキャプチャした同じコンピューターまたはデバイスで、ローカルにライブビデオを再生することも、Flash Media Server に送信し、サーバーを使用して、他のユーザーにストリームすることもできます。

注意：iOS AIR アプリケーションでは、アプリケーションが GPU レンダリングモードを使用している際にはカメラビデオは表示されません。

パラメーター

関連する API エレメント

アプリケーション内の Video オブジェクトの境界内に表示するビデオストリームを指定します。ビデオストリームは、NetStream.play() で再生されるビデオファイル、Camera オブジェクト、または null です。ビデオファイルを使用する場合、ファイルはローカルファイルシステムまたは Flash Media Server に保存できます。netStream 引数の値に null を指定すると、Video オブジェクト内でビデオが再生されなくなります。

ビデオファイルにオーディオしか含まれない場合、このメソッドを使用する必要はありません。ビデオファイルのオーディオ部分は、NetStream.play() を呼び出すと自動的に再生されます。ビデオファイルに関連付けられたオーディオを制御するには、ビデオファイルを再生する NetStream オブジェクトの soundTransform プロパティを使用します。

パラメーター

関連する API エレメント

Video オブジェクトに現在表示されているイメージ（ビデオストリームではない）をクリアします。このメソッドは、現在のイメージを処理する場合に便利です。例えば、最後のイメージをクリアしたり、Video オブジェクトを非表示にせずにスタンバイ情報を表示したりできます。

関連する API エレメント

この例では、Video オブジェクトと NetStream オブジェクトを作成し、Video.attachNetStream() および NetStream.play() メソッドを呼び出すコードがハンドラー関数に配置されます。ハンドラーは、NetConnection オブジェクトへの接続が成功した場合にのみ呼び出されます。つまり、netStatus イベントが、成功したことを示す code プロパティと共に info オブジェクトを返す場合です。接続に成功するまで待ってから、NetStream.play() を呼び出すことをお勧めします。

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }