Bitmap  - AS3

L'oggetto BitmapData al quale viene fatto riferimento.

Determina se l'oggetto Bitmap viene agganciato o meno al pixel più vicino. La classe PixelSnapping include i seguenti valori possibili:

• PixelSnapping.NEVER - L'aggancio ai pixel non viene eseguito.
• PixelSnapping.ALWAYS - L'immagine viene sempre agganciata al pixel più vicino, indipendentemente dalla trasformazione.
• PixelSnapping.AUTO - L'immagine bitmap viene agganciata al pixel più vicino se è disegnata senza alcuna rotazione o inclinazione e con un fattore di scala compreso tra 99,9% e 100,1%. Se queste condizioni sono soddisfatte, l'immagine bitmap viene disegnata con un fattore di scala del 100% e agganciata al pixel più vicino. Internamente, questo valore consente di disegnare l'immagine con la massima velocità possibile utilizzando il renderer dei vettori.

Determina se la bitmap viene smussata durante la modifica in scala. Se è true, la bitmap viene smussata durante la modifica in scala. Se è false, la bitmap non viene smussata.

Inizializza un oggetto Bitmap in modo che faccia riferimento all'oggetto BitmapData specificato.

	bitmapData:BitmapData (default = null) — L'oggetto BitmapData al quale viene fatto riferimento.
	pixelSnapping:String (default = "auto") — Indica se l'oggetto Bitmap viene agganciato o meno al pixel più vicino.
	smoothing:Boolean (default = false) — Indica se la bitmap viene smussata durante la modifica in scala. Ad esempio, gli esempi seguenti mostrano la stessa bitmap modificata in scala in base a un fattore 3, con smoothing impostato su false (sinistra) e su true (destra):

const IMAGE_URL:String = "http://www.helpexamples.com/flash/images/logo.png";
 
var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldr_complete);
ldr.load(new URLRequest(IMAGE_URL));
 
var bitmap1:Bitmap;
var bitmap2:Bitmap;
var bitmap3:Bitmap;
var bitmap4:Bitmap;
 
function ldr_complete(evt:Event):void {
    var bmp:Bitmap = ldr.content as Bitmap;
 
    bitmap1 = new Bitmap(bmp.bitmapData);
    bitmap1.x = 100;
    bitmap1.y = 100;
    bitmap1.rotation = 0;
    addChild(bitmap1);
 
    bitmap2 = new Bitmap(bmp.bitmapData);
    bitmap2.x = 200;
    bitmap2.y = 100;
    bitmap2.rotation = 90;
    addChild(bitmap2);
 
    bitmap3 = new Bitmap(bmp.bitmapData);
    bitmap3.x = 300;
    bitmap3.y = 100;
    bitmap3.rotation = 180;
    addChild(bitmap3);
 
    bitmap4 = new Bitmap(bmp.bitmapData);
    bitmap4.x = 400;
    bitmap4.y = 100;
    bitmap4.rotation = 270;
    addChild(bitmap4);
}

1. Viene creata una proprietà url, che corrisponde alla posizione e al nome del file di immagine.
2. La funzione di costruzione della classe chiama il metodo configureAssets(), il quale a propria volta chiama il metodo completeHandler().
3. configureAssets() crea un oggetto Loader che crea un'istanza di un listener di eventi che viene inviata quando il metodo completeHandler() completa la manipolazione delle immagini.
4. A questo punto, il metodo buildChild() crea una nuova istanza di un oggetto URLRequest, request, passando url in modo che il nome e la posizione del file siano noti.
5. L'oggetto request viene quindi passato al metodo loader.load(), che carica l'immagine in memoria utilizzando un oggetto di visualizzazione.
6. L'immagine viene quindi posizionata nell'elenco di visualizzazione, che visualizza immediatamente l'immagine sullo schermo in corrispondenza delle coordinate x = 0, y = 0.
7. Il metodo completeHandler() esegue quindi le seguenti operazioni:
   1. Crea un secondo oggetto Loader, insieme a un oggetto Bitmap, il quale viene inizializzato con l'oggetto Loader.
   2. Crea un secondo oggetto Bitmap, duplicate, che a propria volta chiama il metodo duplicateImage(), che crea un duplicato dell'immagine originale.
   3. Crea un nuovo oggetto BitmapData che viene assegnato all'oggetto BitmapData dell'oggetto duplicate.
   4. Crea un nuovo oggetto Rectangle inizializzato con le stesse coordinate e gli stessi valori di larghezza e altezza dell'immagine originale.
   5. Crea un nuovo oggetto Point, che ha come valore predefinito x = 0, y = 0.
   6. Crea le variabili seguenti:
      • operation: applica il nuovo colore quando il valore di soglia è superiore o uguale all'originale.
      • threshold: il valore rispetto al quale viene confrontato ogni pixel viene impostato sul grigio chiaro con un'impostazione alfa pari a 0xCC.
      • color: il colore su cui saranno impostati i pixel per passare la prova della soglia (in questo caso, giallo uniforme).
      • mask: imposta l'esatto opposto del colore (blu trasparente).
      • copySource: impostato su false, che indica che i valori dei pixel non vengono copiati se il valore di soglia non passa. Questo valore non ha alcun significato poiché l'immagine viene duplicata e vengono modificati solo i pixel che passano la prova della soglia.
   7. Chiama il metodo threshold() mediante le variabili che lo precedono. L'equazione della soglia risultante è la seguente: if (current pixel Value & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) then set pixel to 0xFFFFFF00.

Note:

• È necessario compilare il file SWF con "Sicurezza riproduzione locale" impostato su "Accedi solo ai file locali".
• Questo esempio richiede che un file di nome Image.gif venga collocato nella stessa directory del file SWF.
• Si consiglia di utilizzare un'immagine con una larghezza massima di circa 80 pixel.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}