ContextMenu  - AS3

Een instantie van de klasse ContextMenuBuiltInItems met de volgende eigenschappen: forwardAndBack, loop, play, print, quality, rewind, save en zoom. Wanneer u deze variabelen op false instelt, worden de overeenkomende menu-items uit het opgegeven object ContextMenu verwijderd. Deze eigenschappen kunnen worden opgesomd en zijn standaard op true ingesteld.

Opmerking: In AIR bevatten contextmenu's geen ingebouwde items.

Verwante API-elementen

Een instantie van de klasse ContextMenuClipboardItems met de volgende eigenschappen: cut, copy, paste, delete, selectAll. Wanneer een van deze eigenschappen wordt ingesteld op false wordt het corresponderende item in het klembordmenu uitgeschakeld.

Verwante API-elementen

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Geeft aan of het klembordmenu moet worden gebruikt of niet. Als deze waarde true is, bepaalt de eigenschap clipboardItems welke items in het klembordmenu zijn in- of uitgeschakeld.

Als de eigenschap link niet null is, wordt deze clipBoardMenu-eigenschap genegeerd.

Een array van objecten ContextMenuItem. Elk object in de array vertegenwoordigt een contextmenu-item dat u hebt gedefinieerd. Gebruik deze eigenschap om aangepaste menu-items toe te voegen, te verwijderen of te wijzigen.

Wanneer u nieuwe menu-items wilt toevoegen, maakt u een nieuw object ContextMenuItem en voegt u deze vervolgens toe aan de array customItems (bijvoorbeeld met Array.push()). Zie ContextMenuItem voor meer informatie over het maken van menu-items.

Verwante API-elementen

De eigenschap isSupported wordt ingesteld op true als de ContextMenu-klasse op het huidige platform wordt ondersteund. Als dit niet het geval is, wordt de eigenschap ingesteld op false.

De array met aangepaste items in dit menu.

Het gebruik van deze eigenschap komt overeen met het gebruik van de eigenschap customItems. De array is gesorteerd op volgorde van weergave.

De URLRequest van de koppeling. Als deze eigenschap null is, wordt een normaal snelmenu weergegeven. Als deze eigenschap niet null is, wordt het koppelingssnelmenu weergegeven, waarvoor de opgegeven URL wordt gebruikt.

Als een koppeling is opgegeven, wordt de eigenschap clipboardMenu genegeerd.

De standaardwaarde is null.

Het aantal items in dit menu.

Maakt een object ContextMenu.

Verwante API-elementen

Voegt een menu-item onder aan het menu toe.

Wanneer u een contextmenu maakt, kunt u zowel objecten NativeMenuItem als objecten ContextMenuItem toevoegen. Het is echter raadzaam slechts één type object te gebruiken in een contextmenu, zodat alle items in het menu dezelfde eigenschappen hebben.

Parameters

Hiermee wordt een kopie van het opgegeven ContextMenu-object gemaakt. De kopie neemt alle eigenschappen over van het oorspronkelijke menuobject.

Meldt of dit menu het opgegeven menu-item bevat.

Parameters

Geeft dit menu op de opgegeven locatie weer.

Opmerking: in Flash Player wordt deze methode niet ondersteund.

Parameters

Hiermee wordt het menu-item opgehaald bij de opgegeven index.

Parameters

Haalt de positie van het opgegeven item op.

Parameters

Verbergt alle ingebouwde menu-items (met uitzondering van Instellingen) in het opgegeven object ContextMenu. Wanneer de foutopsporingsversie van Flash Player wordt uitgevoerd, wordt het menu-item Debugging weergegeven, hoewel deze gedimd is voor SWF-bestanden die foutopsporing op afstand niet hebben ingeschakeld.

Deze methode verbergt alleen de menu-items die in het standaardcontextmenu worden weergegeven; de methode heeft geen effect op items die in de bewerkmenu’s of foutmenu’s worden weergegeven.

Deze methode werkt wanneer u alle booleaanse leden van my_cm.builtInItems instelt op false. U kunt een ingebouwd item selectief zichtbaar maken door het overeenkomende lid in my_cm.builtInItems in te stellen op true.

Opmerking: In AIR bevatten contextmenu's geen ingebouwde items. Het aanroepen van deze methode heeft geen effect.

Verwante API-elementen

Hiermee worden alle items uit de lijst verwijderd.

Verwijdert het menu-item en retourneert het bij de opgegeven index.

Parameters

Wordt verzonden wanneer een gebruiker voor het eerst een contextmenu genereert, maar voordat de inhoud van het contextmenu wordt weergegeven. Hierdoor kan uw programma de set contexmenu-items wijzigen voordat het menu wordt weergegeven. De gebruiker genereert het contextmenu door met de rechtermuisknop op het aanwijsapparaat te klikken.

Deze gebeurtenis heeft de volgende eigenschappen:

1. Een eigenschap myContextMenu wordt gedeclareerd en vervolgens toegewezen aan een nieuw object ContextMenu en een eigenschap redRectangle van het type Sprite wordt gedeclareerd.
2. De methode removeDefaultItems() wordt aangeroepen. Deze verwijdert alle ingebouwde contextmenu-items behalve Print.
3. De methode addCustomMenuItems() wordt aangeroepen, waardoor een menu-item met de naam Red to Black in de array defaultItems wordt geplaatst met de methode push() van Array. Een gebeurtenislistener menuItemSelect wordt toegevoegd aan het object ContextMenuItem en de daaraan gekoppelde methode wordt menuItemSelectHandler() genoemd. Deze methode drukt instructies af met trace() wanneer toegang wordt verkregen tot het contextmenu en Red to Black wordt geselecteerd. Ook wordt het rode vierkant verwijderd en vervangen door een zwart vierkant.
4. Een gebeurtenislistener van het type menuSelect wordt toegevoegd, samen met de gekoppelde methode menuSelectHandler, die elke keer dat een item in het contextmenu wordt geopend, drie instructies afdrukt met trace().
5. Vervolgens tekent addChildren() een rood vierkant en voegt het toe aan het weergaveoverzicht waar het direct wordt weergegeven.
6. Tot slot wordt myContextMenu toegewezen aan het contextmenu van de sprite redRectangle, zodat het aangepaste contextmenu alleen wordt weergegeven wanneer de muisaanwijzer zich boven het vierkant bevindt.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}