ContextMenuItem  - AS3

Pakket	flash.ui
Klasse	public final class ContextMenuItem
Overerving	ContextMenuItem NativeMenuItem EventDispatcher Object

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

De klasse ContextMenuItem representeert een item in het snelmenu. Elk object ContextMenuItem heeft een bijschrift (tekst) dat wordt weergegeven in het contextmenu. Wanneer u een nieuw contextmenu-item aan een contextmenu wilt toevoegen, voegt u dat toe aan de array customItems van een object ContextMenu.

Met de eigenschappen van de klasse ContextMenuItem kunt u specifieke menu-items in- of uitschakelen en kunt u ze zichtbaar of onzichtbaar maken.

U schrijft een gebeurtenishandler voor de gebeurtenis menuItemSelect om functionaliteit aan het menu-item toe te voegen als de gebruiker het selecteert.

Aangepaste menu-items worden boven in het contextmenu weergegeven, boven ingebouwde items. Ingebouwde en aangepaste menu-items worden gescheiden door een scheidingsbalk. AIR bevat geen ingebouwde items en de volgende beperkingen zijn niet van toepassing op inhoud in de AIR-toepassingssandbox.

Beperkingen:

• U kunt maximaal 15 aangepaste items aan een contextmenu toevoegen.
• Elk bijschrift moet tenminste één zichtbaar teken bevatten.
• Besturingstekens, nieuwe-regeltekens en overige witruimtetekens worden genegeerd.
• Een bijschrift mag niet langer zijn dan 100 tekens.
• Bijschriften die identiek zijn aan ingebouwde menu-items, of een ander aangepast item, worden genegeerd, of het overeenkomstige teken zichtbaar is of niet. Menubijschriften worden vergeleken met ingebouwde bijschriften of bestaande aangepaste bijschriften zonder acht te slaan op hoofdletters, leestekens of witruimte.
• De volgende bijschriften zijn niet toegestaan, maar de woorden kunnen gebruikt worden in combinatie met andere woorden om een aangepast bijschrift te vormen (bijvoorbeeld: 'Plakken' is niet toegestaan, maar 'Plakken kaas' is wel toegestaan):

   Save
   Zoom In
   Zoom Out
   100%
   Show All
   Quality
   Play
   Loop
   Rewind
   Forward
   Back
   Movie not loaded
   About
   Print
   Show Redraw Regions
   Debugger
   Undo
   Cut
   Copy
   Paste
   Delete
   Select All
   Open
   Open in new window
   Copy link
   

• Geen van de volgende woorden mag afzonderlijk in een aangepast bijschrift worden weergegeven of in combinatie met andere woorden:

   Adobe
   Macromedia
   Flash Player
   Settings
   

Opmerking: wanneer de speler wordt uitgevoerd op een niet-Engelstalig systeem, worden de tekenreeksen van de bijschriften vergeleken met zowel de Engelse lijst als de gelokaliseerde equivalenten.

Bekijk de voorbeelden

Verwante API-elementen

---

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}