ContextMenuEvent  - AS3

Het weergaveoverzichtobject waaraan het menu is gekoppeld. Dit zou het muisdoel (mouseTarget) of één van de afstammingen van zijn weergaveoverzicht kunnen zijn.

Geeft aan of de eigenschap mouseTarget om veiligheidsredenen op null is ingesteld. Als de nominale waarde van menuTarget een referentie is naar een DisplayObjectin een andere beveiligingssandbox, wordt menuTarget ingesteld op null tenzij er een machtiging in beide richtingen is over de sandboxgrenzen heen. Deze toestemming kan worden ingesteld door Security.allowDomain() aan te roepen vanuit een SWF-bestand of door vanaf de server een beleidsbestand beschikbaar te stellen voor een afbeeldingsbestand. In dat geval moet de vlag LoaderContext.checkPolicyFile worden ingesteld tijdens het laden van de afbeelding.

Verwante API-elementen

Het weergaveoverzichtobject waarop de gebruiker met de rechtermuisknop heeft geklikt om het contextmenu weer te geven. Dit kan het weergaveoverzichtobject kunnen zijn waar het menu aan is gekoppeld (contextMenuOwner) of een van de afstammingen van zijn weergaveoverzicht.

De waarde van deze eigenschap kan in twee gevallen null zijn: Als er geen muisdoel is, bijvoorbeeld wanneer u de muis over iets op de achtergrond beweegt; of als er wel een muisdoel is, maar dit zich bevindt in een beveiligingssandbox waartoe u geen toegang hebt. Gebruik de eigenschap isMouseTargetInaccessible() om vast te stellen welke van deze redenen van toepassing is.

Verwante API-elementen

Maakt een Event-object dat specifieke informatie bevat over gebeurtenissen Menu. Gebeurtenisobjecten worden als parameters aan gebeurtenislisteners doorgegeven.

Verwante API-elementen

Maakt een kopie van het object ContextMenuEvent en stelt de waarde van elke eigenschap in zodat deze overeenkomt met die van het origineel.

Retourneert een tekenreeks die alle eigenschappen van het object ContextMenuEvent bevat. De tekenreeks heeft de volgende indeling:

[ContextMenuEvent type= value bubbles= value cancelable= value ... contextMenuOwner= value ]

Definieert de waarde van de eigenschap type van een gebeurtenisobject menuItemSelect.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject menuSelect.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

1. De eigenschap myContextMenu wordt gedeclareerd en vervolgens toegewezen aan een nieuw object ContextMenu en de eigenschap redRectangle (van het type Sprite) wordt gedeclareerd.
2. De methode removeDefaultItems() wordt aangeroepen. Deze methode verwijdert alle ingebouwde contextmenuitems behalve Afdrukken.
3. De methode addCustomMenuItems() wordt aangeroepen. Deze methode plaatst een menu-item Reverse Colors in de array defaultItems met behulp van de methode push() van Array. Een gebeurtenislistener menuItemSelect wordt toegevoegd aan het object ContextMenuItem en de daaraan gekoppelde methode wordt menuItemSelectHandler() genoemd. Deze methode drukt enkele instructies trace() af wanneer de gebruiker Reverse Colors selecteert in het contextmenu. Bovendien wordt het rode vierkant zwart en de zwarte tekst wordt rood.
4. Ondertussen wordt in de constructor een gebeurtenislistener menuSelect toegevoegd samen met de gekoppelde methodemenuSelectHandler(), die iedere keer dat een item in het contextmenu wordt geselecteerd drie instructies trace() afdrukt.
5. De constructor roept addChildren() aan, die een rood vierkant tekent en het aan het weergaveoverzicht toevoegt, dat onmiddellijk het vierkant weergeeft.
6. Tot slot wordt myContextMenu toegewezen aan het contextmenu van de eigenschap redRectangle, zodat het aangepaste contextmenu alleen wordt weergegeven wanneer de muisaanwijzer zich boven het vierkant bevindt.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}