ContextMenu  - AS3

Un'istanza della classe ContextMenuBuiltInItems con le proprietà seguenti: forwardAndBack, loop, play, print, quality, rewind, save e zoom. Se si impostano queste proprietà su false, vengono rimosse le voci di menu corrispondenti dall'oggetto ContextMenu specificato. Queste proprietà sono enumerabili e sono impostate su true per impostazione predefinita.

Nota: in AIR, i menu di scelta rapida non hanno voci predefinite.

Elementi API correlati

Un'istanza della classe ContextMenuClipboardItems con le proprietà seguenti: cut, copy, paste, delete, selectAll. Se impostate una di queste proprietà su false, viene disattivata la voce di menu corrispondente nel menu degli Appunti.

Elementi API correlati

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Specifica se deve essere utilizzato o meno il menu Appunti. Se questo valore è true, la proprietà clipboardItems determina quali elementi sono attivati o disattivati nel menu degli Appunti.

Se la proprietà link non è null, questa proprietà clipBoardMenu viene ignorata.

Un array di oggetti ContextMenuItem. Ogni oggetto dell'array rappresenta un menu di scelta rapida che è stato definito. Utilizzate questa proprietà per aggiungere, rimovete o modificate queste voci di menu personalizzate.

Per aggiungere nuove voci di menu, create un oggetto ContextMenuItem e successivamente aggiungerlo all'array customItems (ad esempio, mediante Array.push()). Per ulteriori informazioni sulla creazione delle voci di menu, vedete la sezione relativa alla classe ContextMenuItem.

Elementi API correlati

La proprietà isSupported è impostata su true se la classe ContextMenu è supportata nella piattaforma corrente, altrimenti è impostata su false.

L'array di voci personalizzate del menu.

Questa proprietà è analoga alla proprietà customItems. L'array viene ordinato in base all'ordine di visualizzazione.

URLRequest del collegamento. Se questa proprietà è null, viene visualizzato un menu di scelta rapida standard. Se questa proprietà non è null, viene visualizzato il menu di scelta rapida del collegamento che agisce sull'url specificato.

Se è specificato link, la proprietà clipboardMenu viene ignorata.

Il valore predefinito è null.

Il numero di voci del menu.

Crea un oggetto ContextMenu.

Elementi API correlati

Aggiunge una voce di menu in fondo al menu.

Quando create un menu di scelta rapida, potete aggiungere sia oggetti NativeMenuItem che oggetti ContextMenuItem. Tuttavia, è consigliabile utilizzare solo un tipo di oggetto in un menu di scelta rapida in modo che tutte le voci del menu abbiano le stesse proprietà.

Parametri

Crea una copia dell’oggetto ContextMenu specificato. La copia eredita tutte le proprietà dell’oggetto menu originale.

Segnala se il menu contiene la voce di menu specificata.

Parametri

Visualizza il menu nella posizione specificata.

Nota: in Flash Player, questo metodo non è supportato.

Parametri

Ottiene la voce di menu nella posizione di indice specificata.

Parametri

Ottiene la posizione della voce specificata.

Parametri

Nasconde tutte le voci di menu incorporate (a eccezione di Settings, o Impostazioni) nell'oggetto ContextMenu. Se è in esecuzione la versione di debug di Flash Player, viene visualizzata la voce di menu Debug (per i file SWF per cui non è attivato il debug remoto, la voce di menu è disattivata).

Questo metodo nasconde solo le voci dei menu di scelta rapida standard; non ha alcun effetto sulle voci che fanno parte del menu Modifica o dei menu di errore.

Questo metodo funziona impostando tutti i membri booleani di my_cm.builtInItems su false. È possibile rendere visibile una voce di menu incorporata in modo selettivo impostandone il membro corrispondente in my_cm.builtInItems su true.

Nota: in AIR, i menu di scelta rapida non hanno voci predefinite. La chiamata a questo metodo non ha alcun effetto.

Elementi API correlati

Rimuove tutte le voci dal menu.

Rimuove e restituisce la voce di menu nella posizione di indice specificata.

Parametri

Inviato quando un utente genera per la prima volta un menu di scelta rapida, ma prima che il contenuto del menu venga visualizzato. Questo consente al programma di modificare il set delle voci del menu di scelta rapida prima di visualizzare il menu. L'utente genera il menu di scelta rapida facendo clic con il pulsante destro del dispositivo di puntamento.

Questo evento ha le seguenti proprietà:

1. Una proprietà di nome myContextMenu viene dichiarata e quindi assegnata a un nuovo oggetto ContextMenu, quindi viene dichiarata una proprietà redRectangle del tipo Sprite.
2. Viene chiamato il metodo removeDefaultItems(), che rimuove tutte le voci incorporate del menu di scelta rapida ad eccezione di Print.
3. Viene chiamato il metodo addCustomMenuItems(), che inserisce la voce di menu Red to Black nell'array defaultItems utilizzando il metodo push() di Array. Viene aggiunto un listener di eventi menuItemSelect all'oggetto ContextMenuItem e viene chiamato il metodo associato menuItemSelectHandler(). Questo metodo genera alcune istruzioni mediante trace() ogni volta che viene aperto il menu di scelta rapida e viene selezionata la voce Red to Black. Inoltre, il quadrato rosso viene rimosso e viene sostituito da uno nero.
4. Viene aggiunto un listener di eventi del tipo menuSelect, insieme al metodo associato menuSelectHandler, che si limita a generare tre istruzioni mediante trace() ogni volta che viene aperta una voce del menu di scelta rapida.
5. Quindi, addChildren() disegna un quadrato rosso e lo aggiunge all'elenco di visualizzazione nel quale viene visualizzato immediatamente.
6. Infine, myContextMenu viene assegato al menu di sceta rapida dello sprite redRectangle in modo che il menu di scelta rapida venga visualizzato solo quando il puntatore del mouse si trova sopra il quadrato.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}