ContextMenuEvent  - AS3

L'oggetto elenco di visualizzazione al quale il menu è associato. Può trattarsi del target del mouse (mouseTarget) o di uno dei suoi antenati nell'elenco di visualizzazione.

Indica se la proprietà mouseTarget è stata impostata su null per motivi di sicurezza. Se il valore nominale di menuTarget è un riferimento a DisplayObject presente in un'altra sandbox di sicurezza, menuTarget viene impostato su null, a meno che non vi sia autorizzazione in entrambe le direzioni attraverso questa sandbox. L'autorizzazione si stabilisce chiamando Security.allowDomain() da un file SWF o fornendo un file di criteri dal server di un file di immagine e impostando il flag LoaderContext.checkPolicyFile quando si carica l'immagine.

Elementi API correlati

L'oggetto elenco di visualizzazione su cui l'utente ha fatto clic con il pulsante destro per visualizzare il menu di scelta rapida. Può trattarsi dell'oggetto dell'elenco di visualizzazione a cui è associato il menu (contextMenuOwner) o di uno dei suoi discendenti all'interno dell'elenco.

Il valore di questa proprietà può essere null in due casi: se non vi è target del mouse, ad esempio quando il mouse passa sopra a un elemento nello sfondo, oppure se esiste un target del mouse ma si trova in una sandbox a cui non si può accedere. Per individuare il motivo, utilizzate la proprietà isMouseTargetInaccessible().

Elementi API correlati

Crea un oggetto evento contenente informazioni specifiche sugli eventi di menu. Gli oggetti evento vengono passati ai listener di eventi come parametri.

Elementi API correlati

Crea una copia dell'oggetto ContextMenuEvent e imposta il valore di ogni proprietà in modo che corrisponda a quello dell'originale.

Restituisce una stringa che contiene tutte le proprietà dell'oggetto ContextMenuEvent. La stringa ha il seguente formato:

[ContextMenuEvent type= valore bubbles= valore cancelable= valore ... contextMenuOwner= value]

Definisce il valore della proprietà type di un oggetto evento menuItemSelect.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento menuSelect.

Questo evento ha le seguenti proprietà:

Elementi API correlati

1. Viene dichiarata la proprietà myContextMenu e quindi viene assegnata a un nuovo oggetto ContextMenu. Viene quindi dichiarata la proprietà redRectangle (di tipo Sprite)
2. Viene chiamato il metodo removeDefaultItems(), che rimuove tutte le voci incorporate del menu di scelta rapida ad eccezione di Print.
3. Viene chiamato il metodo addCustomMenuItems(). Questo metodo colloca una voce di menu Reverse Colors (per l'inversione dei colori) nell'array defaultItems utilizzando il metodo push() di Array. Viene aggiunto un listener di eventi menuItemSelect all'oggetto ContextMenuItem e viene chiamato il metodo associato menuItemSelectHandler(). Questo metodo stampa alcune istruzioni trace() ogni volta che l'utente seleziona la voce Reverse Colors dal menu di scelta rapida. Inoltre, il quadrato rosso diventa nero e il testo nero diventa rosso.
4. Nella funzione di costruzione viene aggiunto un listener di eventi menuSelect, unitamente al metodo associato menuSelectHandler(), che stampa semplicemente tre istruzioni trace() ogni volta che viene selezionata una voce dal menu di scelta rapida.
5. La funzione di costruzione chiama addChildren(), che disegna un quadrato rosso e lo aggiunge all'elenco di visualizzazione nel quale viene visualizzato immediatamente.
6. Viene infine assegnato myContextMenu al menu di scelta rapida della proprietà redRectangle, in modo che il menu di scelta rapida venga visualizzato solo quando il puntatore del mouse si trova sopra il quadrato.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}