ContextMenuItem  - AS3

Pacchetto	flash.ui
Classe	public final class ContextMenuItem
Ereditarietà	ContextMenuItem NativeMenuItem EventDispatcher Object

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9

La classe ContextMenuItem rappresenta una voce del menu di scelta rapida. Ciascun oggetto ContextMenuItem ha una didascalia (testo) che viene visualizzata nel menu di scelta rapida. Per aggiungere una nuova voce a un menu di scelta rapida, aggiungetela all'array customItems di un oggetto ContextMenu.

Le proprietà della classe ContextMenuItem consentono di abilitare o disabilitare voci di menu specifiche oppure di renderle visibili o invisibili.

Per aggiungere funzionalità a una voce di menu quando viene selezionata dall'utente, è possibile scrivere un gestore di eventi per l'evento menuItemSelect.

Le voci di menu personalizzate vengono visualizzate in cima al menu di scelta rapida, sopra le voci incorporate da cui sono distinte per mezzo di una barra separatrice. In AIR, non sono disponibili voci incorporate e le seguenti limitazioni non valgono per il contenuto presente nella sandbox di sicurezza.

Restrizioni:

• È possibile aggiungere un massimo di 15 voci personalizzate a un menu di scelta rapida.
• Ciascuna didascalia deve contenere almeno un carattere visibile.
• I caratteri di controllo, i caratteri newline e altri caratteri di spazio vuoto vengono ignorati.
• Nessuna didascalia può superare i 100 caratteri.
• Le didascalie identiche a una voce di menu incorporata o a un'altra voce personalizzata vengono ignorate, anche se la voce corrispondente non è visibile. Le didascalie di menu vengono confrontate con le didascalie incorporate o personalizzate esistenti senza tener conto di maiuscole/minuscole, punteggiatura o spazi vuoti.
• Le didascalie seguenti non sono consentite, ma possono essere utilizzate in combinazione con altre parole per formare una didascalia personalizzata (ad esempio, sebbene "Paste" non sia consentita, "Paste tastes great" invece lo è):

   Save
   Zoom In
   Zoom Out
   100%
   Show All
   Quality
   Play
   Loop
   Rewind
   Forward
   Back
   Movie not loaded
   About
   Print
   Show Redraw Regions
   Debugger
   Undo
   Cut
   Copy
   Paste
   Delete
   Select All
   Open
   Open in new window
   Copy link
   

• Nessuna delle parole seguenti può costituire una didascalia personalizzata di per sé o in combinazione con altre parole:

   Adobe
   Macromedia
   Flash Player
   Settings
   

Nota: quando il lettore è in esecuzione su un sistema non in lingua inglese, le stringhe delle didascalie vengono confrontate sia con l'elenco inglese che con gli equivalenti localizzati.

Vedere gli esempi

Altri esempi

Elementi API correlati

---

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}