ContextMenu  - AS3

Une occurrence de la classe ContextMenuBuiltInItems dont les propriétés sont les suivantes : forwardAndBack, loop, play, print, quality, rewind, save et zoom. La définition de ces propriétés sur false supprime les éléments de menu correspondants dans l’objet ContextMenu spécifié. Ces propriétés sont énumérables et définies sur true par défaut.

Remarque : dans AIR, les menus contextuels ne possèdent aucun élément intégré.

Eléments de l’API associés

Une occurrence de la classe ContextMenuClipboardItems dont les propriétés sont les suivantes : cut, copy, paste, delete, selectAll. Définir l’une de ces propriétés sur false désactive l’élément correspondant dans le menu du presse-papiers.

Eléments de l’API associés

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Précise si le menu du presse-papiers doit être utilisé. Si cette valeur est true, la propriété clipboardItems détermine quels éléments sont affichés ou masqués dans le menu du presse-papiers.

Si la propriété link n’est pas nulle, cette propriété clipBoardMenu est ignorée.

Tableau d’objets ContextMenuItem. Chaque objet du tableau représente un élément de menu contextuel que vous avez défini. Utilisez cette propriété pour ajouter, supprimer ou modifier ces éléments de menu personnalisés.

Pour ajouter de nouveaux éléments de menu, créez un objet ContextMenuItem, puis ajoutez-le au tableau customItems (à l’aide de Array.push(), par exemple). Pour plus d’informations sur la création d’éléments de menu, voir l’entrée de la classe ContextMenuItem.

Eléments de l’API associés

La propriété isSupported est définie sur true si la classe ContextMenu est disponible sur la plate-forme actuelle ; dans le cas contraire, elle est définie sur false.

Tableau des éléments personnalisés dans ce menu.

Utiliser cette propriété équivaut à utiliser la propriété customItems. Le tableau est trié par ordre d’affichage.

URLRequest du lien. Si cette propriété est définie sur null, un menu contextuel standard apparaît. Si cette propriété n’est pas définie sur null, le menu contextuel du lien apparaît et agit sur l’url spécifiée.

Si un lien est spécifié, la propriété clipboardMenu est ignorée.

La valeur par défaut est null.

Nombre d’éléments dans ce menu.

Crée un objet ContextMenu.

Eléments de l’API associés

Ajoute un élément de menu en bas du menu.

Lors de la création d’un menu contextuel, vous pouvez ajouter des objets NativeMenuItem ou ContextMenuItem. Nous vous conseillons toutefois de n’utiliser qu’un seul type d’objet dans un menu contextuel afin que tous les éléments du menu possèdent les mêmes propriétés.

Paramètres

Crée une copie de l’objet ContextMenu. La copie hérite de toutes les propriétés de l’objet du menu d’origine.

Indique si ce menu contient l’option de menu spécifiée.

Paramètres

Déroule ce menu à l’emplacement spécifié.

Remarque : Flash Player ne prend pas en charge cette méthode.

Paramètres

Obtient l’option de menu à l’index spécifié.

Paramètres

Obtient la position de l’option spécifiée.

Paramètres

Masque tous les éléments de menu intégrés (à l’exception de Paramètres) dans l’objet ContextMenu spécifié. Si la version de débogage de Flash Player s’exécute, l’élément de menu Débogage apparaît, bien qu’il soit grisé pour les fichiers SWF sur lesquels le débogage à distance n’est pas activé.

Cette méthode masque uniquement les éléments de menu qui s’affichent dans le menu contextuel standard ; elle n’affecte pas les éléments qui s’affichent dans les menus Edition ou d’erreur.

Cette méthode règle tous les membres booléens de my_cm.builtInItems sur false. Vous pouvez rendre visible un élément intégré de façon sélective en réglant le membre correspondant dans my_cm.builtInItems sur true.

Remarque : dans AIR, les menus contextuels ne possèdent aucun élément intégré. L’appel de cette méthode est sans effet.

Eléments de l’API associés

Supprime tous les éléments du menu.

Supprime et renvoie l’option de menu à l’index spécifié.

Paramètres

Distribué lorsqu’un utilisateur génère initialement un menu contextuel, mais avant que le contenu du menu contextuel soit affiché. Votre programme peut ainsi modifier les éléments de menu avant d’afficher le menu. L’utilisateur génère le menu contextuel en cliquant du bouton droit du périphérique de pointage.

Les propriétés de cet événement sont les suivantes :

1. Une propriété myContextMenu est déclarée, puis attribuée à un nouvel objet ContextMenu ; une propriété redRectangle de type Sprite est également déclarée.
2. La méthode removeDefaultItems() est appelée, ce qui supprime tous les éléments de menu contextuel intégrés sauf Print.
3. La méthode addCustomMenuItems() est appelée, ce qui a pour effet de placer un élément de menu appelé Red to Black (Remplacer le rouge par le noir) dans le tableau defaultItems par le biais de la méthode push() de Array. Un écouteur d’événements menuItemSelect est ajouté à l’objet ContextMenuItem et la méthode associée est appelée menuItemSelectHandler(). Cette méthode imprime certaines instructions par le biais de trace() chaque fois que le menu contextuel est affiché et l’élément Red to Black (Remplacer le rouge par le noir) sélectionné. Parallèlement, le carré rouge est supprimé et remplacé par un carré noir.
4. Un écouteur d’événements de type menuSelect est ajouté avec la méthode associée menuSelectHandler qui imprime trois instructions par le biais detrace() chaque fois qu’un élément du menu contextuel est ouvert.
5. La méthode addChildren() dessine ensuite un carré rouge et l’ajoute à la liste d’affichage dans laquelle il apparaît immédiatement.
6. Finalement, la propriété myContextMenu est attribuée au menu contextuel de l’icône animée (sprite) redRectangle si bien que le menu contextuel personnalisé s’affiche uniquement lorsque le pointeur de la souris est positionné sur le carré.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}