ContextMenuItem  - AS3

Package	flash.ui
Classe	public final class ContextMenuItem
Héritage	ContextMenuItem NativeMenuItem EventDispatcher Object

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 1.0, Flash Player 9

La classe ContextMenuItem représente un élément dans le menu contextuel. Chaque objet ContextMenuItem est doté d’une légende (texte) qui s’affiche dans le menu contextuel. Pour intégrer un nouvel élément à un menu contextuel, il vous suffit de l’ajouter au tableau customItems d’un objet ContextMenu.

Les propriétés de la classe ContextMenuItem vous permettent d’activer ou de désactiver des éléments de menu, mais aussi de les afficher ou de les masquer.

Vous écrivez un gestionnaire d’événements destiné à l’événement menuItemSelect pour ajouter une fonctionnalité à l’élément de menu lorsque l’utilisateur le sélectionne.

Les éléments de menu personnalisés s’affichent dans la partie supérieure du menu contextuel, au-dessus des éléments intégrés. Une barre de séparation sépare toujours les éléments de menu personnalisés des éléments intégrés. Dans AIR, il n’existe aucun élément intégré et les restrictions suivantes ne s’appliquent pas au contenu du sandbox de l’application AIR.

Restrictions :

• Vous ne pouvez pas ajouter plus de 15 éléments personnalisés à un menu contextuel.
• Les légendes doivent comporter au moins un caractère visible.
• Les caractères de contrôle, de nouvelle ligne et autres espaces blancs ne sont pas pris en compte.
• Aucune légende ne peut comporter plus de 100 caractères.
• Les éléments identiques à un élément de menu intégré, ou à un autre élément personnalisé, sont ignorés, que l’élément correspondant soit visible ou non. Les éléments de menu sont comparés aux éléments intégrés ou personnalisés existants sans respecter la casse, la ponctuation ou les espaces blancs.
• Les légendes suivantes sont exclues, mais elles peuvent être utilisées en conjonction avec d’autres mots pour créer une légende personnalisée (ainsi, « Paste » (Coller) n’est pas autorisée, mais la légende « Paste tastes great » (Coller au texte) est permise) :

   Save
   Zoom In
   Zoom Out
   100%
   Show All
   Quality
   Play
   Loop
   Rewind
   Forward
   Back
   Movie not loaded
   About
   Print
   Show Redraw Regions
   Debugger
   Undo
   Cut
   Copy
   Paste
   Delete
   Select All
   Open
   Open in new window
   Copy link
   

• Les termes suivants ne doivent en aucun cas apparaître dans une légende personnalisée, seuls ou avec d’autres mots :

   Adobe
   Macromedia
   Flash Player
   Settings
   

Remarque : lorsque le lecteur s’exécute sur un système qui n’est pas en anglais, les chaînes sont comparées à la liste anglaise et aux traductions équivalentes.

Consulter les exemples

Plus d’exemples

Eléments de l’API associés

---

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}