Loader  - AS3

Enthält das Stamm-Anzeigeobjekt der SWF- oder Bilddatei (JPG, PNG oder GIF), die anhand der Methode load() oder loadBytes() geladen worden ist.

Verwandte API-Elemente

Gibt ein LoaderInfo-Objekt zurück, das dem zu ladenden Objekt entspricht. LoaderInfo-Objekte werden sowohl vom Loader-Objekt als auch von geladenen Inhaltsobjekten genutzt. Das LoaderInfo-Objekt stellt Informationen und Statistiken zum Ladefortschritt der geladenen Datei bereit.

Ereignisse, die sich auf das Laden beziehen, werden durch das LoaderInfo-Objekt ausgelöst, auf das über die contentLoaderInfo-Eigenschaft des Loader-Objekts verwiesen wird. Die contentLoaderInfo-Eigenschaft wird bereits auf ein gültiges LoaderInfo-Objekt gesetzt, bevor der Inhalt geladen wird, damit Sie dem Objekt vor dem Laden Ereignis-Listener hinzufügen können.

Um nicht erfasste Fehler zu erkennen, die in einer geladenen SWF-Datei auftreten, verwenden Sie die Loader.uncaughtErrorEvents-Eigenschaft, nicht die Loader.contentLoaderInfo.uncaughtErrorEvents-Eigenschaft.

Verwandte API-Elemente

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

Ein Objekt, das ein uncaughtError-Ereignis absetzt, wenn ein nicht verarbeiteter Fehler in der SWF-Datei auftritt, die von diesem Loader-Objekt geladen wird. Fehler werden nicht erfasst, wenn sie außerhalb von try..catch-Blöcken ausgegeben werden, oder wenn ein ErrorEvent-Objekt ausgelöst wird, aber keine registrierten Listener vorhanden sind.

Beachten Sie, dass die uncaughtErrorEvents-Eigenschaft eines Loader-Objekts Ereignisse absetzt, die durch das Objekt aufsteigen, keine Ereignisse, die direkt abgesetzt werden. Sie setzt nie ein uncaughtErrorEvent in der Zielphase ab. Sie setzt das Ereignis nur in den Erfassungs- und Bubblingphasen ab. Um einen nicht erfassten Fehler in der aktuellen SWF-Datei (die SWF-Datei, in der das Loader-Objekt definiert ist) zu erkennen, verwenden Sie stattdessen die LoaderInfo.uncaughtErrorEvents-Eigenschaft.

Wenn es sich bei dem vom Loader-Objekt geladenen Inhalt um eine AVM1 (ActionScript 2)-SWF-Datei handelt, führen nicht erfasste Fehler in der AVM1-SWF-Datei nicht zu einem uncaughtError-Ereignis.

Verwandte API-Elemente

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

Erstellt ein Loader-Objekt, das Sie zum Laden von Dateien wie SWF-, JPEG-, GIF- oder PNG-Dateien verwenden können. Rufen Sie die load()-Methode auf, um den Bestandsartikel als Child-Objekt der Loader-Instanz zu laden. Anschließend können Sie das Loader-Objekt in die Anzeigeliste aufnehmen (z. B. indem Sie die addChild()-Methode einer DisplayObjectContainer-Instanz verwenden). Der Bestandsartikel erscheint auf der Bühne, noch während er geladen wird.

Sie können eine Loader-Instanz auch außerhalb der Liste verwenden, also ohne sie in einen Anzeigeobjekt-Container in der Anzeigeliste einzufügen. In diesem Modus kann die Loader-Instanz zum Laden einer SWF-Datei verwendet werden, die zusätzliche Module einer Anwendung enthält.

Um festzustellen, wann die SWF-Datei vollständig geladen ist, können Sie die Ereignisse des LoaderInfo-Objekts verwenden, das der contentLoaderInfo-Eigenschaft des Loader-Objekts zugeordnet ist. An diesem Punkt kann der Code in der Modul-SWF-Datei ausgeführt werden, um das Modul zu initialisieren und zu starten. Außerhalb der Liste kann eine Loader-Instanz auch verwendet werden, um eine SWF-Datei zu laden, die Komponenten oder Medienbestände enthält. Wiederum können Sie die Ereignisbenachrichtigungen des LoaderInfo-Objekts verwenden, um festzustellen, wann die Komponenten vollständig geladen sind. An diesem Punkt kann die Anwendung beginnen, mit den Komponenten und Medienbeständen in der Bibliothek der SWF-Datei zu arbeiten, indem die ActionScript 3.0-Klassen, die diese Komponenten und Medienbestände repräsentieren, instanziiert werden.

Um den Status eines Loader-Objekts zu ermitteln, überwachen Sie die folgenden Ereignisse, die das LoaderInfo-Objekt der contentLoaderInfo-Eigenschaft des Loader-Objekts zugeordnet hat:

• Das open-Ereignis wird ausgelöst, wenn der Ladevorgang beginnt.
• Die Ereignisse ioError bzw. securityError werden ausgelöst, wenn die Datei nicht geladen werden kann oder wenn während des Ladevorgangs ein Fehler aufgetreten ist.
• Das progress-Ereignis wird fortlaufend ausgelöst, während die Datei geladen wird.
• Das complete-Ereignis wird ausgelöst, nachdem eine Datei vollständig heruntergeladen wurde, jedoch noch bevor die Methoden und Eigenschaften des geladenen Movieclips verfügbar sind.
• Das init-Ereignis wird ausgelöst, sobald die Eigenschaften und Methoden der geladenen SWF-Datei verfügbar sind, sodass Sie mit der Bearbeitung der geladenen SWF-Datei beginnen können. Dieses Ereignis wird vor der Prozedur complete ausgelöst. In gestreamten SWF-Dateien kann das init-Ereignis um einiges früher eintreten als das complete-Ereignis. Für die meisten Zwecke ist die init-Prozedur geeignet.

Hinweise (nur iOS): In AIR-Anwendungen unter iOS können Sie nur eine SWF-Datei, die ActionScript enthält, aus dem Anwendungspaket laden. Diese Beschränkung schließt alle ActionScripts ein (z. B. Elemente mit Klassennamen, die für ActionScript exportiert wurden). Zum Laden einer SWF-Datei müssen Sie die SWF-Datei über dieselbe Anwendungsdomäne wie die übergeordnete SWF-Datei laden.

Vor AIR 3.6 können nur SWF-Dateien, die keinen ActionScript-Bytecode enthalten, geladen werden, unabhängig davon, ob sie aus dem Anwendungspaket oder über ein Netzwerk geladen werden. Anstatt eine externe SWF-Datei mit ActionScript zu laden, können Sie alternativ dazu eine SWC-Bibliothek erstellen und diese mit Ihrer SWF-Hauptdatei verknüpfen.

Diese Beschränkungen gelten nicht, wenn eine Anwendung im iOS-Simulator (ipa-test-interpreter-simulator oder ipa-debug-interpreter-simulator) oder im Interpreter-Modus (ipa-test-interpreter oder ipa-debug-interpreter) ausgeführt wird.

Verwandte API-Elemente

Bricht einen aktuell für die Loader-Instanz ausgeführten Vorgang der load()-Methode ab.

Verwandte API-Elemente

Lädt eine SWF-, JPEG-, progressive JPEG-, nicht animierte GIF- oder PNG-Datei in ein Objekt, das dem Loader-Objekt untergeordnet ist. Wenn Sie eine animierte GIF-Datei laden, wird nur das erste Bild angezeigt. Da das Loader-Objekt nur ein einziges untergeordnetes Objekt besitzen darf, beendet eine nachfolgende load()-Anforderung eine ggf. noch aktive vorherige Anforderung und beginnt einen neuen Ladevorgang.

Hinweis: In AIR 1.5 und Flash Player 10 ist die maximale Höhe oder Breite eines geladenen Bilds 8.191 Pixel, die Pixelzahl darf insgesamt 16.777.215 nicht übersteigen. (Wenn ein geladenes Bild also 8.191 Pixel breit ist, darf es nur 2.048 Pixel hoch sein.) In Flash Player 9 und niedriger und AIR 1.1 und niedriger liegt die Grenze bei je 2.880 Pixel Höhe und Breite.

Eine in ein Loader-Objekt geladene SWF- oder Bilddatei übernimmt die Positions-, Drehungs- und Skalierungseigenschaften der dem Loader-Objekt übergeordneten Anzeigeobjekte.

Mit der unload()-Methode können Sie mit dieser Methode geladene Filme oder Bilder entfernen oder einen laufenden Ladevorgang abbrechen.

Sie können eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie auf der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.

iOS-Hinweise

In AIR-Anwendungen unter iOS können Sie nur eine SWF-Datei, die ActionScript enthält, aus dem Anwendungspaket laden. Diese Beschränkung schließt alle ActionScripts ein (z. B. Elemente mit Klassennamen, die für ActionScript exportiert wurden). Zum Laden einer SWF-Datei müssen Sie die SWF-Datei über dieselbe Anwendungsdomäne wie die übergeordnete SWF-Datei laden. Dieser Vorgang wird im folgenden Beispiel gezeigt:

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

Des Weiteren können Sie eine SWF-Datei, die ActionScript-ByteCode (ABC) enthält, nicht auf iOS laden, entfernen und erneut laden. Bei einem derartigen Vorgang wird ein Laufzeitfehler 3764 zurückgegeben.

Vor AIR 3.6 können nur SWF-Dateien, die keinen ActionScript-Bytecode enthalten, geladen werden, unabhängig davon, ob sie aus dem Anwendungspaket oder über ein Netzwerk geladen werden. Anstatt eine externe SWF-Datei mit ActionScript zu laden, können Sie alternativ dazu eine SWC-Bibliothek erstellen und diese mit Ihrer SWF-Hauptdatei verknüpfen.

Diese Beschränkungen gelten nicht, wenn eine Anwendung im iOS-Simulator (ipa-test-interpreter-simulator oder ipa-debug-interpreter-simulator) oder im Interpreter-Modus (ipa-test-interpreter oder ipa-debug-interpreter) ausgeführt wird.

Loader-Sicherheit

Wenn Sie diese Methode verwenden, beachten Sie das Flash Player-Sicherheitsmodell, das in der Beschreibung der Loader-Klasse erklärt wird.

Wenn Sie in Flash Player 10 oder höher einen Multipart-Content-Type verwenden (z. B. „multipart/form-data“), der einen Upload enthält (gekennzeichnet durch einen „filename“-Parameter in einem „content-disposition“-Header innerhalb des POST-Body), so unterliegt die POST-Methode den Sicherheitsregeln für Uploads:

• Der POST-Vorgang muss als Reaktion auf eine durch den Benutzer initiierte Aktion, z. B. Mausklick oder Tastendruck, erfolgen.
• Ist die POST-Methode domänenübergreifend (das POST-Ziel befindet sich auf einem anderen Server als die SWF-Datei, die die POST-Anforderung sendet), so muss der Zielserver eine URL-Richtliniendatei bereitstellen, die den domänenübergreifenden Zugriff erlaubt.

Bei mehrteiligen Inhaltstypen muss zudem auch die Syntax gemäß Standard RFC2046 gültig sein. Scheint die Syntax ungültig zu sein, so unterliegt die POST-Methode den Sicherheitsregeln für Uploads.

Weitere Informationen zum Thema Sicherheit finden Sie im Flash Player Developer Center im Abschnitt Sicherheit.

Parameter

Verwandte API-Elemente

Lädt in einem ByteArray-Objekt gespeicherte Binärdaten.

Die loadBytes()-Methode ist eine asynchrone Methode. Sie müssen auf das "init"-Ereignis warten, bevor Sie auf die Eigenschaften eines geladenen Objekts zugreifen können.

Wenn Sie diese Methode verwenden, beachten Sie das Flash Player-Sicherheitsmodell, das in der Beschreibung der Loader-Klasse erklärt wird.

Hinweis (nur iOS): In AIR-Anwendungen unter iOS können Sie nur eine SWF-Datei, die ActionScript enthält, aus dem Anwendungspaket laden. Diese Beschränkung schließt alle ActionScripts ein (z. B. Elemente mit Klassennamen, die für ActionScript exportiert wurden). Zum Laden einer SWF-Datei müssen Sie die SWF-Datei über dieselbe Anwendungsdomäne wie die übergeordnete SWF-Datei laden.

Vor AIR 3.6 hat das Aufrufen dieser Methode unter iOS keine Auswirkungen.

Parameter

Verwandte API-Elemente

Lädt eine IFilePromise-Instanz.

Die loadFilePromise-Methode verwendet ein IFilePromise-Objekt und lädt die Binärdaten. Wenn es sich bei den Daten um einen progressiven Stream handelt, zum Beispiel ein Video, warten Sie auf die „init“- oder Fortschrittsereignisse, bevor Sie auf die Eigenschaften des geladenen Objekts zugreifen. Warten Sie andernfalls auf das complete-Ereignis, um sicherzustellen, dass die Daten vollständig geladen wurden.

Wenn Sie diese Methode verwenden, beachten Sie das Flash Player-Sicherheitsmodell, das in der Beschreibung der Loader-Klasse erklärt wird.

Parameter

Verwandte API-Elemente

Entfernt ein untergeordnetes Objekt dieses Loader-Objekts, das mit der Methode load() geladen wurde. Die property (Eigenschaft) des zugeordneten LoaderInfo-Objekts wird auf null zurückgesetzt. Das untergeordnete Objekt wird nicht unbedingt gelöscht, da andere Objekte möglicherweise Verweise darauf enthalten. Allerdings ist es dem Loader-Objekt nicht mehr untergeordnet.

Wenn Sie die unload()-Methode aufrufen, wird die contentLoaderInfo-Eigenschaft des Loader-Objekts auf null gesetzt. Alle sichtbaren Elemente, die mit der SWF geladen wurden, werden aus dem Speicher entfernt. ActionScript-Klassendefinitionen in der geladenen SWF-Datei bleiben im Speicher und der Code in derselben Anwendungsdomäne wie die geladene SWF-Datei kann auf Instanzen dieser Klassen zugreifen und neue Instanzen erstellen.

Hinweis (nur iOS): Vor AIR 3.6 hat diese Methode unter iOS keine Auswirkungen.

Es ist ratsam, vor dem Entladen einer untergeordneten SWF-Datei alle Streams in deren Objekten, z. B. LocalConnection-, NetConnection-, NetStream- oder Sound-Objekte, ausdrücklich zu schließen. Andernfalls kann es passieren, dass Audiodaten in der untergeordneten SWF-Datei unaufhörlich abgespielt werden, obwohl die SWF-Datei selbst bereits entladen worden ist. Um Streams in der untergeordneten SWF-Datei zu schließen, fügen Sie dem untergeordneten Objekt, das auf das unload-Ereignis wartet, einen Ereignis-Listener hinzu. Wenn das übergeordnete Objekt die Loader.unload()-Methode aufruft, wird für das untergeordnete Objekt das unload-Ereignis ausgelöst. Im folgenden Code wird gezeigt, wie Sie dies realisieren können:

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Verwandte API-Elemente

Versucht, die Inhalte der untergeordneten SWF-Datei zu entladen und beendet die Ausführung der Befehle geladener SWF-Dateien. Diese Methode versucht, SWF-Dateien zu entladen, die mithilfe von Loader.load() oder Loader.loadBytes() erstellt wurden, indem sie Verweise auf EventDispatcher-, NetConnection-, Timer-, Sound- oder Video-Objekte der untergeordneten SWF-Datei entfernt. Als Ergebnis tritt Folgendes für die untergeordnete SWF-Datei und die Anzeigeliste der untergeordneten SWF-Datei ein:

• Sounds werden gestoppt.
• Stage-Ereignis-Listener werden entfernt.
• Ereignis-Listener für enterFrame, frameConstructed, exitFrame, activate und deactivate werden entfernt.
• Timer werden gestoppt.
• Kamera- und Mikrofoninstanzen werden getrennt.
• Movieclips werden gestoppt.

Wenn Sie die unloadAndStop()-Methode aufrufen, wird die contentLoaderInfo-Eigenschaft des Loader-Objekts auf null gesetzt. Alle sichtbaren Elemente, die mit der SWF geladen wurden, werden aus dem Speicher entfernt. ActionScript-Klassendefinitionen in der geladenen SWF-Datei bleiben im Speicher und der Code in derselben Anwendungsdomäne wie die geladene SWF-Datei kann auf Instanzen dieser Klassen zugreifen und neue Instanzen erstellen.

Hinweis (nur iOS): Vor AIR 3.6 hat diese Methode unter iOS keine Auswirkungen.

Parameter

Verwandte API-Elemente

1. Es wird eine url-Eigenschaft erstellt, die den Speicherort und Namen der Grafikdatei angibt.
2. Im Konstruktor LoaderExample wird ein neues Loader-Objekt mit dem Namen loader erstellt, das dann an die configureListeners()-Methode übergeben wird. Dies ist in Schritt 3 beschrieben.
3. Der Konstruktor erstellt eine neue Instanz eines URLRequest-Objekts, request, mit Übergabe von url, damit der Dateiname und -speicherort bekannt sind.
4. Das request-Objekt wird im loader-Objekt an die load()-Methode übergeben, die das Bild in die Anzeigeliste lädt.
5. Im Loader wird ein clickHandler-Ereignis-Listener für das click-Ereignis registriert. Nach einem Klick mit der Maus wird das geladene Bild entfernt.
6. Die configureListeners()-Methode fügt mithilfe der folgenden Methoden sieben Ereignis-Listener hinzu:
   • Die completeHandler()-Methode wird ausgeführt, nachdem das Laden des Bilds beendet ist.
   • Die httpStatusHandler()-Methode wird ausgeführt, wenn das Bild nicht lokal geladen wird und nur wenn die Netzwerkanforderung verfügbar ist und der Flash Player diese erkennen kann.
   • Die initHandler()-Methode wird vor der completeHandler()-Methode und nach der progressHandler()-Methode ausgeführt. Das init-Ereignis ist in der Regel nützlicher, wenn SWF-Dateien geladen werden.
   • Die ioErrorHandler()-Methode wird ausgeführt, wenn die Bilddatei nicht verfügbar oder nicht zugänglich ist.
   • Die openHandler()-Methode wird ausgeführt, nachdem die Bilddatei zum ersten Mal geöffnet wurde.
   • Die progressHandler()-Methode wird ausgeführt, wenn das Laden der Bilddatei beginnt, und wird erneut ausgeführt, wenn das Laden der Bilddatei abgeschlossen ist.
   • Die unLoadHandler()-Methode wird ausgeführt, wenn das Bild entfernt wird, indem die unload()-Methode verwendet wird, wenn Benutzer auf das Bild klicken.

Beachten Sie folgende Bedingungen:

• Zur Ausführung dieses Beispiels müssen Sie eine Datei mit dem Namen „Image.gif“ in dem Ordner ablegen, in dem sich auch die kompilierte SWF-Datei befindet. Verwenden Sie ein Bild mit einem Bereich, der in die Abmessungen der SWF-Hauptdatei passt.
• Obwohl in diesem Beispiel alle verfügbaren Ereignisse des LoaderInfo-Objekts verwendet werden, ist in den meisten Situationen nur ein Teil davon erforderlich. Beim einfachen Laden einer Bilddatei reicht z. B. das complete-Ereignis (und ggf. das ioError-Ereignis) aus, sofern ein lokales Bild geladen wird.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}