Transform  - AS3

Ein ColorTransform-Objekt mit Werten, die sämtliche Farben im Anzeigeobjekt ändern.

Verwandte API-Elemente

Ein ColorTransform-Objekt, das die kombinierten auf das Anzeigeobjekt und alle übergeordneten Objekte angewendeten Farbtransformationen bis hin zur Stammebene angibt. Wenn verschiedene Farbtransformationen auf unterschiedlichen Ebenen angewendet wurden, werden diese bei dieser Eigenschaft in einem ColorTransform-Objekt verknüpft.

Verwandte API-Elemente

Ein Matrix-Objekt, das die kombinierten Transformationsmatrizen des Anzeigeobjekts und aller übergeordneten Objekte bis hin zur Stammebene angibt. Wenn verschiedene Transformationsmatrizen auf unterschiedlichen Ebenen angewendet wurden, werden sie für diese Eigenschaft in einer Matrix verknüpft. Bei größenveränderbaren, im Browser ausgeführten SWF-Inhalten berücksichtigt diese Eigenschaft auch den Unterschied zwischen Bühnenkoordinaten und Fensterkoordinaten, der durch die Änderung der Fenstergröße entsteht. Somit konvertiert diese Eigenschaft lokale Koordinaten in Fensterkoordinaten, die nicht notwendigerweise dem Koordinatenraum der Bühne entsprechen.

Ein Matrix-Objekt mit Werten, die die Skalierung, Drehung und Versetzung des Anzeigeobjekts ändern.

Wenn die matrix-Eigenschaft auf einen Wert (nicht null) eingestellt ist, ist die matrix3D-Eigenschaft null. Und wenn die matrix3D-Eigenschaft auf einen Wert (nicht null) eingestellt ist, ist die matrix-Eigenschaft null.

Verwandte API-Elemente

Erlaubt den Zugriff auf das Matrix3D-Objekt eines dreidimensionalen Anzeigeobjekts. Das Matrix3D-Objekt stellt eine Transformationsmatrix dar, die die Position und Ausrichtung des Anzeigeobjekts bestimmt. Ein Matrix3D-Objekt kann auch perspektivische Projektionen ausführen.

Wenn die matrix-Eigenschaft auf einen Wert (nicht null) eingestellt ist, ist die matrix3D-Eigenschaft null. Und wenn die matrix3D-Eigenschaft auf einen Wert (nicht null) eingestellt ist, ist die matrix-Eigenschaft null.

Verwandte API-Elemente

Erlaubt den Zugriff auf das PerspectiveProjection-Objekt eines dreidimensionalen Anzeigeobjekts. Das PerspectiveProjection-Objekt kann verwendet werden, um die Perspektiventransformation der Bühne zu ändern oder um allen untergeordneten dreidimensionalen Objekten eines Anzeigeobjekts eine Perspektiventransformation zuzuweisen.

Basierend auf dem Sichtfeld und dem Seitenverhältnis (Abmessungen) der Bühne wird dem Stammobjekt ein PerspectiveProjection-Standardobjekt zugewiesen.

Verwandte API-Elemente

Ein Rectangle-Objekt, das das Begrenzungsrechteck des Anzeigeobjekts auf der Bühne definiert.

Gibt ein Matrix3D-Objekt zurück, das den Raum eines angegebenen Anzeigeobjekts relativ zu seinem derzeitigen Raum transformiert. Mit der getRelativeMatrix3D()-Methode bewegen Sie ein dreidimensionales Anzeigeobjekt relativ zu einem anderen dreidimensionalen Anzeigeobjekt.

Parameter

Verwandte API-Elemente

1. Der TransformExample()-Konstruktor erstellt ein neues Sprite-Objekt mit dem Namen target.
2. Der TransformExample()-Konstruktor ruft die Methode draw() auf, die ein Quadrat mit Farbverlaufsfüllung im Sprite zeichnet.
3. Der TransformExample()-Konstruktor fügt dem Sprite einen click-Ereignis-Listener hinzu, der von der clickHandler()-Methode verarbeitet wird.
4. Mithilfe der clickHandler()-Methode wird ein neues Matrix-Objekt erstellt (skewMatrix), durch das ein Neigungseffekt angewendet wird. Eine weitere Matrix (tempMatrix) wird der aktuellen Transformationsmatrix des Sprites zugewiesen und dann mithilfe der concat()-Methode mit skewMatrix kombiniert. Diese Matrix wird der transform.matrix-Eigenschaft des quadratischen Sprites zugewiesen. Jedes Mal, wenn der Benutzer auf das Quadrat klickt, wird clickHandler() aufgerufen, wodurch die Form des Quadrats geneigt wird.
5. Darüber hinaus erstellt die clickHandler()-Methode ein neues ColorTransform-Objekt. Die redOffset-Eigenschaft des neuen ColorTransform-Objekts wird auf den um 25 erhöhten aktuellen Wert von „redOffset“ gesetzt. Entsprechend wird der Wert der blueOffset-Eigenschaft um 25 verringert. Bei jedem Klicken ändern sich die Farben des Sprites.

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() { 
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;
            
            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);            
        }
    }
}