AccessibilityImplementation  - AS3

Gibt einen Fehlercode an. Fehler werden Out-of-Band angegeben und nicht in Rückgabewerten. Für die Fehlerangabe setzen Sie die errno-Eigenschaft auf einen der im Anhang, welcher die AccessibilityImplementation-Konstanten behandelt, dokumentierten Fehlercodes. Hierdurch wird der Rückgabewert ignoriert. Die errno-Eigenschaft der AccessibilityImplementation wird vom Player stets gelöscht (auf null gesetzt), bevor eine AccessibilityImplementation-Methode aufgerufen wird.

Verwandte API-Elemente

Wird verwendet, um einen Komponenteneingabehilfenteil zu erstellen. Wenn eine Komponente ohne Implementierung von ActionScript-Barrierefreiheit verwendet wird, empfiehlt Adobe, einen Stub für Komponentenbarrierefreiheit hinzuzufügen. Aufgrund dieses Stubs behandelt Flash Player die Komponente für Barrierefreiheitszwecke als einfache Grafik und stellt nicht die interne Struktur von Schaltflächen, Textfeldern usw. der Komponente bereit.

Um einen Accessibility-Stub für eine Komponente zu erstellen, erstellen Sie aus der relevanten AccImpl-Klasse eine Unterklasse und überschreiben Sie den Eigenschaften-Stub mit dem Wert true.

Verwandte API-Elemente

Statischer Konstruktor. Instanziieren Sie AccessibilityImplementation nicht direkt, indem Sie ihren Konstruktor aufrufen. Erstellen Sie stattdessen neue Implementierungen für Barrierefreiheit durch Erweiterung der mx.accessibility.AccImpl-Klasse für jede neue Komponente.

Verwandte API-Elemente

Eine IAccessible-Methode, die die Aktion ausführt, die standardmäßig mit der Komponente verknüpft ist, die diese accessibilityImplementation darstellt, oder eines ihrer untergeordneten Elemente.

Implementieren Sie diese Methode nur, wenn die AccessibilityImplementation ein Element der Benutzeroberfläche darstellt, für das im MSAA-Modell eine Standardaktion vorhanden ist.

Wenn Sie accDoDefaultAction() nur für die AccessibilityImplementation implementieren oder nur für die ihr untergeordneten Elemente, müssen Sie in einigen Fällen angeben, dass für eine bestimmte childID, die übergeben wurde, keine Standardaktion existiert. Dies erfolgt, indem Sie die errno-Eigenschaft auf E_MEMBERNOTFOUND setzen.

Parameter

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

MSAA-Methode zur Rückgabe eines DisplayObject oder eines Rectangle. Gibt den Begrenzungsrahmen eines untergeordneten Elements in der AccessibilityImplementation an.

Diese Methode wird bei einer childID mit dem Wert 0 (Null) niemals aufgerufen. Implementieren Sie diese Methode nicht, wenn Ihre AccessibilityImplementation niemals untergeordnete Elemente enthalten wird. Wenn Ihre AccessibilityImplementation untergeordnete Elemente enthalten kann, ist diese Methode dagegen obligatorisch.

Normalerweise können Sie die Anforderungen dieser Methode erfüllen, indem Sie ein Objekt zurückgeben, dass das untergeordnete Element selbst darstellt. Dies funktioniert, solange das untergeordnete Element ein DisplayObject ist. Geben Sie in diesen Fällen einfach das DisplayObject zurück, das dem Instanznamen entspricht, der in der Anzeigeliste mit dem entsprechenden visuellen Objekt verknüpft ist.

Erfüllt ein untergeordnetes Element nicht die Voraussetzung für das oben beschriebene Vorgehen, können Sie den Begrenzungsrahmen selbst berechnen und ein Rectangle mit den Eigenschaften x, y, width und height zurückgeben. Die Member x und y geben die linke obere Ecke des Begrenzungsrahmens an, die Größe wird durch width und height vorgegeben. Alle vier Member sind in Einheiten von Bühnen-Pixeln anzugeben sowie relativ zum Ursprung der Komponente, die die AccessibilityImplementation darstellt. Die x- und y-Eigenschaften können negative Werte haben, da der Ursprung eines DisplayObject nicht notwendigerweise die linke obere Ecke ist.

Wenn das durch die childID angegebene untergeordnete Element nicht sichtbar ist (d. h., get_accState würde für dieses untergeordnete Element einen Wert einschließlich STATE_SYSTEM_INVISIBLE zurückgeben), dürfen Sie null von accLocation zurückgeben. Sie können auch ein Rectangle zurückgeben, das die Koordinaten darstellt, an denen das untergeordnete Element angezeigt würde, wenn es sichtbar wäre.

Parameter

Weitere Informationen

Verwandte API-Elemente

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

IAccessible-Methode zum Ändern der Auswahl in der Komponente, die diese AccessibilityImplementation darstellt.

Der childID-Parameter ist immer ungleich 0 (null). Diese Methode bezieht sich immer auf ein untergeordnetes Element und gilt nicht für die Gesamtkomponente; Flash Player verwaltet die Auswahl der Gesamtkomponente.

Der selFlag-Parameter ist ein aus einer oder mehreren Auswahl-Flag-Konstanten bestehendes Bitfeld, mit dessen Hilfe ein MSAA-Client angibt, wie das von der childID referenzierte Objekt auszuwählen ist oder den Fokus erhält. Es folgen Beschreibungen der Auswahl-Flag-Konstanten sowie ihrer Mitteilungen an die accessibility-Implementierung. Bei Implementierungen dieser Methode in Accessibility-Implementierungen, die von der Flex mx.accessibility.ListBaseAccImpl-Klasse erben, wird die selFlag-Konstante in der Praxis meist ignoriert. Stattdessen wird für die Verarbeitung der Mehrfachauswahl auf das Auswahlverhalten der Komponente per Tastatur zurückgegriffen.

Der selFlag-Parameter enthält gegebenenfalls das SELFLAG_TAKEFOCUS-Flag. Ist dies vorhanden, setzen Sie den Fokus des untergeordneten Elements auf die childID und nur, wenn auch SELFLAG_EXTENDSELECTION vorhanden ist, machen Sie dieses untergeordnete Element zum Auswahlanker. Andernfalls lassen Sie den Fokus des untergeordneten Elements und den Auswahlanker unverändert, trotz der Tatsache, dass die im Folgenden beschriebenen zusätzlichen Flags die Auswahl möglicherweise modifizieren.

Das selFlag-Argument enthält stets eins der folgenden vier Flags, die anzeigen, welche Art von Auswahlmodifizierung gewünscht ist.

• SELFLAG_TAKESELECTION: Bestehende Auswahl löschen und Auswahl auf die festgelegte childID setzen.

• SELFLAG_EXTENDSELECTION: Bereich der untergeordneten Elemente, vom Auswahlanker bis zur angegebenen childID einschließlich, berechnen. Ist SELFLAG_ADDSELECTION vorhanden, sind sämtliche untergeordneten Elemente der Auswahl hinzuzufügen. Ist SELFLAG_REMOVESELECTION vorhanden, sind sämtliche untergeordneten Elemente aus der Auswahl zu entfernen. Wenn weder SELFLAG_ADDSELECTION noch SELFLAG_REMOVESELECTION vorhanden ist, sollten sämtliche untergeordneten Elemente den Auswahlstatus des Auswahlankers übernehmen: Ist der Auswahlanker ausgewählt, sind diese untergeordneten Elemente der Auswahl hinzuzufügen; andernfalls sind sie aus der Auswahl zu entfernen.

• SELFLAG_ADDSELECTION (ohne SELFLAG_EXTENDSELECTION): Angegebene childID zur Auswahl hinzufügen.

• SELFLAG_REMOVESELECTION (ohne SELFLAG_EXTENDSELECTION): Angegebene childID aus der Auswahl entfernen.

Die einzig gültigen selFlag-Parameterwerte für Komponenten ohne Mehrfachauswahl sind SELFLAG_TAKEFOCUS und SELFLAG_TAKESELECTION. Theoretisch hätten Sie auch die Möglichkeit, SELFLAG_REMOVESELECTION zu unterstützen bei Komponenten ohne Mehrfachauswahl, die das Erzwingen einer null-Auswahl durch den Benutzer zulassen. In der Praxis funktioniert dies bei den meisten Komponenten ohne Mehrfachauswahl nicht und MSAA-Clients führen diese Vorgänge möglicherweise nicht aus.

Wenn Sie auf nicht gültig erscheinende Flags treffen, setzen Sie errno auf E_INVALIDARG.

Wenn accSelect aufgerufen wird, stellt Flash Player sicher, dass er über den host focus verfügt (den Fensterfokus seiner Container-Anwendung) und dass Ihre Komponente innerhalb von Flash Player den Fokus erhält.

Parameter

Weitere Informationen

Verwandte API-Elemente

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

MSAA-Methode zur Rückgabe der Aktion, die standardmäßig mit der Komponente verknüpft ist, die diese accessibilityImplementation darstellt, oder eines ihrer untergeordneten Elemente.

Implementieren Sie diese Methode nur, wenn die AccessibilityImplementation ein Element der Benutzeroberfläche darstellt, für das im MSAA-Modell eine Standardaktion vorhanden ist. Stellen Sie sicher, dass exakt der vom MSAA-Modell angegebene String zurückgegeben wird. Beispiel: Der String für die Standardaktion einer Button-Komponente lautet „Press“.

Wenn Sie get_accDefaultAction() nur für die AccessibilityImplementation implementieren oder nur für die ihr untergeordneten Elemente, müssen Sie in einigen Fällen angeben, dass für eine bestimmte childID, die übergeben wurde, keine Standardaktion existiert. Dies erfolgt, indem Sie einfach null zurückgeben.

Parameter

Weitere Informationen

Verwandte API-Elemente

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

MSAA-Methode für die Rückgabe der ID des untergeordneten Elements als vorzeichenlose Ganzzahl, sofern ein solches untergeordnetes Element mit entsprechendem Fokus innerhalb der Komponente vorhanden ist. Wenn kein untergeordnetes Element über den entsprechenden Fokus verfügt, gibt die Methode 0 (Null) zurück.

Weitere Informationen

Verwandte API-Elemente

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

MSAA-Methode zur Rückgabe des Namens der Komponente, die diese accessibilityImplementation darstellt, oder eines ihrer untergeordneten Elemente.

Handelt es sich um die AccessibilityImplementation selbst (childID == 0) und die Methode ist nicht implementiert oder sie gibt keinen Wert zurück, dann verwendet Flash Player den Wert der AccessibilityProperties.name-Eigenschaft, sofern vorhanden.

Diese Methode muss bei AccessibilityImplementations, die untergeordnete Elemente haben können, implementiert werden. Sie muss einen Stringwert zurückgeben, wenn childID nicht null ist.

Je nach Typ des Benutzeroberflächenelements ist ein Name in MSAA entweder ein vom Autor vergebener Name oder der tatsächliche Textinhalt des Elements. Normalerweise fällt die AccessibilityImplementation in erstere Kategorie. D. h. ihre name-Eigenschaft ist ein vom Autor zugewiesener Name. Untergeordnete Elemente gehören immer der zweiten Kategorie an. Folglich gibt ihr Name den Textinhalt an.

Wenn die name-Eigenschaft einer AccessibilityImplementation den Wert eines vom Autor vergebenen Namens hat, gibt es zwei Möglichkeiten, wie Komponenten Namen von Autoren erhalten können. Die erste bezieht sich auf Namen, die innerhalb der Komponente selbst vorhanden sind. Beispiel: Eine Checkbox-Komponente enthält eine Textbeschriftung, die als ihr Name dient. Bei der zweiten Variante (einem Fallback zur ersten) werden die in der Benutzeroberfläche angegebenen Namen als AccessibilityProperties.name übernommen. Diese Fallbackoption ermöglicht es, Namen genauso anzugeben, wie für jeden anderen Sprite oder MovieClip üblich.

Damit sind für die AccessibilityImplementation selbst (childID == zero) drei Möglichkeiten gegeben:

• Vom Autor vergebener Name innerhalb der Komponente. Es ist die get_accName-Methode zu implementieren. Sie sollte einen Stringwert zurückgeben, der den Namen der AccessibilityImplementation zurückgibt, wenn childID gleich null ist. Ist childID gleich null, die AccessibilityImplementation hat jedoch keinen Namen, dann muss get_accName einen leeren String zurückgeben, um zu verhindern, dass der Player auf die AccessibilityProperties.name-Eigenschaft zurückgreift.

• Vom Autor vergebener Name aus der Komponente. Wenn die AccessibilityImplementation untergeordnete Elemente haben kann, ist die get_accName-Methode zu implementieren. Diese darf jedoch keinen Wert zurückgeben, wenn childID den Wert null hat. Wenn die AccessibilityImplementation niemals untergeordnete Elemente enthalten wird, ist get_accName nicht zu implementieren.

• Name mit Inhaltsbedeutung. Es ist die get_accName-Methode zu implementieren. Sie muss einen entsprechenden Stringwert zurückgeben, wenn childID null ist. Ist childID gleich null, die AccessibilityImplementation hat jedoch keinen Inhalt, dann muss get_accName einen leeren String zurückgeben, um zu verhindern, dass der Player auf die AccessibilityProperties.name-Eigenschaft zurückgreift.

Auf untergeordnete Elemente (sofern die AccessibilityImplementation diese haben kann) trifft immer der dritte Fall zu. D. .h., die get_accName-Methode ist zu implementieren. Sie muss einen entsprechenden Stringwert zurückgeben, wenn childID nicht null ist.

Parameter

Weitere Informationen

Verwandte API-Elemente

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

MSAA-Methode zur Rückgabe der Systemrolle der Komponente, die diese accessibilityImplementation darstellt, oder eines ihrer untergeordneten Elemente. Für alle MSAA-Komponenten gibt es vordefinierte Systemrollen.

Parameter

Weitere Informationen

Verwandte API-Elemente

MSAA-Methode zur Rückgabe eines Arrays, das die IDs aller ausgewählten untergeordneten Elemente enthält. Das zurückgegebene Array kann null, eine oder mehrere IDs in der Form vorzeichenloser Ganzzahlen enthalten.

Weitere Informationen

Verwandte API-Elemente

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

IAccessible-Methode zur Rückgabe des aktuellen Laufzeitstatus der Komponente, die diese accessibilityImplementation darstellt, oder eines ihrer untergeordneten Elemente.

Diese Methode muss für Komponenten in MSAA eine Kombination von null, einer oder mehreren vordefinierten object state constants zurückgeben. Wenn mehr als ein Status zutrifft, sind die Statuskonstanten in einem Bitfeld unter Verwendung des bitweisen OR-Operators | zusammenzufassen.

Um anzugeben, dass derzeit keine der Statuskonstanten gilt, muss diese Methode null zurückgeben.

Sie brauchen die Status STATE_SYSTEM_FOCUSABLE oder STATE_SYSTEM_FOCUSED nicht zu verfolgen oder zu berichten. Flash Player verarbeitet diese Status automatisch.

Parameter

Weitere Informationen

Verwandte API-Elemente

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

MSAA-Methode zur Rückgabe des Laufzeitwerts der Komponente, die diese accessibilityImplementation darstellt, oder eines ihrer untergeordneten Elemente.

Implementieren Sie diese Methode nur, wenn die AccessibilityImplementation ein Benutzeroberflächenelement darstellt, für das im MSAA-Modell ein Wert vorhanden ist. Einige Benutzeroberflächenelemente haben einen „Wert“, der auf unterschiedliche Weise dargestellt wird. Dies gilt für get_accName (z. B. durch Text), get_accState (z. B. durch Kontrollkästchen) oder get_accSelection (z. B. durch Listenfelder).

Wenn Sie get_accValue() nur für die AccessibilityImplementation selbst implementieren oder nur für die ihr untergeordneten Elemente, müssen Sie in einigen Fällen angeben, dass für eine bestimmte übergebene childID kein Wertkonzept existiert. Dies erfolgt, indem Sie einfach null zurückgeben.

Parameter

Weitere Informationen

Verwandte API-Elemente

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

Gibt ein Array zurück, das die IDs aller untergeordneten Elemente der AccessibilityImplementation als vorzeichenlose Ganzzahl enthält.

Die Länge des Arrays kann 0 (Null) sein. Die IDs müssen im Array in derselben logischen Reihenfolge erscheinen wie die untergeordneten Elemente, die sie darstellen. Wenn Ihre AccessibilityImplementation untergeordnete Elemente enthalten kann, ist diese Methode obligatorisch. Andernfalls ist sie nicht zu verwenden.

Verwenden Sie für das Zuweisen der ChildIDs an die untergeordneten Elemente ein Schema, das geeignet ist, die Eindeutigkeit innerhalb der jeweiligen Instanz Ihrer AccessibilityImplementation zu wahren. Die ChildIDs müssen nicht aufeinander folgen und ihre Reihenfolge muss nicht mit der logischen Reihenfolge der untergeordneten Elemente übereinstimmen. Richten Sie es so ein, dass ChildIDs nicht wiederverwendet werden. Wenn ein untergeordnetes Element gelöscht wird, darf seine ID in dieser AccessibilityImplementation-Instanz nicht noch einmal verwendet werden. Aufgrund von Implementierungsoptionen des Flash Player-Codes kann es zu unerwünschtem Verhalten kommen, wenn Sie ChildIDs > 1 Million wählen.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

Gibt true oder false zurück, um anzugeben, ob ein Textobjekt, das durch x, y, width und height festgelegt ist, als Beschriftung für die durch diese AccessibilityImplementation repräsentierte Komponente betrachtet werden soll.

Die Koordinaten x und y sind relativ zur oberen linken Ecke der Komponente, für die AccessibilityImplementation gilt, und können auch negativ sein. Alle Koordinaten werden in der Einheit Bühnenpixel angegeben.

Diese Methode ermöglicht die Einbeziehung von barrierefreien Komponenten in die Flash Player-Suche nach automatischen Beschriftungsbeziehungen, wodurch Text außerhalb eines Objekts den Objektnamen angeben kann. Diese Methode wird bereitgestellt, da davon auszugehen ist, dass sich die Kriterien für das Erkennen von Beschriftungen von Komponente zu Komponente unterscheiden. Wenn Sie diese Methode implementieren, sollten Sie versuchen, geometrische Kriterien zu verwenden, die den im Player-Code verwendeten Kriterien für Schaltflächen und Textfelder ähneln. Diese Kriterien lauten wie folgt:

• Bei Schaltflächen wird jeder Text, der sich vollständig innerhalb der Schaltfläche befindet, als Beschriftung betrachtet.
• Bei Textfeldern wird jeder Text, der sich in der Nähe oberhalb und links ausgerichtet oder in der Nähe der linken Seite befindet, als Beschriftung betrachtet.

Wenn die Komponente, die AccessibilityImplementation repräsentiert, nie in automatische Beschriftungsbeziehungen einbezogen werden soll, implementieren Sie isLabeledBy nicht. Dies entspricht der ständigen Rückgabe von false. Eine Situation, in der isLabeledBy nicht implementiert werden sollte, ist, wenn für AccessibilityImplementation der Fall „vom Autor zugewiesener Name innerhalb der Komponente“ zutrifft, was weiter oben unter get_accName beschrieben ist.

Beachten Sie, dass diese Methode auf keiner IAccessible-Methode basiert; sie ist Flash-spezifisch.

Parameter