ProgressEvent  - AS3

Die Anzahl der geladenen Elemente oder Bytes zu dem Zeitpunkt, zu dem der Listener das Ereignis verarbeitet.

Die Gesamtanzahl der Elemente oder Byte, die bei einem erfolgreichen Ladevorgang geladen werden. Wenn das Fortschrittsereignis ausgelöst oder einem Socket-Objekt hinzugefügt wird, ist der Wert von bytesTotal immer 0, falls nicht im bytesTotal-Parameter des Konstruktors ein Wert angegeben wird. Die tatsächliche Anzahl der Byte, die zurück order vorwärts gesendet werden, wird nicht festgelegt und ist Sache des Anwendungsentwicklers.

Erstellt ein Ereignisobjekt, das Informationen über progress-Ereignisse enthält. Ereignisobjekte werden Ereignis-Listenern als Parameter übergeben.

Erstellt eine Kopie des ProgressEvent-Objekts und stellt den Wert jeder Eigenschaft so ein, dass er dem Wert des Originals entspricht.

Gibt eine Zeichenfolge zurück, die alle Eigenschaften des ProgressEvent-Objekts enthält. Der String liegt im folgenden Format vor:

[ProgressEvent type=Wert bubbles=Wert cancelable=Wert bytesLoaded=Wert bytesTotal=Wert]

Definiert den Wert der Eigenschaft type eines progress-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines socketData-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines standardErrorData-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines standardInputProgress-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines standardOutputData-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

1. Die Eigenschaften downloadURL und fileName werden mit dem Speicherort und dem Namen der Download-Datei erstellt.
2. Im Konstruktor ProgressEventExample wird ein neues FileReference-Objekt mit dem Namen file erstellt, das dann an die configureListeners()-Methode übergeben wird.
3. Die Eigenschaften downloadURL und fileName werden an file.download() übergeben. Diese Methode ermittelt dann den Speicherort für den Download der Datei.
4. Die configureListeners()-Methode fügt sieben Ereignis-Listener und die verknüpften Abonnentenmethoden hinzu:
   1. cancel/cancelHandler() wird ausgelöst, wenn das Herunterladen der Datei abgebrochen wird.
   2. complete/complereHandler() wird ausgelöst, wenn das Herunterladen der Dateien abgeschlossen ist.
   3. ioError/ioErrorHandler() wird ausgelöst, wenn die Download-Datei nicht verfügbar oder unzugänglich ist.
   4. open/openHandler()wird nach Beginn des Download-Vorgangs ausgelöst.
   5. progress/progressHandler() wird beim Beginn und beim Ende des Download-Vorgangs ausgelöst.
   6. securityError/securityErrorHandler wird ausgelöst, wenn die lokalen Sicherheitseinstellungen für die Wiedergabe nicht mit der Art des Datenzugriffs für die Download-Datei übereinstimmen (lokaler Zugriff bzw. Netzwerkzugriff). Siehe Hinweise unten.
   7. select/selectHandler() wird bei Auswahl des Download-Objekts ausgelöst.

Hinweise:

• Für die Kompilierung der SWF-Datei müssen Sie die Option „Sicherheit bei lokaler Wiedergabe“ auf „Nur auf Netzwerk zugreifen“ einstellen.
• Bei diesem Beispiel ist die Datei SomeFile.pdf erforderlich.
• Obwohl in diesem Beispiel alle verfügbaren Ereignisse des FileReference-Objekts verwendet werden, ist in den meisten Situationen nur ein Teil davon erforderlich.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}