Sound  - AS3

Gibt die derzeit verfügbare Anzahl der Byte in diesem Soundobjekt zurück. Diese Eigenschaft ist in der Regel nur für extern geladene Dateien nützlich.

Gibt die Gesamtanzahl der Byte in diesem Soundobjekt zurück.

Bietet Zugriff auf die Metadaten, die in MP3-Dateien enthalten sind.

MP3-Sounddateien können ID3-Tags mit Metadaten zur Datei enthalten. Wenn MP3-Sound, der mit der Sound.load()-Methode geladen wurde, ID3-Tags enthält, können Sie diese Eigenschaften abfragen. Es werden nur ID3-Tags unterstützt, die den UTF-8-Zeichensatz verwenden.

Flash Player 9 und höher sowie AIR unterstützen ID3 2.0-Tags, im Speziellen 2.3 und 2.4. In der folgenden Tabelle sind die ID3 2.0-Standardtags und der Inhaltstyp der einzelnen Tags aufgeführt. Mit der Sound.id3-Eigenschaft kann über das Format my_sound.id3.COMM, my_sound.id3.TIME usw. auf diese Tags zugegriffen werden. Die erste Tabelle beschreibt Tags, auf die entweder über den ID3 2.0- oder den ActionScript-Eigenschaftennamen zugegriffen werden kann. Die zweite Tabelle beschreibt ID3-Tags, die unterstützt werden, aber keine vordefinierten Eigenschaften in ActionScript haben.

In der folgenden Tabelle sind ID3-Tags beschrieben, die unterstützt werden, jedoch in der Soundklasse über keine vordefinierten Eigenschaften verfügen. Auf diese Tags kann durch Aufrufen von mySound.id3.TFLT, mySound.id3.TIME usw. zugegriffen werden. HINWEIS: Keines dieser Tags wird in Flash Lite 4 unterstützt.

Bedenken Sie bei Verwendung dieser Eigenschaft das Flash Player-Sicherheitsmodell:

• Die id3-Eigenschaft eines Soundobjekts ist immer für SWF-Dateien erlaubt, die in der gleichen Sicherheitssandbox wie die Sounddatei sind. Bei Dateien in anderen Sandboxen werden Sicherheitsprüfungen durchgeführt.
• Wenn Sie Sound mithilfe der load()-Methode der Soundklasse laden, können Sie einen context-Parameter angeben, bei dem es sich um ein SoundLoaderContext-Objekt handelt. Wenn Sie die checkPolicyFile-Eigenschaft des SoundLoaderContext-Objekts auf true festlegen, wird in Flash Player auf dem Server, von dem der Sound geladen wird, eine URL-Richtliniendatei gesucht. Wenn eine Richtliniendatei existiert und diese den Zugriff von der Domäne der ladenden SWF-Datei erlaubt, darf die Datei auf die id3-Eigenschaft des Soundobjekts zugreifen; andernfalls darf sie es nicht.

In Adobe AIR unterliegt Inhalt in der Sicherheitssandbox der Anwendung (Inhalt, der mit der AIR-Anwendung installiert wird) nicht diesen Sicherheitseinschränkungen.

Weitere Informationen zum Thema Sicherheit finden Sie im Flash Player Developer Center im Abschnitt Sicherheit.

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.media.Sound;
    import flash.net.URLRequest;
    import flash.media.ID3Info;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;

    public class Sound_id3Example extends Sprite {
        private var snd:Sound = new Sound();       
        private var myTextField:TextField = new TextField();

        public function Sound_id3Example() {
            snd.addEventListener(Event.ID3, id3Handler);
            snd.load(new URLRequest("mySound.mp3"));
        }
    
        private function id3Handler(event:Event):void {
            var id3:ID3Info = snd.id3;

            myTextField.autoSize = TextFieldAutoSize.LEFT;
            myTextField.border = true;

            myTextField.appendText("Received ID3 Info: \n");
              
            for (var propName:String in id3) {
                myTextField.appendText(propName + " = " + id3[propName] + "\n");
            }
 
            myTextField.appendText("\n" + "Artist: " + id3.artist + "\n");
            myTextField.appendText("Song name: " + id3.songName + "\n");
            myTextField.appendText("Album: " + id3.album + "\n\n"); 
 
            this.addChild(myTextField);
        }
    }
}

Gibt den Zwischenspeicherstatus externer MP3-Dateien zurück. Wenn der Wert auf true gesetzt ist, wird die Wiedergabe unterbrochen, während das Objekt auf weitere Daten wartet.

Gibt an, ob die Sound.url-Eigenschaft gekürzt wurde. Wenn isURLInaccessible den Wert true hat, ist der Sound.url-Wert nur die Domäne der endgültigen URL, von der der Sound geladen wird. Die Eigenschaft wird zum Beispiel gekürzt, wenn der Sound aus http://www.adobe.com/assets/hello.mp3 geladen wird und die Sound.url-Eigenschaft den Wert http://www.adobe.com hat. Der Wert von isURLInaccessible ist nur dann true, wenn auch Folgendes zutrifft:

• Beim Laden der Sounddatei ist eine HTTP-Umleitung aufgetreten.
• Die SWF-Datei, die Sound.load() aufruft, stammt aus einer anderen Domäne als die endgültige URL der Sounddatei.
• Die SWF-Datei, die Sound.load() aufruft, hat keine Zugriffsberechtigung für die Sounddatei. Zugriffsberechtigungen für die Sounddatei werden auf die gleiche Weise gewährt wie für die Sound.id3-Eigenschaft: Richten Sie eine Richtliniendatei ein und verwenden Sie die SoundLoaderContext.checkPolicyFile-Eigenschaft.

Hinweis: Die isURLInaccessible-Eigenschaft wurde für Flash Player 10.1 und AIR 2.0 hinzugefügt. Diese Eigenschaft steht jedoch SWF-Dateien aller Versionen zur Verfügung, wenn die Flash-Laufzeitumgebung dies unterstützt. Die Verwendung einiger Authoring-Tools im „strikten Modus“ führt also zu einem Kompilierungsfehler. Um diesen Fehler zu umgehen, verwenden Sie die indirekte Syntax mySound["isURLInaccessible"] oder deaktivieren Sie den strikten Modus. Wenn Sie Flash Professional CS5 oder Flex SDK 4.1 verwenden, können Sie diese API für Laufzeitumgebungen verwenden und kompilieren, die vor Flash Player 10.1 und AIR 2 veröffentlicht wurden.

Für Anwendungsinhalte in AIR ist der Wert dieser Eigenschaft immer false.

Verwandte API-Elemente

Die Länge des aktuellen Sounds in Millisekunden.

Die URL, von der der Sound geladen wurde. Diese Eigenschaft kann nur auf Soundobjekte angewendet werden, die mit der Sound.load()-Methode geladen wurden. Bei Soundobjekten, die mit einem Soundelement in der Bibliothek einer SWF-Datei verknüpft sind, ist der Wert der url-Eigenschaft null.

Da die endgültige URL noch nicht bekannt ist, hat die url-Eigenschaft beim ersten Aufrufen von Sound.load() anfänglich den Wert null. Sobald ein open-Ereignis über das Soundobjekt ausgelöst wurde, nimmt die url-Eigenschaft einen anderen Wert an.

Die url-Eigenschaft enthält die endgültige, absolute URL, von der Sound geladen wurde. Der Wert von url entspricht in der Regel dem Wert, der an den stream-Parameter von Sound.load() übergeben wurde. Wenn Sie allerdings eine relative URL an Sound.load() übergeben haben, ist der Wert der url-Eigenschaft die absolute URL. Wird die ursprüngliche URL-Anforderung zusätzlich über einen HTTP-Server umgeleitet, entspricht der Wert der url-Eigenschaft der endgültigen URL, über die die Sounddatei tatsächlich heruntergeladen wurde. Diese Protokollierung einer absoluten, endgültigen URL entspricht dem Verhalten von LoaderInfo.url.

In einigen Fällen ist der Wert der url-Eigenschaft gekürzt; weitere Informationen finden Sie im Eintrag zur isURLInaccessible-Eigenschaft.

Verwandte API-Elemente

Erstellt ein neues Soundobjekt. Wenn Sie ein gültiges URLRequest-Objekt für den Soundkonstruktor übergeben, ruft der Konstruktor automatisch die load()-Funktion für das Soundobjekt auf. Wenn Sie kein gültiges URLRequest-Objekt für den Soundkonstruktor übergeben, müssen Sie die load()-Funktion für das Soundobjekt selbst aufrufen, da der Stream andernfalls nicht geladen wird.

Sobald load() für ein Soundobjekt aufgerufen wurde, kann später keine andere Sounddatei mehr in dieses Soundobjekt geladen werden. Erstellen Sie ein neues Soundobjekt, wenn Sie eine andere Sounddatei laden möchten.

Schließt den Stream. Dadurch werden eventuelle Downloads von Daten beendet. Nach dem Aufrufen der close()-Methode können möglicherweise keine Daten aus dem Stream gelesen werden.

 
package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;    
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.errors.IOError;
    import flash.events.IOErrorEvent;

    public class Sound_closeExample extends Sprite {
        private var snd:Sound = new Sound();
        private var button:TextField = new TextField();
        private var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
        
        public function Sound_closeExample() {
            button.x = 10;
            button.y = 10;
            button.text = "START";
            button.border = true;
            button.background = true;
            button.selectable = false;
            button.autoSize = TextFieldAutoSize.LEFT;

            button.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(button);
        }

        private function clickHandler(e:MouseEvent):void {

            if(button.text == "START") {

                snd.load(req);
                snd.play();        

                snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);

                button.text = "STOP";
            }
            else if(button.text == "STOP") {
                    
                try {
                    snd.close();
                    button.text = "Wait for loaded stream to finish.";
                }
                catch (error:IOError) {
                    button.text = "Couldn't close stream " + error.message;    
                }
            }
        }
        
        private function errorHandler(event:IOErrorEvent):void {
                button.text = "Couldn't load the file " + event.text;
        }
    }
}

Extrahiert unformatierte Sounddaten aus einem Soundobjekt.

Diese Methode ist für Situationen gedacht, in denen Sie mit dynamisch generiertem Sound arbeiten und eine Funktion zum sampleData-Ereignis für ein anderes Soundobjekt zuweisen. Sie können diese Methode also verwenden, um Sounddaten aus einem Soundobjekt zu extrahieren. Anschließend können Sie die Daten in das Bytearray schreiben, das ein anderes Soundobjekt zum Streamen von dynamischem Audio verwendet.

Die Audiodaten werden im Zielbytearray beginnend mit der aktuellen Position des Bytearrays abgelegt. Die Audiodaten werden immer als 44100 Hz Stereo wiedergegeben. Der Sampletyp ist ein 32-Bit-Gleitkommawert, der über ByteArray.readFloat() in eine Zahl umgewandelt werden kann.

Parameter

Verwandte API-Elemente

var sourceSnd:Sound = new Sound();
var outputSnd:Sound = new Sound();
var urlReq:URLRequest = new URLRequest("test.mp3");

sourceSnd.load(urlReq);
sourceSnd.addEventListener(Event.COMPLETE, loaded);

function loaded(event:Event):void
{
    outputSnd.addEventListener(SampleDataEvent.SAMPLE_DATA, processSound);
    outputSnd.play();
}

function processSound(event:SampleDataEvent):void
{
    var bytes:ByteArray = new ByteArray();
    sourceSnd.extract(bytes, 4096);
    event.data.writeBytes(upOctave(bytes));
}

function upOctave(bytes:ByteArray):ByteArray
{
    var returnBytes:ByteArray = new ByteArray();
    bytes.position = 0;
    while(bytes.bytesAvailable > 0)
    {
        returnBytes.writeFloat(bytes.readFloat());
        returnBytes.writeFloat(bytes.readFloat());
        if (bytes.bytesAvailable > 0)
        {
            bytes.position += 8;
        }
    }
    return returnBytes;
}

Initiiert den Ladevorgang einer externen MP3-Datei von der angegebenen URL. Wenn Sie ein gültiges URLRequest-Objekt für den Soundkonstruktor übergeben, wird Sound.load() automatisch aufgerufen. Sie müssen Sound.load() nur aufrufen, wenn Sie kein gültiges URLRequest-Objekt oder den Wert null für den Soundkonstruktor übergeben.

Sobald load() für ein Soundobjekt aufgerufen wurde, kann später keine andere Sounddatei mehr in dieses Soundobjekt geladen werden. Erstellen Sie ein neues Soundobjekt, wenn Sie eine andere Sounddatei laden möchten.

Beachten Sie bei Verwendung dieser Methode das folgende Sicherheitsmodell von:

• Der Aufruf von Sound.load() ist nicht zulässig, wenn sich die aufrufende Datei in der lokalen Sandbox des Dateisystems und sich der Sound in einer Netzwerk-Sandbox befindet.
• Zum Aufrufen der lokal vertrauenswürdigen Sandbox oder der lokalen Sandbox mit Netzwerkzugang sind Zugriffsrechte von einer Website über eine URL-Richtliniendatei erforderlich.
• Eine Verbindung mit normalerweise reservierten Ports ist nicht möglich. Eine vollständige Liste der gesperrten Ports finden Sie unter „Beschränken von Netzwerk-APIs“ im ActionScript 3.0 Entwicklerhandbuch.
• Sie können eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie auf der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der object- und embed-Tags festlegen.

Wenn Sie in Flash Player 10 oder höher einen Multipart-Content-Type verwenden (z. B. „multipart/form-data“), der einen Upload enthält (gekennzeichnet durch einen „filename“-Parameter in einem „content-disposition“-Header innerhalb des POST-Body), so unterliegt die POST-Methode den Sicherheitsregeln für Uploads:

• Der POST-Vorgang muss als Reaktion auf eine durch den Benutzer initiierte Aktion, z. B. Mausklick oder Tastendruck, erfolgen.
• Ist die POST-Methode domänenübergreifend (das POST-Ziel befindet sich auf einem anderen Server als die SWF-Datei, die die POST-Anforderung sendet), so muss der Zielserver eine URL-Richtliniendatei bereitstellen, die den domänenübergreifenden Zugriff erlaubt.

Für alle mehrteiligen Content-Typen muss ebenfalls die Syntax nach Standard RFC2046 gültig sein. Scheint die Syntax ungültig zu sein, so unterliegt die POST-Methode den Sicherheitsregeln für Uploads.

In Adobe AIR unterliegt Inhalt in der Sicherheitssandbox der Anwendung (Inhalt, der mit der AIR-Anwendung installiert wird) jedoch nicht diesen Sicherheitseinschränkungen.

Weitere Informationen zum Thema Sicherheit finden Sie im Flash Player Developer Center im Abschnitt Sicherheit.

Parameter

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.ProgressEvent;
    import flash.events.IOErrorEvent;
    
    public class Sound_loadExample extends Sprite {
        private var snd:Sound = new Sound();
        private var statusTextField:TextField  = new TextField();

        public function Sound_loadExample(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;
            var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
            snd.load(req);
            
            snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
 
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(ProgressEvent.PROGRESS, progressHandler);
                     
            this.addChild(statusTextField);
        }
    
        private function progressHandler(event:ProgressEvent):void {
            var loadTime:Number = event.bytesLoaded / event.bytesTotal;
            var LoadPercent:uint = Math.round(100 * loadTime);
              
            statusTextField.text = "Sound file's size in bytes: " + event.bytesTotal + "\n" 
                                 + "Bytes being loaded: " + event.bytesLoaded + "\n" 
                                 + "Percentage of sound file that is loaded " + LoadPercent + "%.\n";
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

lädt MP3-Sounddaten aus einem ByteArray-Objekt in ein Sound-Objekt. Die Daten werden aus der aktuellen ByteArray-Position gelesen und verlassen die ByteArray-Position am Ende der angegebenen Bytelänge, nachdem dies abgeschlossen ist. Wenn die MP3-Sounddaten ID3-Daten enthält, werden während dieses Funktionsaufrufs ID3-Ereignisse abgesetzt. Diese Funktion gibt keine Ausnahme aus, wenn das ByteArray-Objekt nicht genügend Daten enthält.

Parameter

Lädt PCM 32-Bit-Gleitkomma-Sounddaten aus einem ByteArray-Objekt in ein Sound-Objekt. Die Daten werden von der aktuellen ByteArray-Position gelesen und verlassen nach Abschluss dieses Vorgangs die ByteArray-Position am Ende der angegebenen Samplelänge multipliziert mit 1 Kanal oder 2 Kanälen, falls das Stereo-Flag gesetzt wurde.

Ab Flash Player 11.8 ist die Menge an Audiodaten, die an diese Funktion übergeben werden, eingeschränkt. Für SWF-Versionen >= 21 gibt diese Funktion eine Ausnahme aus, wenn die Menge an Audiodaten, die an diese Funktion übergeben werden, mehr als 1800 Sekunden beträgt. Das heißt, samples / sampleRate sollten kleiner als oder gleich 1800 sein. Für die SWF-Versionen < 21 schlägt die Laufzeit ohne weitere Meldung fehl, wenn die Menge an weitergeleiteten Audiodaten mehr als 12000 Sekunden beträgt. Dies wird nur für Abwärtskompatibilität bereitgestellt.

Diese Funktion gibt keine Ausnahme aus, wenn das ByteArray-Objekt nicht genügend Daten enthält.

Parameter

Erstellt ein neues SoundChannel-Objekt zur Wiedergabe von Sound. Diese Methode gibt ein SoundChannel-Objekt zurück, auf das Sie zum Beenden von Sound und zum Überwachen der Lautstärke zugreifen können. (Greifen Sie zum Steuern von Lautstärke, Schwenkung und Balance auf das SoundTransform-Objekt zu, das dem Soundkanal zugewiesen ist.)

Parameter

Verwandte API-Elemente

 
package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;
    import flash.media.Sound;;
    import flash.net.URLRequest;
    import flash.media.SoundChannel;
    import flash.events.ProgressEvent;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample1 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel = new SoundChannel();
        private var infoTextField:TextField = new TextField();
    
        public function Sound_playExample1() {

            var req:URLRequest = new URLRequest("MySound.mp3");
            
            infoTextField.autoSize = TextFieldAutoSize.LEFT;
            infoTextField.text = "Please wait for the file to be loaded.\n" 
                                + "Then select from the bar to decide where the file should start.";
            
            snd.load(req);               
            channel = snd.play();

            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(Event.COMPLETE, completeHandler);


            this.addChild(infoTextField);
        }

        private function completeHandler(event:Event):void {                
            infoTextField.text = "File is ready.";

            var bar:Sprite = new Sprite();

            bar.graphics.lineStyle(5, 0xFF0000);
            bar.graphics.moveTo(100, 100);
            bar.graphics.lineTo(200, 100);

            bar.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(bar);
        }
    
        private function clickHandler(event:MouseEvent):void {
            
                var position:uint = event.localX;
                var percent:uint = Math.round(position) - 100;   
                var cue:uint = (percent / 100) * snd.length;

                channel.stop();
                channel = snd.play(cue);    
        }

        private function errorHandler(errorEvent:IOErrorEvent):void {
            infoTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.media.Sound;
    import flash.net.URLRequest;

    public class Sound_playExample2 extends Sprite {
        private var button:Sprite = new Sprite(); 
        private var snd:Sound = new Sound();
            
        public function Sound_playExample2() {

            var req:URLRequest = new URLRequest("click.mp3");
            snd.load(req);               
     
            button.graphics.beginFill(0x00FF00);
            button.graphics.drawRect(10, 10, 50, 30);
            button.graphics.endFill();
     
            button.addEventListener(MouseEvent.CLICK, clickHandler);
            button.addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
     
            this.addChild(button);
        }

        private function clickHandler(event:MouseEvent):void {
            snd.play();            
        }

        private function doubleClickHandler(event:MouseEvent):void {
            snd.play(0, 2);        
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample3 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel;
        private var statusTextField:TextField  = new TextField();

        public function Sound_playExample3(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;

           var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
                snd.load(req);
            
                channel = snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
                    
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            addEventListener(Event.ENTER_FRAME, enterFrameHandler);
            channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
                    
            this.addChild(statusTextField);
        }
    
        private function enterFrameHandler(event:Event):void {    
            var loadTime:Number = snd.bytesLoaded / snd.bytesTotal;
            var loadPercent:uint = Math.round(100 * loadTime);
            var estimatedLength:int = Math.ceil(snd.length / (loadTime));
            var playbackPercent:uint = Math.round(100 * (channel.position / estimatedLength));
      
            statusTextField.text = "Sound file's size is " + snd.bytesTotal + " bytes.\n" 
                                   + "Bytes being loaded: " + snd.bytesLoaded + "\n" 
                                   + "Percentage of sound file that is loaded " + loadPercent + "%.\n"
                                   + "Sound playback is " + playbackPercent + "% complete.";     
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }

        private function soundCompleteHandler(event:Event):void {
            statusTextField.text = "The sound has finished playing.";
            removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }
    }
}

Wird nach dem erfolgreichen Laden von Daten ausgelöst.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird durch ein Soundobjekt ausgelöst, wenn ID3-Daten für MP3-Sound verfügbar sind.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird beim Auftreten eines I/O-Fehlers ausgelöst, durch den der Ladevorgang fehlschlägt.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird beim Start eines Ladevorgangs ausgelöst.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird ausgelöst, wenn während eines Ladevorgangs Daten empfangen werden.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird abgesetzt, wenn die Laufzeitumgebung neue Audiodaten anfordert.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

var mySound:Sound = new Sound();
function sineWaveGenerator(event:SampleDataEvent):void {
    for ( var c:int=0; c<8192; c++ ) {
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
    }
}

mySound.addEventListener(SampleDataEvent.SAMPLE_DATA,sineWaveGenerator);
mySound.play();

Verwandte API-Elemente