Graphics  - AS3

Füllt einen Zeichenbereich mit einer Bitmap. Um den Bereich zu füllen, kann das Bild wiederholt oder mehrfach neben- und untereinander angeordnet werden. Die Füllung bleibt wirksam, bis Sie eine der Methoden beginFill(), beginBitmapFill(), beginGradientFill() oder beginShaderFill() aufrufen. Durch das Aufrufen der clear()-Methode wird die Füllung gelöscht.

Die Anwendung stellt die Füllung immer dann dar, wenn drei oder mehr Punkte gezeichnet werden oder die endFill()-Methode aufgerufen wird.

Parameter

     matrix = new flash.geom.Matrix(); 
     matrix.rotate(Math.PI / 4);
     

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.geom.Matrix;

    public class Graphics_beginBitmapFillExample extends Sprite {
 
        private var url:String = "image1.jpg";
        private var loader:Loader = new Loader();

        public function Graphics_beginBitmapFillExample() {

            var request:URLRequest = new URLRequest(url);
            
            loader.load(request);
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, drawImage);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function drawImage(event:Event):void {

            var mySprite:Sprite = new Sprite();
            var myBitmap:BitmapData = new BitmapData(loader.width, loader.height, false);
  
            myBitmap.draw(loader, new Matrix());
            
            var matrix:Matrix = new Matrix();
            matrix.rotate(Math.PI/4);
            
            mySprite.graphics.beginBitmapFill(myBitmap, matrix, true);
            mySprite.graphics.drawRect(100, 50, 200, 90);
            mySprite.graphics.endFill();
            
            addChild(mySprite);
        }
 
         private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }   
}

Gibt eine einfache, einfarbige Füllung an, die bei nachfolgenden Aufrufen anderer Graphics-Methoden (wie lineTo() oder drawCircle()) zum Zeichnen verwendet wird. Die Füllung bleibt wirksam, bis Sie eine der Methoden beginFill(), beginBitmapFill(), beginGradientFill() oder beginShaderFill() aufrufen. Durch das Aufrufen der clear()-Methode wird die Füllung gelöscht.

Die Anwendung stellt die Füllung immer dann dar, wenn drei oder mehr Punkte gezeichnet werden oder die endFill()-Methode aufgerufen wird.

Parameter

Verwandte API-Elemente

Gibt eine Farbverlaufsfüllung an, die bei nachfolgenden Aufrufen anderer Graphics-Methoden wie lineTo() oder drawCircle() zum Zeichnen verwendet wird. Die Füllung bleibt wirksam, bis Sie eine der Methoden beginFill(), beginBitmapFill(), beginGradientFill() oder beginShaderFill() aufrufen. Durch das Aufrufen der clear()-Methode wird die Füllung gelöscht.

Die Anwendung stellt die Füllung immer dann dar, wenn drei oder mehr Punkte gezeichnet werden oder die endFill()-Methode aufgerufen wird.

Parameter

	type:String — Ein Wert aus der GradientType-Klasse, mit dem angegeben wird, welcher Farbverlaufstyp verwendet werden soll: GradientType.LINEAR oder GradientType.RADIAL.
	colors:Array — Ein Array mit hexadezimalen RGB-Farbwerten, die im Farbverlauf verwendet werden (beispielsweise 0xFF0000 für Rot, 0x0000FF für Blau usw.). Sie können bis zu 15 Farben angeben. Definieren Sie für jede Farbe einen entsprechenden Wert in den Parametern „alphas“ und „ratios“.
	alphas:Array — Ein Array mit Alphawerten für die entsprechenden Farben im Array „colors“. Gültig sind Werte von 0 bis 1. Ist der Wert kleiner als 0, ist der Standardwert 0. Ist der Wert größer als 1, ist der Standardwert 1.
	ratios:Array — Ein Array mit Farbverteilungsverhältnissen. Zulässig sind Werte zwischen 0 und 255. Dieser Wert gibt den Breitenanteil an, in dem die Farbe mit 100 % gesampelt wird. Der Wert 0 stellt die linke Position im Farbverlaufsfeld dar, 255 die rechte. Hinweis: Dieser Wert repräsentiert Positionen im Farbverlaufsfeld, nicht im Koordinatenraum des endgültigen Farbverlaufs, der breiter oder schmaler als das Farbverlaufsfeld sein kann. Geben Sie für jeden Wert im Parameter colors einen Wert an. Die folgende Abbildung zeigt für einen linearen Verlauf mit den beiden Farben Blau und Grün die Farbplatzierung im Verlauf basierend auf den verschiedenen Werten im ratios-Array an: ratios Gradient [0, 127] [0, 255] [127, 255] Die Werte im Array müssen sich sequenziell erhöhen. Beispiel: [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — Eine Transformationsmatrix, wie sie von der flash.geom.Matrix-Klasse definiert wird. Die flash.geom.Matrix-Klasse umfasst eine createGradientBox()-Methode, mit der Sie die Matrix zur Verwendung mit der beginGradientFill()-Methode auf einfache Weise festlegen können.
	spreadMethod:String (default = "pad") — Ein Wert aus der SpreadMethod-Klasse, der festlegt, welche Auftragstärke zu verwenden ist: SpreadMethod.PAD, SpreadMethod.REFLECT oder SpreadMethod.REPEAT. Angenommen, Sie haben einen einfachen linearen Farbverlauf zwischen zwei Farben: import flash.geom.* import flash.display.* var fillType:String = GradientType.LINEAR; var colors:Array = [0xFF0000, 0x0000FF]; var alphas:Array = [1, 1]; var ratios:Array = [0x00, 0xFF]; var matr:Matrix = new Matrix(); matr.createGradientBox(20, 20, 0, 0, 0); var spreadMethod:String = SpreadMethod.PAD; this.graphics.beginGradientFill(fillType, colors, alphas, ratios, matr, spreadMethod); this.graphics.drawRect(0,0,100,100); Dieses Beispiel verwendet SpreadMethod.PAD als Methode für die Auftragstärke, und der Farbverlauf sieht folgendermaßen aus: Mit der Auftragstärke SpreadMethod.REFLECT sieht die Farbverlaufsfüllung folgendermaßen aus: Mit der Auftragstärke SpreadMethod.REPEAT sieht die Farbverlaufsfüllung folgendermaßen aus:
	interpolationMethod:String (default = "rgb") — Ein Wert der InterpolationMethod-Klasse, der festlegt, welcher Wert verwendet werden soll: InterpolationMethod.LINEAR_RGB oder InterpolationMethod.RGB. Angenommen, Sie haben einen einfachen linearen Farbverlauf zwischen zwei Farben (wobei der Parameter spreadMethod auf SpreadMethod.REFLECT gesetzt ist). Die verschiedenen Interpolationsmethoden haben folgende Auswirkung auf die Darstellung des Farbverlaufs: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Eine Zahl, die die Position des Farbverlaufsbrennpunkts steuert. Der Wert 0 bedeutet, dass der Brennpunkt in der Mitte liegt. Der Wert 1 bedeutet, dass der Brennpunkt an einem Rand des Farbverlaufskreises liegt. Der Wert -1 bedeutet, dass der Brennpunkt am anderen Rand des Farbverlaufskreises liegt. Werte, die kleiner als -1 oder größer als 1 sind, werden auf -1 bzw. 1 gerundet. Im folgenden Beispiel ist focalPointRatio z. B. auf 0,75 gesetzt:

Verwandte API-Elemente

Legt eine Shaderfüllung fest, die bei nachfolgenden Aufrufen anderer Graphics-Methoden (wie lineTo() oder drawCircle()) für das Objekt verwendet wird. Die Füllung bleibt wirksam, bis Sie eine der Methoden beginFill(), beginBitmapFill(), beginGradientFill() oder beginShaderFill() aufrufen. Durch das Aufrufen der clear()-Methode wird die Füllung gelöscht.

Die Anwendung stellt die Füllung immer dann dar, wenn drei oder mehr Punkte gezeichnet werden oder die endFill()-Methode aufgerufen wird.

Shader-Füllungen werden beim GPU-Rendering nicht unterstützt; gefüllte Bereiche werden in Cyan eingefärbt.

Parameter

     matrix = new flash.geom.Matrix(); 
     matrix.rotate(Math.PI / 4);
     

Verwandte API-Elemente

Löscht die Grafiken, die für dieses Graphics-Objekt gezeichnet worden sind, und setzt die Einstellungen für den Füll- und Linienstil zurück.

Kopiert alle Zeichenbefehle vom Graphics-Quellobjekt in das aufrufende Graphics-Objekt.

Parameter

Zeichnet eine kubische Bézierkurve von der aktuellen Zeichenposition zum angegebenen Ankerpunkt. Kubische Bézierkurven bestehen aus zwei Ankerpunkten und zwei Steuerpunkten. Die Kurve interpoliert die zwei Ankerpunkte und neigt sich zu den beiden Steuerpunkten hin.

Die vier Punkte, die Sie zum Zeichnen einer kubischen Bézierkurve mit der cubicCurveTo()-Methode verwenden, sind:

• Die aktuelle Zeichenposition ist der erste Ankerpunkt.
• Die Parameter anchorX und anchorY geben den zweiten Ankerpunkt an.
• Die Parameter controlX1 und controlY1 geben den ersten Steuerungspunkt an.
• Die Parameter controlX2 und controlY2 geben den zweiten Steuerungspunkt an.

Wenn Sie die cubicCurveTo()-Methode vor dem Aufruf der moveTo()-Methode aufrufen, beginnt Ihre Kurve bei Position (0, 0).

Wenn die cubicCurveTo()-Methode erfolgreich ist, legt die Flash-Laufzeitumgebung die aktuelle Zeichenposition auf (anchorX, anchorY) fest. Wenn die cubicCurveTo()-Method fehlschlägt, wird die aktuelle Zeichenposition nicht verändert.

Falls Ihr Movieclip Inhalt enthält, der mit den Flash-Zeichenwerkzeugen erstellt wurde, werden die Ergebnisse der Aufrufe der cubicCurveTo()-Methode unter diesem Inhalt gezeichnet.

Parameter

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    
    public class Graphics_cubicCurveToExample extends Sprite
    {
        public function Graphics_cubicCurveToExample():void
        {
            var rounderObject:Shape = new Shape();

            rounderObject.graphics.beginFill(0x0000FF);
            rounderObject.graphics.moveTo(250, 0);
            rounderObject.graphics.cubicCurveTo(275, 0, 300, 25, 300, 50);
            rounderObject.graphics.cubicCurveTo(300, 75, 275, 100, 250, 100);
            rounderObject.graphics.cubicCurveTo(225, 100, 200, 75, 200, 50);
            rounderObject.graphics.cubicCurveTo(200, 25, 225, 0, 250, 0);
            rounderObject.graphics.endFill();
            
            this.addChild(rounderObject);
        }
    }
}

Zeichnet eine quadratische Bézierkurve im aktuellen Linienstil von der aktuellen Zeichnungsposition zu (anchorX, anchorY) unter Verwendung des durch (controlX, controlY) angegebenen Steuerpunkts. Die aktuelle Zeichnungsposition wird dann auf (anchorX, anchorY) gesetzt. Wenn der Movieclip, in dem Sie zeichnen, einen mit den Flash-Zeichenwerkzeugen erstellten Inhalt enthält, werden die Ergebnisse von Aufrufen der curveTo()-Methode unterhalb dieses Inhalts gezeichnet. Wenn Sie die curveTo()-Methode vor der moveTo()-Methode aufrufen, ist der Standardwert der aktuellen Zeichnungsposition (0, 0). Wenn ein Parameter fehlt, schlägt die Ausführung dieser Methode fehl, und die aktuelle Zeichnungsposition wird beibehalten.

Die gezeichnete Kurve ist eine quadratische Bézierkurve. Quadratische Bézierkurven bestehen aus zwei Ankerpunkten und einem Steuerpunkt. Die Kurve interpoliert die zwei Ankerpunkte und neigt sich zum Steuerpunkt hin.

Parameter

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    
    public class Graphics_curveToExample1 extends Sprite
    {
        public function Graphics_curveToExample1():void
        {
            var roundObject:Shape = new Shape();

            roundObject.graphics.beginFill(0x00FF00);
            roundObject.graphics.moveTo(250, 0);
            roundObject.graphics.curveTo(300, 0, 300, 50);
            roundObject.graphics.curveTo(300, 100, 250, 100);
            roundObject.graphics.curveTo(200, 100, 200, 50);
            roundObject.graphics.curveTo(200, 0, 250, 0);
            roundObject.graphics.endFill();
            
            this.addChild(roundObject);
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_curveToExample2 extends Sprite
    {
        public function Graphics_curveToExample2() {
            var newMoon:Shape = new Shape();
            
            newMoon.graphics.lineStyle(1, 0);
            newMoon.graphics.beginFill(0xFFFFFF);
            newMoon.graphics.moveTo(100, 100); 
            newMoon.graphics.curveTo(30, 150, 100, 200);    
            newMoon.graphics.curveTo(50, 150, 100, 100);
            graphics.endFill();
            
            this.addChild(newMoon);
        }
    }
}

Zeichnet einen Kreis. Setzen Sie den Linienstil oder die Füllung oder beides, bevor Sie die drawCircle()-Methode aufrufen. Dazu rufen Sie die Methode linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() oder beginBitmapFill() auf.

Parameter

Verwandte API-Elemente

Zeichnet eine Ellipse. Setzen Sie den Linienstil oder die Füllung oder beides, bevor Sie die drawEllipse()-Methode aufrufen. Dazu rufen Sie die Methode linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() oder beginBitmapFill() auf.

Parameter

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_drawEllipseExample extends Sprite
    {
        public static const SMALL:uint = 0;
        public static const MEDIUM:uint = 1;
        public static const LARGE:uint = 2;

        public function Graphics_drawEllipseExample()
        {
            drawEgg(SMALL, 0, 100);
            drawEgg(MEDIUM, 100, 60);
            drawEgg(LARGE, 250, 35);    
        }

        public function drawEgg(eggSize:uint, x:Number, y:Number):void  {
            
            var myEgg:Shape = new Shape();
            
            myEgg.graphics.beginFill(0xFFFFFF);
            myEgg.graphics.lineStyle(1);

            switch(eggSize) {
                case SMALL:
                    myEgg.graphics.drawEllipse(x, y, 60, 70);
                    break;
                case MEDIUM:
                    myEgg.graphics.drawEllipse(x, y, 120, 150);    
                    break;
                case LARGE:
                    myEgg.graphics.drawEllipse(x, y, 150, 200);
                    break;
                default:
                    trace ("Wrong size! There is no egg.");
                break;            
            }
            
            myEgg.graphics.endFill();
    
            this.addChild(myEgg);
        }
    }
}

Sendet eine Reihe von IGraphicsData-Instanzen für das Zeichnen. Diese Methode akzeptiert einen Vektor mit Objekten, einschließlich Pfade, Füllungen und Striche, die die IGraphicsData-Schnittstelle implementieren. Ein Vektor mit IGraphicsData-Instanzen kann sich auf einen Teil einer Form beziehen, kann aber auch ein komplexer, umfangreicher Datensatz sein, der eine Form vollständig darstellt.

Grafikpfade können andere Grafikpfade enthalten. Enthält der graphicsData-Vektor einen Pfad, so wird dieser während dieses Vorgangs mit allen seinen Unterpfaden dargestellt.

Parameter

Verwandte API-Elemente

package
{
    import flash.display.*;
    import flash.geom.*;

    public class DrawGraphicsDataExample extends Sprite
    {
        public function DrawGraphicsDataExample()
        {
            // establish the fill properties
            var myFill:GraphicsGradientFill = new GraphicsGradientFill();
            myFill.colors = [0xEEFFEE, 0x0000FF];
            myFill.matrix = new Matrix();
            myFill.matrix.createGradientBox(100, 100, 0);
            
            // establish the stroke properties
            var myStroke:GraphicsStroke = new GraphicsStroke(2);
            myStroke.fill = new GraphicsSolidFill(0x000000);
            
            // establish the path properties
            var pathCommands = new Vector.<int>(5, true);
            pathCommands[0] = GraphicsPathCommand.MOVE_TO;
            pathCommands[1] = GraphicsPathCommand.LINE_TO;
            pathCommands[2] = GraphicsPathCommand.LINE_TO;
            pathCommands[3] = GraphicsPathCommand.LINE_TO;
            pathCommands[4] = GraphicsPathCommand.LINE_TO;
            
            var pathCoordinates:Vector.<Number> = new Vector.<Number>(10, true);
            pathCoordinates.push(10,10, 10,100, 100,100, 100,10, 10,10);
            
            var myPath:GraphicsPath = new GraphicsPath(pathCommands, pathCoordinates);
            
            // populate the IGraphicsData Vector array
            var myDrawing:Vector.<IGraphicsData> = new Vector.<IGraphicsData>(3, true);
            myDrawing[0] = myFill;
            myDrawing[1] = myStroke;
            myDrawing[2] = myPath;
            
            // render the drawing
            graphics.drawGraphicsData(myDrawing);
        }
    }
}

Sendet eine Reihe von Befehlen für das Zeichnen. Die drawPath()-Methode lässt einen Vektor von einzelnen moveTo()-, lineTo()- und curveTo()-Zeichnenbefehlen zu und fasst sie zu einem einzigen Aufruf zusammen. Die Parameter der drawPath()-Methode kombinieren Zeichnenbefehle mit Wertepaaren aus x- und y-Koordinaten und einer Zeichnenrichtung. Die Zeichnenbefehle sind Ganzzahlen, die als Konstanten dargestellt werden, die in der GraphicsPathCommand-Klasse definiert werden. Die Wertepaare aus x- und y-Koordinaten sind Zahlen in einem Array, wobei jedes Paar eine Koordinatenposition festlegt. Die Zeichenrichtung ist ein Wert aus der GraphicsPathWinding-Klasse.

Generell ist die Darstellung von Zeichnungen mithilfe von drawPath() schneller als mit einer Reihe einzelner lineTo()- und curveTo()-Methodenaufrufe.

Die drawPath()-Methode verwendet eine gleitende Berechnung, sodass die Drehung und Skalierung von Formen genauer ist und ein besseres Ergebnis erzielt. Andererseits können Kurven, die mithilfe der drawPath()-Methode gesendet wurden, geringfügige Ausrichtungsfehler auf der Subpixelebene aufweisen, wenn sie gemeinsam mit der lineTo()- oder curveTo()-Methode verwendet werden.

Die drawPath()-Methode verwendet auch leicht unterschiedliche Regeln für das Füllen und Zeichnen von Linien. Diese sind nachfolgend beschrieben:

• Beim Anwenden einer Füllung beim Darstellen eines Pfads:
  • Ein Unterpfad, der kürzer als 3 Punkte ist, wird nicht dargestellt. (Beachten Sie jedoch, dass der Strich trotzdem dargestellt wird, und zwar in Übereinstimmung mit den Regeln für Striche, siehe unten.)
  • Ein nicht geschlossener Unterpfad (Endpunkt und Anfangspunkt stimmen nicht überein) wird implizit geschlossen.
• Beim Anwenden eines Strichs beim Darstellen eines Pfads:
  • Der Unterpfad kann aus einer beliebigen Anzahl an Punkten bestehen.
  • Der Unterpfad wird niemals implizit geschlossen.

Parameter

Verwandte API-Elemente

package
{
    import flash.display.*;
        
    public class DrawPathExample extends Sprite
    {
        public function DrawPathExample()
        {
            var star_commands:Vector.<int> = new Vector.<int>(5, true);
            
            star_commands[0] = GraphicsPathCommand.MOVE_TO;
            star_commands[1] = GraphicsPathCommand.LINE_TO;
            star_commands[2] = GraphicsPathCommand.LINE_TO;
            star_commands[3] = GraphicsPathCommand.LINE_TO;
            star_commands[4] = GraphicsPathCommand.LINE_TO;
            
            var star_coord:Vector.<Number> = new Vector.<Number>(10, true);
            star_coord[0] = 66; //x
            star_coord[1] = 10; //y 
            star_coord[2] = 23; 
            star_coord[3] = 127; 
            star_coord[4] = 122; 
            star_coord[5] = 50; 
            star_coord[6] = 10; 
            star_coord[7] = 49; 
            star_coord[8] = 109; 
            star_coord[9] = 127;
            
            graphics.beginFill(0x003366);
            graphics.drawPath(star_commands, star_coord);
        }
    }
}

 graphics.drawPath(star_commands, star_coord, GraphicsPathWinding.NON_ZERO);
 

Zeichnet ein Rechteck. Setzen Sie den Linienstil oder die Füllung oder beides, bevor Sie die drawRect()-Methode aufrufen. Dazu rufen Sie die Methode linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() oder beginBitmapFill() auf.

Parameter

Verwandte API-Elemente

var movieClip:MovieClip = new MovieClip();
movieClip.graphics.beginFill(0xFF0000);
movieClip.graphics.drawRect(0, 0, 100, 80);
movieClip.graphics.endFill();
movieClip.x = 10;
movieClip.y = 10;
addChild(movieClip);

Zeichnet ein abgerundetes Rechteck. Setzen Sie den Linienstil oder die Füllung oder beides, bevor Sie die drawRoundRect()-Methode aufrufen. Dazu rufen Sie die Methode linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() oder beginBitmapFill() auf.

Parameter

Verwandte API-Elemente

Stellt einen Satz an Dreiecken dar, normalerweise, um Bitmaps zu verzerren und ihnen ein dreidimensionales Aussehen zu verleihen. Die drawTriangles()-Methode ordnet den Flächen von Dreiecken entweder die aktuelle oder eine Bitmapfüllung als Satz von Koordinaten (u,v) zu.

Es kann jeder Füllungstyp verwendet werden, aber wenn die Füllung über eine Transformationsmatrix verfügt, wird diese Transformationsmatrix ignoriert.

Ein uvtData-Parameter verbessert bei der Verwendung einer Bitmapfüllung das Texturmapping.

Parameter

Verwandte API-Elemente

Versieht die Linien und Kurven, die seit dem letzten Aufruf der Methode beginFill(), beginGradientFill() oder beginBitmapFill() hinzugefügt wurden, mit einer Füllung. Flash verwendet die im vorherigen Aufruf der Methode beginFill(), beginGradientFill() oder beginBitmapFill() angegebene Füllung. Wenn die aktuelle Zeichnungsposition nicht der in einer moveTo()-Methode angegebenen vorherigen Position entspricht und eine Füllung definiert ist, wird der Pfad mit einer Linie geschlossen und dann gefüllt.

Verwandte API-Elemente

Legt eine Bitmap fest, die beim Zeichnen von Linien für den Linienstrich verwendet wird.

Der Bitmaplinienstil wird für nachfolgende Aufrufe von Graphics-Methoden, z. B. lineTo() oder drawCircle(), verwendet. Der Linienstil bleibt wirksam, bis Sie die lineStyle()- oderlineGradientStyle()-Methode oder wieder die lineBitmapStyle()-Methode mit anderen Parametern aufrufen.

Sie können die lineBitmapStyle()-Methode während des Zeichnens eines Pfads aufrufen, um für unterschiedliche Linienabschnitte in einem Pfad unterschiedliche Stile zu verwenden.

Rufen Sie die lineStyle()-Methode vor der lineBitmapStyle()-Methode auf, um einen Strich zu aktivieren, andernfalls ist der Linienstil undefined.

Wenn Sie die clear()-Methode aufrufen, wird der Linienstil wieder auf undefined gesetzt.

Parameter

Verwandte API-Elemente

Legt einen Verlauf für den Strich beim Zeichnen von Linien fest.

Der Linienverlaufsstil wird für nachfolgende Aufrufe von Graphics-Methoden, z. B. lineTo() oder drawCircle(), verwendet. Der Linienstil bleibt wirksam, bis Sie die lineStyle()- oderlineBitmapStyle()-Methode oder wieder die lineGradientStyle()-Methode mit anderen Parametern aufrufen.

Sie können lineGradientStyle() beim Zeichnen eines Pfads aufrufen, um für unterschiedliche Liniensegmente in einem Pfad unterschiedliche Linientypen zu verwenden.

Rufen Sie die lineStyle()-Methode vor der lineGradientStyle()-Methode auf, um einen Strich zu aktivieren, andernfalls ist der Linienstil undefined.

Wenn Sie die clear()-Methode aufrufen, wird der Linienstil wieder auf undefined gesetzt.

Parameter

	type:String — Ein Wert aus der GradientType-Klasse, mit dem angegeben wird, welcher Farbverlaufstyp verwendet werden soll, entweder „GradientType.LINEAR“ oder „GradientType.RADIAL“.
	colors:Array — Ein Array mit hexadezimalen RGB-Farbwerten, die im Farbverlauf verwendet werden sollen (beispielsweise 0xFF0000 für Rot, 0x0000FF für Blau usw.).
	alphas:Array — Ein Array mit Alphawerten für die entsprechenden Farben im Array „colors“. Gültig sind Werte von 0 bis 1. Ist der Wert kleiner als 0, ist der Standardwert 0. Ist der Wert größer als 1, ist der Standardwert 1.
	ratios:Array — Ein Array mit Farbverteilungsverhältnissen. Die zulässigen Werte liegen zwischen 0 und 255. Dieser Wert gibt den Breitenanteil an, in dem die Farbe mit 100 % gesampelt wird. Der Wert 0 stellt die linke Position im Farbverlaufsfeld dar, 255 die rechte. Dieser Wert repräsentiert Positionen im Farbverlaufsfeld, nicht im Koordinatenraum des endgültigen Farbverlaufs, der breiter oder schmaler als das Farbverlaufsfeld sein kann. Geben Sie für jeden Wert im Parameter colors einen Wert an. Die folgende Abbildung zeigt für einen linearen Verlauf mit den beiden Farben Rot und Blau die Farbplatzierung im Verlauf basierend auf den verschiedenen Werten im ratios-Array: ratios Gradient [0, 127] [0, 255] [127, 255] Die Werte im Array müssen sich sequenziell erhöhen. Beispiel: [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — Eine Transformationsmatrix, wie sie von der flash.geom.Matrix-Klasse definiert wird. Die flash.geom.Matrix-Klasse umfasst eine createGradientBox()-Methode, mit der Sie die Matrix zur Verwendung mit der lineGradientStyle()-Methode auf einfache Weise festlegen können.
	spreadMethod:String (default = "pad") — Ein Wert aus der SpreadMethod-Klasse, der festlegt, welche Auftragstärke zu verwenden ist: SpreadMethod.PAD SpreadMethod.REFLECT SpreadMethod.REPEAT
	interpolationMethod:String (default = "rgb") — Ein Wert aus der InterpolationMethod-Klasse, der festlegt, welcher Wert zu verwenden ist. Angenommen, Sie haben einen einfachen linearen Farbverlauf zwischen zwei Farben (wobei der Parameter spreadMethod auf SpreadMethod.REFLECT gesetzt ist). Die verschiedenen Interpolationsmethoden haben folgende Auswirkung auf die Darstellung des Farbverlaufs: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Eine Zahl, die die Position des Farbverlaufsbrennpunkts steuert. Der Wert 0 bedeutet, dass der Brennpunkt in der Mitte liegt. Der Wert 1 bedeutet, dass der Brennpunkt an einem Rand des Farbverlaufskreises liegt. Der Wert -1 bedeutet, dass der Brennpunkt am anderen Rand des Farbverlaufskreises liegt. Werte, die kleiner als -1 oder größer als 1 sind, werden auf -1 bzw. 1 gerundet. Das folgende Bild zeigt einen Farbverlauf mit einem focalPointRatio von -0,75:

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.geom.Matrix; 
    import flash.display.GradientType;
    
    public class Graphics_lineGradientStyleExample extends Sprite
    {
        public function Graphics_lineGradientStyleExample()
        {
            var myShape:Shape = new Shape();
            var gradientBoxMatrix:Matrix = new Matrix();
  
            gradientBoxMatrix.createGradientBox(200, 40, 0, 0, 0);  
            
            myShape.graphics.lineStyle(5);
  
            myShape.graphics.lineGradientStyle(GradientType.LINEAR, [0xFF0000,
            0x00FF00, 0x0000FF], [1, 1, 1], [0, 128, 255], gradientBoxMatrix);
            
            myShape.graphics.drawRect(0, 0, 200, 40);
            myShape.graphics.drawCircle(100, 120, 50);  
             
            this.addChild(myShape);
    
        }
    }
}

Legt einen Shader für den Linienstrich beim Zeichnen von Linien fest.

Der Shaderlinienstil wird für nachfolgende Aufrufe von Graphics-Methoden, z. B. lineTo() oder drawCircle(), verwendet. Der Linienstil bleibt wirksam, bis Sie die lineStyle()- oderlineGradientStyle()-Methode oder wieder die lineBitmapStyle()-Methode mit anderen Parametern aufrufen.

Sie können die lineShaderStyle()-Methode während des Zeichnens eines Pfads aufrufen, um für unterschiedliche Linienabschnitte in einem Pfad unterschiedliche Stile zu verwenden.

Rufen Sie die lineStyle()-Methode vor der lineShaderStyle()-Methode auf, um einen Strich zu aktivieren, andernfalls ist der Linienstil undefined.

Wenn Sie die clear()-Methode aufrufen, wird der Linienstil wieder auf undefined gesetzt.

Parameter

Verwandte API-Elemente

Legt einen Linienstil fest, der für nachfolgende Aufrufe von Graphics-Methoden, z. B. lineTo() oder drawCircle(), verwendet wird. Der Linienstil bleibt wirksam, bis Sie die lineGradientStyle()-Methode, die lineBitmapStyle()-Methode oder wieder die lineStyle()-Methode mit anderen Parametern aufrufen.

Sie können die lineStyle()-Methode während des Zeichnens eines Pfads aufrufen, um für unterschiedliche Linienabschnitte in einem Pfad unterschiedliche Stile zu verwenden.

Hinweis: Wenn Sie die clear()-Methode aufrufen, wird der Linienstil wieder auf undefined gesetzt.

Hinweis: Flash Lite 4 unterstützt nur die ersten drei Parameter (thickness, color und alpha).

Parameter

Verwandte API-Elemente

Zeichnet eine Linie im aktuellen Linienstil von der aktuellen Zeichnungsposition zu (x, y). Die aktuelle Zeichnungsposition wird dann auf (x, y) gesetzt. Wenn das Anzeigeobjekt, in dem Sie zeichnen, mit den Flash-Zeichenwerkzeugen erstellte Objekte enthält, werden die Ergebnisse von Aufrufen der lineTo()-Methode unter diesen Objekten gezeichnet. Wenn Sie lineTo() vor der moveTo()-Methode aufrufen, wird die aktuelle Zeichnungsposition standardmäßig auf (0, 0) gesetzt. Wenn ein Parameter fehlt, schlägt die Ausführung dieser Methode fehl, und die aktuelle Zeichnungsposition wird beibehalten.

Parameter

package {
    import flash.display.Sprite;
    import flash.display.LineScaleMode;
    import flash.display.CapsStyle;
    import flash.display.JointStyle;
    import flash.display.Shape;


    public class Graphics_lineToExample extends Sprite {

        public function Graphics_lineToExample() {

            var trapezoid:Shape = new Shape();    

            trapezoid.graphics.lineStyle(10, 0xFFD700, 1, false, LineScaleMode.VERTICAL,
                               CapsStyle.NONE, JointStyle.MITER, 10);

            trapezoid.graphics.moveTo(100, 100);
 
            trapezoid.graphics.lineTo(120, 50);
            trapezoid.graphics.lineTo(200, 50);
            trapezoid.graphics.lineTo(220, 100);
            trapezoid.graphics.lineTo(100, 100); 

            this.addChild(trapezoid);
        }
    }
}

Verschiebt die aktuelle Zeichnungsposition auf (x, y). Wenn ein Parameter fehlt, schlägt die Ausführung dieser Methode fehl, und die aktuelle Zeichnungsposition wird beibehalten.

Parameter

package {
    import flash.display.Sprite;
    import flash.display.CapsStyle;
    import flash.display.LineScaleMode;

    public class Graphics_moveToExample extends Sprite
    {
        public function Graphics_moveToExample() {
            
            graphics.lineStyle(3, 0x990000, 0.25, false, 
                            LineScaleMode.NONE, CapsStyle.SQUARE);

            graphics.moveTo(10, 20);
            graphics.lineTo(20, 20);
            graphics.moveTo(30, 20);
            graphics.lineTo(50, 20);
            graphics.moveTo(60, 20);
            graphics.lineTo(80, 20);
            graphics.moveTo(90, 20);
            graphics.lineTo(110, 20);            
            graphics.moveTo(120, 20);
            graphics.lineTo(130, 20);           
        }
    }
}

Fragt ein Sprite- oder Shape-Objekt (und optional seine untergeordneten Elemente) nach dem Vektorgrafikinhalt ab. Das Ergebnis ist ein Vektor von IGraphicsData-Objekten. Transformationen werden auf das Anzeigeobjekt vor der Abfrage angewendet, damit sich die zurückgegebenen Pfade alle im Koordinatenraum befinden. Koordinaten in den Ergebnisdaten befinden sich relativ zur Bühne, nicht zum gesampelten Anzeigeobjekt.

Das Ergebnis beinhaltet die folgenden Objekttypen innerhalb der angegebenen Beschränkungen:

• GraphicsSolidFill
• GraphicsGradientFill
  • Alle Eigenschaften des Farbverlaufs werden von readGraphicsData() zurückgegeben.
  • Die zurückgegebene Matrix ähnelt der Eingabematrix, ist aber nicht dieselbe.
• GraphicsEndFill
• GraphicsBitmapFill
  • Die zurückgegebene Matrix ähnelt der Eingabematrix, ist aber nicht dieselbe.
  • repeat ist immer „true“.
  • smooth ist immer „false“.
• GraphicsStroke
  • thickness wird unterstützt.
  • fill unterstützt GraphicsSolidFill, GraphicsGradientFill und GraphicsBitmapFill, wie zuvor beschrieben.
  • Alle anderen Eigenschaften haben Standardwerte.
• GraphicsPath
  • Die einzigen unterstützten Befehle sind MOVE_TO, CURVE_TO und LINE_TO.

Die folgenden visuellen Elemente und Transformationen können nicht dargestellt werden und sind nicht in den Ergebnissen enthalten:

• Masken
• Text (mit einer Ausnahme): Statischer Text, der mit Anti-Aliasing-Typ („Anti-Aliasing für Animation“) definiert ist, wird als Vektorformen gerendert, sodass er im Ergebnis angezeigt wird.
• Shader-Füllungen
• Füllmethoden
• Skalierung im 9-teiligen Segmentraster
• Dreiecke (erstellt mit der drawTriangles()-Methode)
• Undurchsichtiger Hintergrund
• scrollrect-Einstellungen
• 2.5D-Transformationen
• Nicht sichtbare Objekte (Objekte, deren visible-Eigenschaft false ist)

Parameter

Verwandte API-Elemente

package
{
    import flash.display.GraphicsPathCommand;
    import flash.display.IGraphicsData;
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    
    public class ReadGraphicsDataExample extends Sprite
    {
        private var original:Shape;
        private var copy:Shape;
        
        public function ReadGraphicsDataExample()
        {
            original = new Shape();
            original.x = 50;
            original.y = 100;
            addChild(original);
            
            drawSquare();
            
            copy = new Shape();
            copy.x = 250;
            copy.y = 100;
            addChild(copy);
            
            stage.addEventListener(MouseEvent.CLICK, drawCopyOnClick);
        }
        
        private function drawCopyOnClick(event:MouseEvent):void
        {
            // reset
            copy.graphics.clear();
            
            // Sample the vector data. Move the original to 0,0
            // before sampling so that the coordinates match the 
            // relative coordinates of the original.
            var xPos:Number = original.x;
            var yPos:Number = original.y;
            original.x = 0;
            original.y = 0;
            var result:Vector.<IGraphicsData> = original.graphics.readGraphicsData(false);
            original.x = xPos;
            original.y = yPos;
            
            // re-draw
            copy.graphics.drawGraphicsData(result);
        }
        
        private function drawSquare():void
        {
            var squareCommands:Vector.<int> = new Vector.<int>(5, true);
            
            squareCommands[0] = GraphicsPathCommand.MOVE_TO;
            squareCommands[1] = GraphicsPathCommand.LINE_TO;
            squareCommands[2] = GraphicsPathCommand.LINE_TO;
            squareCommands[3] = GraphicsPathCommand.LINE_TO;
            
            var squareCoordinates:Vector.<Number> = new Vector.<Number>(8, true);
            squareCoordinates[0] = 0;
            squareCoordinates[1] = 0; 
            squareCoordinates[2] = 50; 
            squareCoordinates[3] = 0; 
            squareCoordinates[4] = 50; 
            squareCoordinates[5] = 50; 
            squareCoordinates[6] = 0; 
            squareCoordinates[7] = 50; 
            
            original.graphics.beginFill(0x003366);
            original.graphics.drawPath(squareCommands, squareCoordinates);
        }
    }
}

1. Deklarieren Sie eine size-Eigenschaft zur späteren Verwendung beim Bestimmen der Größe der einzelnen Formen.
2. Deklarieren Sie Eigenschaften, die die Hintergrundfarbe auf Orange, die Rahmenfarbe auf Dunkelgrau, die Rahmenbreite auf 0 Pixel und den Eckradius auf 9 Pixel setzen, und setzen Sie den Abstand zwischen Bühnenrand und anderen Objekten auf 5 Pixel.
3. Verwenden Sie die in den vorherigen Schritten deklarierten Eigenschaften zusammen mit den vorhandenen Methoden der Graphics-Klasse, um an den Koordinaten x = 0, y = 0 einen Kreis, ein abgerundetes Rechteck und ein Quadrat zu zeichnen.
4. Zeichnen Sie die einzelnen Formen am oberen Rand der Bühne neu, indem Sie an der Position x = 5, y = 5 beginnen und zwischen den Formen einen Abstand von jeweils 5 Pixel einhalten.

package {
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class GraphicsExample extends Sprite {
        private var size:uint         = 80;
        private var bgColor:uint      = 0xFFCC00;
        private var borderColor:uint  = 0x666666;
        private var borderSize:uint   = 0;
        private var cornerRadius:uint = 9;
        private var gutter:uint       = 5;

        public function GraphicsExample() {
            doDrawCircle();
            doDrawRoundRect();
            doDrawRect();
            refreshLayout();
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = gutter;
            lastChild.y = gutter;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = gutter;
                lastChild = child;
            }
        }

        private function doDrawCircle():void {
            var child:Shape = new Shape();
            var halfSize:uint = Math.round(size / 2);
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawCircle(halfSize, halfSize, halfSize);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRoundRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRoundRect(0, 0, size, size, cornerRadius);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRect(0, 0, size, size);
            child.graphics.endFill();
            addChild(child);
        }
    }
}