| Paket | flash.display |
| Klasse | public final class JointStyle |
| Vererbung | JointStyle  Object |
| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | AIR 1.0, Flash Player 9 |
joints der flash.display.Graphics.lineStyle()-Methode verwendet. Die Methode unterstützt drei Verbindungstypen: Winkel, Rund und Geschliffen (vgl. die folgenden Beispiele):
Verwandte API-Elemente
Öffentliche Eigenschaften
Vererbte öffentliche Eigenschaften ausblenden
Vererbte öffentliche Eigenschaften anzeigen
Öffentliche Methoden
Öffentliche Konstanten
| Konstante | Definiert von | ||
|---|---|---|---|
| BEVEL : String = "bevel" [statisch]
Legt im Parameter „joints“ der flash.display.Graphics.lineStyle()-Methode abgeschrägte Verbindungen fest. | JointStyle | ||
| MITER : String = "miter" [statisch]
Legt im Parameter „joints“ der flash.display.Graphics.lineStyle()-Methode spitzwinklige Verbindungen fest. | JointStyle | ||
| ROUND : String = "round" [statisch]
Legt im Parameter „joints“ der flash.display.Graphics.lineStyle()-Methode runde Verbindungen fest. | JointStyle | ||
Konstantendetails
BEVEL | Konstante |
public static const BEVEL:String = "bevel"| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | AIR 1.0, Flash Player 9 |
Legt im Parameter joints der flash.display.Graphics.lineStyle()-Methode abgeflachte Verbindungen fest.
MITER | Konstante |
public static const MITER:String = "miter"| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | AIR 1.0, Flash Player 9 |
Legt im Parameter joints der flash.display.Graphics.lineStyle()-Methode spitzwinklige Verbindungen fest.
ROUND | Konstante |
public static const ROUND:String = "round"| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | AIR 1.0, Flash Player 9 |
Legt im Parameter joints der flash.display.Graphics.lineStyle()-Methode runde Verbindungen fest.
Beispiele Verwendung dieses Beispiels
JointStyleExample.as
Im folgenden Beispiel wird die JointStyleExample-Klasse verwendet, um das Ergebnis von drei verschiedenen Verbindungsstilen zu verdeutlichen, die auf die drei verbundenen Linien angewendet werden. Dies wird in den folgenden Schritten erreicht:
- Die Eigenschaften der Linien sind wie folgt festgelegt:
- Die Linienlänge ist auf 80 Pixel festgelegt.
- Die Rahmenfarbe ist auf Orange gesetzt.
- Die Rahmenbreite ist auf 30 Pixel festgelegt.
- Die Hervorhebungsfarbe ist auf Grau gesetzt.
- Die Hervorhebungsgröße ist auf 0 Pixel festgelegt.
- Alpha ist auf 1 (also vollständige Füllung) gesetzt.
- Die Funktion „pixelHinting“ ist auf „false“ gesetzt (Striche werden nicht als ganze Pixel angezeigt).
- Als Modus für die Linienskalierung ist „normal“ angegeben, sodass die Stärke skaliert wird.
- Die Rahmenabschlüsse und Winkelgrenze sind deklariert, jedoch nicht gesetzt, sodass die Standardwerte verwendet werden.
- Der Klassenkonstruktor erstellt drei Gruppen von jeweils zwei verbundenen Liniensegmenten. Die Segmente beginnen bei x = 0, y = 0, indem für die drei Verbindungsstile (Winkel, Rund und Abgeflacht) jeweils die
doDrawCorner()-Methode aufgerufen wird. Bei jedem der drei Aufrufe derdoDrawCorner()-Methode werden die vorher aufgeführten Verbindungsstile und Eigenschaften verwendet, um zwei verbundene Liniensegmente und die dazugehörigen Linienhervorhebungen zu zeichnen. Dazu wird zuerst ein neueschild-Shape-Objekt erstellt, und dann werden die Methoden der Graphics-Klasse verwendet, um den Linienstil festzulegen und die Linien und Hervorhebungen zu zeichnen. Jede Instanz vonchildwird der Anzeigeliste hinzugefügt und sofort auf der Bühne gezeichnet. - Die verbundenen Liniensegmente werden erneut gezeichnet, indem die
refreshLayout()-Methode mit dem Wert y = 80 Pixel und dem Anfangspunkt bei x = 80 Pixel mit einem Abstand von 25 Pixel zwischen den Liniensegmenten verwendet wird.
package {
import flash.display.DisplayObject;
import flash.display.Graphics;
import flash.display.JointStyle;
import flash.display.LineScaleMode;
import flash.display.Shape;
import flash.display.Sprite;
public class JointStyleExample extends Sprite {
private var size:uint = 80;
private var borderColor:uint = 0xFFCC00;
private var borderSize:uint = 30;
private var highlightColor:uint = 0x666666;
private var highlightSize:uint = 0;
private var gutter:uint = 25;
private var borderAlpha:uint = 1;
private var borderPixelHinting:Boolean = false;
private var borderScaleMode:String = LineScaleMode.NORMAL;
private var borderCaps:String;
private var borderMiterLimit:uint;
public function JointStyleExample() {
doDrawCorner(JointStyle.MITER);
doDrawCorner(JointStyle.ROUND);
doDrawCorner(JointStyle.BEVEL);
refreshLayout();
}
private function doDrawCorner(jointStyle:String):void {
var halfSize:uint = Math.round(size / 2);
var child:Shape = new Shape();
child.graphics.lineStyle(borderSize,
borderColor,
borderAlpha,
borderPixelHinting,
borderScaleMode,
borderCaps,
jointStyle,
borderMiterLimit);
child.graphics.lineTo(0, 0);
child.graphics.lineTo(size, 0);
child.graphics.lineTo(halfSize, size);
child.graphics.endFill();
child.graphics.moveTo(0, 0);
child.graphics.lineStyle(highlightSize, highlightColor);
child.graphics.lineTo(0, 0);
child.graphics.lineTo(size, 0);
child.graphics.lineTo(halfSize, size);
addChild(child);
}
private function refreshLayout():void {
var ln:uint = numChildren;
var child:DisplayObject;
var lastChild:DisplayObject = getChildAt(0);
lastChild.x = size;
lastChild.y = size;
for (var i:uint = 1; i < ln; i++) {
child = getChildAt(i);
child.x = gutter + lastChild.x + lastChild.width;
child.y = size;
lastChild = child;
}
}
}
}
Tue Jun 12 2018, 10:04 AM Z