UIComponent  - AS3 Flash

Определяет или задает значение, указывающее, поддерживает ли компонент взаимодействие с пользователем. Значение true указывает, что компонент поддерживает взаимодействие с пользователем; значение false указывает на то, что оно не поддерживает его.

Если присвоить свойству enabled значение false, цвет контейнера становится тусклым, а данные, вводимые пользователем, блокируются (за исключением компонентов Label и ProgressBar).

Значением по умолчанию является true.

Определяет или задает логическое значение, указывающее, может ли компонент принимать фокус при щелчке пользователя. Значение true указывает, что он может получить фокус; значение false говорит о том, что это невозможно.

Если этому свойству присвоено значение false, фокус переносится на первый родительский объект, свойству mouseFocusEnabled которого присвоено значение true.

Значением по умолчанию является true.

Связанные элементы API

Определяет или задает объект FocusManager, управляющий фокусом для этого компонента и компонентов, находящихся на том же уровне иерархии. Каждый всплывающий компонент имеет собственный цикл фокусировки и экземпляр FocusManager. Воспользуйтесь этим свойством, чтобы открыть правильный экземпляр FocusManager для этого компонента.

Определяет или задает высоту компонента (в пикселах).

Настройка этого свойства приводит к отправке события resize. Чтобы получить подробную информацию о времени отправки события resize, перейдите по одноименной ссылке.

Если свойству scaleY компонента присвоено значение, отличное от 1,0, высота компонента, определяемая по его внутренним координатам, не будет совпадать со значением высоты для координат родительского объекта. Например, компонент высотой 100 пикселов, свойство scaleY которого равно 2, имеет значение, равное 100 пикселам в родительском объекте. При этом сохраняется внутреннее значение, указывающее, что его высота равна 50 пикселам.

Определяет или задает значение, указывающее, может ли компонент принимать фокус при щелчке пользователя. Значение true указывает, что он может получить фокус; значение false говорит о том, что это невозможно.

Если этому свойству присвоено значение false, фокус переносится на первый родительский объект, свойству mouseFocusEnabled которого присвоено значение true.

Значением по умолчанию является true.

Связанные элементы API

Умножает текущую ширину компонента на коэффициент масштабирования.

Связанные элементы API

Умножает текущую высоту компонента на коэффициент масштабирования.

Связанные элементы API

Определяет или задает значение, указывающее, видим ли текущий экземпляр компонента. Значение true указывает, что текущий компонент видим; значение false говорит о том, что он невидим.

Когда этому свойству присвоено значение true, объект отправляет событие show event. Когда этому свойству присвоено значение false, объект отправляет событие hide. В любом случае, дочерние объекты объекта не генерируют событий show и hide, если объект специально не записывает соответствующую реализацию.

Значением по умолчанию является true.

Связанные элементы API

Определяет или задает ширину компонента (в пикселах).

Настройка этого свойства приводит к отправке события resize. Чтобы получить подробную информацию о времени отправки события resize, перейдите по одноименной ссылке.

Если свойству scaleX компонента присвоено значение, отличное от 1,0, ширина компонента, определяемая по его внутренним координатам, не будет совпадать со значением ширины для координат родительского объекта. Например, компонент шириной 100 пикселов, свойство scaleX которого равно 2, имеет значение, равное 100 пикселам в родительском объекте. При этом сохраняется внутреннее значение, указывающее, что его ширина равна 50 пикселам.

Связанные элементы API

Определяет или задает координату, представляющую положение компонента по оси X в пределах родительского контейнера. Это значение описано в пикселах и рассчитывается слева.

Задание этого свойства вызывает отправку события ComponentEvent.MOVE.

Значением по умолчанию является 0.

Связанные элементы API

Определяет или задает координату, представляющую положение компонента по оси Y в пределах родительского контейнера. Это значение описано в пикселах и рассчитывается сверху.

Задание этого свойства вызывает отправку события move.

Связанные элементы API

Создает новый экземпляр компонента UIComponent.

Удаляет свойство style для экземпляра компонента.

При этом метод getStyle() не обязательно возвратит значение undefined.

Параметры

Связанные элементы API

Отображает или скрывает индикатор фокуса этого компонента.

Класс UIComponent реализует этот метод путем создания и размещения экземпляра класса, указанного стилем focusSkin.

Параметры

Инициирует немедленную операцию отрисовки без аннулирования всех элементов (в отличие от метода invalidateNow).

Возвращает объект, который в настоящее время имеет фокус.

Учтите, что этот метод не обязательно возвращает компонент, находящийся в фокусе. Он может вернуть внутренний субкомпонент компонента в фокусе. Чтобы определить компонент, находящийся в фокусе, воспользуйтесь свойством focusManager.focus.

Возвращает свойство style, установленное в последовательности для поиска стилей компонента.

Тип, возвращаемый этим методом, зависит от свойства стиля, который он определяет. Среди возможных типов можно назвать Boolean, String, Number, int, uint для цветов RGB, Class для обложки или любой вид объекта.

Если этот метод вызывается, чтобы определить то или иное свойство стиля, будет известен его тип, который можно сохранить в виде однотипной переменной. Приведение типов не требуется. Вместо этого послужит простой оператор назначения, как, например, этот:

var backgroundColor:uint = getStyle("backgroundColor");

Если свойство стиля не задано в цепочке подстановки стилей, этот метод возвратит значение undefined. Обратите внимание, что undefined — это особое значение, оно отличается от значений false, "", NaN, 0 и null. Значение действительного стиля не может быть undefined. Чтобы проверить, было ли задано значение, можно использовать статический метод StyleManager.isValidStyleValue().

Параметры

Связанные элементы API

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var myComboBox:ComboBox = new ComboBox();
myComboBox.setStyle("textPadding", 6);
myComboBox.setStyle("disabledAlpha", 0.8);

var styleObject:Object = ComboBox.getStyleDefinition();
var styleDP:DataProvider = new DataProvider();
var styleName:String;
var styleDefaultValue:String;
var styleCurrentValue:String;

for (styleName in styleObject) {
    styleDefaultValue = String(styleObject[styleName]);
    styleCurrentValue = String(myComboBox.getStyle(styleName));
    styleDP.addItem({name:styleName, defaultValue:styleDefaultValue, currentValue:styleCurrentValue});
}
styleDP.sortOn("name", Array.CASEINSENSITIVE);

var c1:DataGridColumn = new DataGridColumn("name");
c1.headerText = "Style name:";
var c2:DataGridColumn = new DataGridColumn("defaultValue");
c2.headerText = "Default style value:";
var c3:DataGridColumn = new DataGridColumn("currentValue");
c3.headerText = "Current style value:"

var styleDataGrid:DataGrid = new DataGrid();
styleDataGrid.addColumn(c1); // name
styleDataGrid.addColumn(c2); // defaultValue
styleDataGrid.addColumn(c3); // currentValue
styleDataGrid.dataProvider = styleDP;
styleDataGrid.setSize(stage.stageWidth - 20, stage.stageHeight - 20);
styleDataGrid.move(10, 10);
addChild(styleDataGrid);

Возвращает карту стилей по умолчанию для текущего компонента. Карта стилей содержит тип, который подходит для компонента в зависимости от стиля, используемого компонентом. Например, стиль disabledTextFormat содержит значение null или объект TextFormat. Вы можете воспользоваться этими стилями и вызвать метод setStyle() по отношению к текущему компоненту. Следующий код переопределяет стиль disabledTextFormat, выбранный по умолчанию для указанного компонента:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Связанные элементы API

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Возвращает указанный стиль для компонента, учитывая все стили, заданные на глобальном уровне, уровне компонентов и уровне экземпляров.

Например, если для свойства style компонента на глобальном уровне задано значение myStyle, а вы вызываете метод getStyle("myStyle") для экземпляра, для которого не задано значение свойства, то возвращенным значением будет null. При вызове метода getStyleValue("myStyle") возвращается значение «myStyle», так как оно действует на глобальном уровне.

Параметры

Помечает свойство как недопустимое и обновляет компонент в следующем кадре, если не указано иное.

Параметры

Объединяет стили из нескольких классов в одном объекте. Если стиль определен в нескольких объектах, используется первое найденное вхождение.

Параметры

Перемещает компонент в указанное положение в пределах его родительского компонента. Эффект при этом тот же, что и при смене местоположения компонента путем задания его свойств x и y. Вызов этого метода вызывает отправку события ComponentEvent.MOVE.

Чтобы переопределить метод updateDisplayList() в пользовательском компоненте, воспользуйтесь методом move() вместо того, чтобы задавать свойства x и y. Это происходит потому, что вызов метода move() вызывает немедленную отправку объекта события move после завершения операции перемещения. В отличие от этого, при изменении местоположения компонента путем задания свойств x и y объект события отправляется при следующем обновлении экрана.

Параметры

Связанные элементы API

Задает фокус на этот компонент. Компонент может, в свою очередь, поместить в фокус субкомпонент.

Примечание. Индикатор фокуса появляется только в компонентах TextInput и TextArea, когда фокус устанавливается с помощью этого метода. Когда пользователь переходит к компоненту с помощью клавиши Tab, индикатор фокуса появляется во всех компонентах.

Задает указанную высоту и ширину компонента.

Параметры

Задает свойство style для экземпляра компонента. Этот стиль может переопределить стиль, который задан глобально.

Вызов этого метода может привести к снижению производительности. Используйте его только в случае необходимости.

Параметры

Связанные элементы API

import fl.controls.Button;

var myFormat:TextFormat = new TextFormat();
myFormat.font = "Georgia";

var b:Button = new Button();
b.label = "Hello World";
b.setStyle("textFormat", myFormat);
addChild(b);

import fl.controls.Button;

var flashIcon:Loader = new Loader();
flashIcon.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
flashIcon.load(new URLRequest("http://www.helpexamples.com/flash/images/logo.png"));

var myButton:Button = new Button();
myButton.label = "Flash";
myButton.move(10, 10);
addChild(myButton);

function completeHandler(event:Event):void {
    flashIcon.width = 16;
    flashIcon.height = 16;
    myButton.setStyle("icon", flashIcon);
}

Проверяет и обновляет свойства и макет этого объекта, а также перерисовывает его при необходимости.

Свойства, требующие значительного объема вычислений обычно не обрабатываются до тех пор, пока выполнение сценария не завершится. Это происходит потому, что установка одного свойства может потребовать обработки остальных свойств. Например, задание свойства width может потребовать дополнительно пересчета значений ширины родительского или дочернего объектов. И если в сценарии ширина объекта рассчитывается несколько раз, эти взаимозависимые свойства могут также потребовать повторного вычисления. Воспользуйтесь этим методом, чтобы переопределить это поведение вручную.

Отправляется, когда видимый компонент становится невидимым.

Это событие имеет следующие свойства:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Связанные элементы API

Отправляется при перемещении компонента.

Это событие имеет следующие свойства:

import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

Отправляется при изменении размеров компонента.

Это событие имеет следующие свойства:

import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

Отправляется, когда невидимый компонент становится видимым.

Это событие имеет следующие свойства:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Связанные элементы API

Номер версии компонентов.

import fl.controls.CheckBox;

var myCheckBox:CheckBox = new CheckBox();
trace(myCheckBox.version);