ContextMenu  - AS3

Uma ocorrência da classe ContextMenuBuiltInItems com as seguintes propriedades: forwardAndBack, loop, play, print, quality, rewind, save e zoom. A configuração dessas propriedades como false remove os itens correspondentes do menu do objeto ContextMenu especificado. Essas propriedades são enumeráveis e estão configuradas como true por padrão.

Observação: No AIR, os menus de contexto não têm nenhum item interno.

Elementos da API relacionados

Uma ocorrência da classe ContextMenuClipboardItems com as seguintes propriedades: cut, copy, paste, delete, selectAll. Definir uma dessas propriedades como false remove os itens de menu correspondentes do menu da área de transferência.

Elementos da API relacionados

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Especifica se o menu da área de transferência deve ser usado. Se o valor for true, o clipboardItems determinará que itens estão ativados ou desativados no menu da área de transferência.

Se a propriedade link não for null, essa propriedade clipBoardMenu será ignorada.

Uma matriz de objetos ContextMenuItem. Cada objeto da matriz representa um item de menu de contexto que você definiu. Use essa propriedade para adicionar, remover ou modificar esses itens do menu personalizado.

Para incluir novos itens de menu, você cria um objeto ContextMenuItem e depois insere-o na matriz customItems (por exemplo, com o uso do Array.push()). Para obter mais informações sobre a criação de itens de menu, consulte a entrada de classe ContextMenuItem.

Elementos da API relacionados

A propriedade isSupported será definida como true se a classe ContextMenu for suportada na plataforma atual; de outra maneira, ela será definida como false.

A matriz de itens personalizados nesse menu.

Usar essa propriedade equivale a usar a propriedade customItems. A matriz é classificada por ordem de exibição.

O URLRequest do link. Se esta propriedade for null, um menu de contexto normal será exibido. Se esta propriedade não for null, o menu de contexto de link será exibido e operará na url especificada.

Se um link for especificado, a propriedade clipboardMenu será ignorada.

O valor padrão é null.

O número de itens nesse menu.

Cria um objeto ContextMenu.

Elementos da API relacionados

Adiciona um item de menu à parte inferior do menu.

Ao criar um menu de contexto, você pode adicionar objetos NativeMenuItem ou ContextMenuItem. No entanto, é recomendável usar apenas um tipo de objeto em um menu de contexto de forma que todos os itens do menu tenham as mesmas propriedades.

Parâmetros

Cria uma cópia do objeto ContextMenu especificado. A cópia herda todas as propriedades do objeto de menu original.

Reporta se este menu contém o item de menu especificado.

Parâmetros

Ativa este menu no local especificado.

Observação: No Flash Player, não há suporte a esse método.

Parâmetros

Obtém o item no índice especificado.

Parâmetros

Obtém a posição do item especificado.

Parâmetros

Oculta todos os itens de menu embutidos (exceto Configurações) no objeto ContextMenu especificado. Se a versão depuradora do Flash Player está sendo executada, aparece o item de menu Depuração, embora esteja esmaecido para os arquivos SWF que não estejam com depuração remota ativada.

Esse método esconde apenas os itens de menu que aparecem no menu de contexto padrão; ele não afeta os itens que aparecem nos menus editar e erro.

Esse método funciona com a configuração de todos os membros boolianos domy_cm.builtInItems para false. Você pode seletivamente tornar visível um item embutido com a configuração de seu membro correspondente no my_cm.builtInItems para true.

Observação: No AIR, os menus de contexto não têm nenhum item interno. Chamar esse método não terá nenhum efeito.

Elementos da API relacionados

Remove todos os itens do menu.

Remove e retorna o item de menu no índice especificado.

Parâmetros

Despachado na primeira vez que um usuário gera um menu de contexto, mas antes da exibição do conteúdo desse menu de contexto. Isso permite que o programa modifique o conjunto de itens do menu de contexto antes de exibir o menu. O usuário gera o menu de contexto clicando duas vezes com o botão da direita do dispositivo apontador.

Esse evento tem as seguintes propriedades:

1. É declarada a propriedade myContextMenu e depois atribuída a um novo objeto ContextMenu e é declarada a propriedade redRectangle do tipo Sprite.
2. É chamado o método removeDefaultItems(), que remove todos os itens de menu de contexto embutidos, exceto Imprimir.
3. É chamado o método addCustomMenuItems(), que coloca um item na seleção de menu chamado Red to Black na matriz defaultItems com o uso do método de Matriz push(). Um ouvinte de evento menuItemSelect é adicionado ao objeto ContextMenuItem e o método associado é chamado menuItemSelectHandler(). Esse método imprime algumas instruções com o uso de trace(), sempre que o menu de contexto for acessado e Red to Black for selecionado. Também, o quadrado vermelho é removido e substituído por um preto.
4. Um listener de evento do tipo menuSelect é incluído, juntamente com o método associado menuSelectHandler, que apenas imprime as três instruções com o uso de trace(), todas as vezes que um item de menu de contexto é aberto.
5. Em seguida, o addChildren() desenha um quadrado vermelho e o coloca na lista de exibição, onde é exibido imediatamente.
6. Finalmente, o myContextMenu é atribuído ao menu de contexto do sprite redRectangle, de modo que o menu de contexto personalizado seja exibido apenas quando o ponteiro do mouse está sobre o quadrado.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}