ContextMenuItem  - AS3

Pacote	flash.ui
Classe	public final class ContextMenuItem
Herança	ContextMenuItem NativeMenuItem EventDispatcher Object

Versão da linguagem:

ActionScript 3.0

Versões de runtime:

AIR 1.0, Flash Player 9

A classe ContextMenuItem representa um item no menu de contexto. Cada objeto ContextMenuItem tem uma legenda (texto), exibida no menu de contexto. Para acrescentar um item novo a um menu de contexto, você o insere na matriz customItems de um objeto ContextMenu.

Com as propriedades da classe ContextMenuItem você pode ativar ou desativar itens específicos do menu e pode torná-los visíveis ou invisíveis.

Você grava um manipulador de eventos para o evento menuItemSelect, de modo a inserir funcionalidade no item de menu quando o usuário selecioná-lo.

Os itens de menu personalizados aparecem no topo do menu de contexto, acima dos itens embutidos. Uma barra separadora divide os itens do menu personalizados dos itens embutidos. Em AIR, não há nenhum item construído e as seguintes restrições não se aplicam ao conteúdo na caixa de proteção de aplicativo de AIR.

Restrições:

• Você só pode incluir até 15 itens personalizados no menu de contexto.
• Cada legenda deve conter pelo menos um caractere visível.
• Caracteres de controle, novas linhas e outros espaços em branco são ignorados.
• As legendas só podem ter até 100 caracteres de comprimento.
• As legendas idênticas a qualquer item de menu embutido, ou a qualquer outro item personalizado, são ignoradas, esteja esse item visível ou não. As legendas de menu são comparadas às legendas embutidas ou legendas personalizadas existentes sem levar em consideração a distinção entre maiúsculas e minúsculas, pontuação ou espaço em branco
• As legendas a seguir não são permitidas, mas as palavras podem ser usadas em conjunto com outras para formar uma legenda personalizada (por exemplo, embora "Pasta" não seja permitido, "Pastas são ótimas" é):

   Save
   Zoom In
   Zoom Out
   100%
   Show All
   Quality
   Play
   Loop
   Rewind
   Forward
   Back
   Movie not loaded
   About
   Print
   Show Redraw Regions
   Debugger
   Undo
   Cut
   Copy
   Paste
   Delete
   Select All
   Open
   Open in new window
   Copy link
   

• Nenhuma das palavras a seguir pode aparecer sozinha em uma legenda personalizada ou em conjunto com outras palavras:

   Adobe
   Macromedia
   Flash Player
   Settings
   

Observação: Quando o player está sendo executado em um sistema não inglês, as strings da legenda são comparadas com a lista em inglês e com as equivalentes localizadas.

Veja os exemplos

Elementos da API relacionados

---

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}