ContextMenuEvent  - AS3

O objeto de lista de exibição ao qual o menu está conectado. Isto pode ser o destino do mouse mouseTarget ou um de seus ancestrais na lista de exibição.

Indica se a propriedade mouseTarget foi definida como null por motivos de segurança. Caso o valor nominal de menuTarget seja uma referência para DisplayObject em outra área de segurança, o menuTarget é definido como null, a menos que haja permissão em ambas as direções nos limites da caixa de proteção. A permissão é estabelecida pela chamada de Security.allowDomain() em um arquivo SWF, ou fornecendo um arquivo de política no servidor de um arquivo de imagem e definindo o sinalizador LoaderContext.checkPolicyFile durante o carregamento da imagem.

Elementos da API relacionados

O objeto de lista de exibição no qual o usuário clicou com o botão direito para exibir o menu de contexto. Isto pode ser o objeto da lista de exibição ao qual o menu está anexado (contextMenuOwner) ou um de seus descendentes da lista de exibição.

O valor dessa propriedade pode ser null em duas situações: se não houver nenhum destino do mouse, por exemplo, passar o mouse sobre algo que está em segundo plano, ou se houver um destino do mouse, mas que esteja em uma área de segurança à qual você não tem acesso. Use a propriedade isMouseTargetInaccessible() para determinar qual desses motivos se aplica.

Elementos da API relacionados

Cria um objeto Event que contém informações específicas sobre eventos de menu. Objetos Event são transmitidos como parâmetros para ouvintes de eventos.

Elementos da API relacionados

Cria uma cópia do objeto ContextMenuEvent e define o valor de cada propriedade para corresponder ao do original.

Retorna uma string que contém todas as propriedades do objeto ContextMenuEvent. A string está no seguinte formato:

[ContextMenuEvent type=value bubbles=value cancelable=value ... contextMenuOwner=value]

Define o valor da propriedade type de um objeto de evento menuItemSelect.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Define o valor da propriedade type de um objeto de evento menuSelect.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

1. A propriedade myContextMenu é declarada e então atribuída a um novo objeto ContextMenu, e a propriedade redRectangle (do tipo Sprite) é declarada.
2. O método removeDefaultItems() é chamado. Este método remove todos os itens de menu de contexto incorporados, exceto Imprimir.
3. O método addCustomMenuItems() é chamado. Este método coloca um item de menu Inverter cores na matriz defaultItems usando o método de Arraypush(). Um ouvinte de evento menuItemSelect é adicionado ao objeto ContextMenuItem e o método associado é chamado menuItemSelectHandler(). Este método imprime algumas instruções trace() sempre que o usuário seleciona Inverter cores no menu de contexto. Além disso, o quadrado vermelho se torna preto e o preto se torna vermelho.
4. De volta ao construtor, um ouvinte de evento menuSelect é adicionado, juntamente com o método associado menuSelectHandler(), que simplesmente imprime três instruções trace() toda vez que um item no menu de contexto é selecionado.
5. O construtor chama o addChildren(), que desenha um quadrado vermelho e o adiciona à lista de exibição, que exibe imediatamente o quadrado.
6. Finalmente, o myContextMenu é atribuído ao menu de contexto da propriedade redRectangle, de modo que o menu de contexto personalizado só será exibido quando o ponteiro do mouse estiver sobre o quadrado.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}