Matrix3D  - AS3

Um Número que determina se uma matriz pode ser invertida.

Um objeto Matrix3D deve ser invertível. Você pode usar a propriedade determinant para verificar se um objeto Matrix3D é invertível. Se o determinando é zero, o inverso da matriz não existe. Por exemplo, se uma linha ou coluna inteira da matriz for zero ou se duas linhas ou colunas forem iguais, o determinante será zero. O determinante é usado também para solucionar uma série de equações.

Somente uma matriz quadrada, como a classe Matrix3D, tem um determinante.

Elementos da API relacionados

Um objeto Vector3D que mantém a posição, a coordenada tridimensional (x,y,z) de um objeto de exibição dentro do quadro de referência da transformação. A propriedade position permite acesso imediato ao vetor de translação da matriz do objeto de exibição sem precisar decompor e recompor a matriz.

Com a propriedade position, você pode obter e definir os elementos de translação da matriz de transformação.

Elementos da API relacionados

Um Vetor de 16 Números, em que cada quatro elementos é uma coluna de uma matriz 4x4.

Uma exceção será emitida se a propriedade rawData for definida como uma matriz não invertível. O objeto Matrix3D deve ser invertível. Se for necessária uma matriz não invertível, crie uma subclasse do objeto Matrix3D.

Elementos da API relacionados

Cria um objeto Matrix3D. Os objetos Matrix3D podem ser inicializados com um Vetor de 16 números, em que cada quatro elementos representam uma coluna. Quando o objeto Matrix3D for criado, você poderá acessar os elementos da matriz com a propriedade rawData.

Se nenhum parâmetro for definido, o construtor produzirá um objeto Matrix3D unitário ou de identidade. Na notação da matriz, uma matriz de identidade tem o valor 1 para todos os elementos na posição diagonal principal e um valor zero para todos os outros elementos. O valor da propriedade rawData de uma matriz de identidade é: 1,0,0,0,0,1,0,0,0,0,1,0,0,0,0,1. O valor da translação ou da posição da matriz de identidade é Vector3D(0,0,0), a definição de rotação é Vector3D(0,0,0) e o valor do dimensionamento é Vector3D(1,1,1).

Elementos da API relacionados

Anexa a matriz multiplicando outro objeto Matrix3D pelo objeto Matrix3D atual. O resultado combina as duas transformações de matriz. Você pode multiplicar um objeto Matrix3D por várias matrizes. O objeto Matrix3D final contém o resultado de todas as transformações.

A multiplicação de matriz é diferente da adição de matriz. A multiplicação de matriz não é comutativa. Em outras palavras, A vezes B não é igual a B vezes A. Com o método append(), a multiplicação ocorre do lado esquerdo, significando que o objeto Matrix3D lhs está no lado esquerdo do operador de multiplicação.

Na primeira vez que o método append() é chamado, ele faz uma modificação relativa ao espaço do pai. As chamadas subsequentes são relativas ao quadro de referência do objeto Matrix3D anexado.

O método append() substitui a matriz atual pela matriz anexada. Para anexar duas matrizes sem alterar a matriz atual, copie a matriz atual usando o método clone() e aplique o método append() à copia.

Parâmetros

Elementos da API relacionados

Acrescenta uma rotação incremental a um objeto Matrix3D. Quando o objeto Matrix3D é aplicado a um objeto de exibição, a matriz executa a rotação depois de outras transformações no objeto Matrix3D.

A rotação do objeto de exibição é definida por um eixo, um grau incremental de rotação ao redor do eixo e um ponto de pivô opcional do centro da rotação do objeto. O eixo pode ser qualquer direção em geral. Os eixos comuns são X_AXS (Vector3D (1.0.0)), Y_AXIS (Vector3D (0.1.0)) e Z_AXIS (Vector3D (0.0.1)). Na terminologia da aviação, a rotação sobre o eixo y é chamada de guinada. A rotação sobre o eixo x é chamada de arfada. A rotação sobre o eixo z é chamada de rolamento.

A ordem de transformação é importante. Uma rotação seguida de uma transformação de translação produz um efeito diferente de uma translação seguida de uma transformação de rotação.

O efeito da rotação não é absoluto. Ele é relativo à posição e à orientação atuais. Para fazer uma alteração absoluta na matriz de transformação, use o método recompose(). O método appendRotation() é diferente também da propriedade de rotação do eixo do objeto de exibição, por exemplo, a propriedade rotationX. A propriedade de rotação é sempre executada antes de qualquer translação, ao passo que o método appendRotation() é executado em relação a tudo o que já está na matriz. Para verificar se será obtido um efeito semelhante ao da propriedade de rotação do eixo do objeto de exibição, use o método prependRotation(), que executa a rotação antes de outras transformações na matriz.

Quando a transformação do método appendRotation() é aplicada a um objeto Matrix3D de um objeto de exibição, os valores da propriedade de rotação armazenados em cache do objeto de exibição são invalidados.

Uma forma de fazer com que um objeto de exibição gire ao redor de um ponto específico relativo à sua localização é definir a translação do objeto como o ponto especificado, girar o objeto usando o método appendRotation() e transladar o objeto de volta à posição original. No exemplo a seguir, o objeto de exibição 3D myObject faz uma rotação do eixo y ao redor da coordenada (10,10,0).

    
    myObject.z = 1; 
    myObject.transform.matrix3D.appendTranslation(10,10,0);
    myObject.transform.matrix3D.appendRotation(1, Vector3D.Y_AXIS);
    myObject.transform.matrix3D.appendTranslation(-10,-10,0);
     
    

Parâmetros

Elementos da API relacionados

Acrescenta uma alteração de dimensionamento incremental nos eixos x, y e z a um objeto Matrix3D. Quando o objeto Matrix3D é aplicado a um objeto de exibição, a matriz executa as alterações de dimensionamento depois de outras transformações no objeto Matrix3D. O fator de dimensionamento padrão é (1.0, 1.0, 1.0).

O dimensionamento é definido como um conjunto de três alterações incrementais ao longo dos três eixos (x,y,z). Você pode multiplicar cada eixo por um número diferente. Quando as alterações de dimensionamento são aplicadas a um objeto de exibição, o tamanho do objeto aumenta ou diminui. Por exemplo, se os eixos x, y e z forem definidos como dois, o tamanho do objeto será duplicado e, se eles forem definidos como 0,5, o tamanho será dividido por dois. Para que a transformação de dimensionamento afete somente um eixo específico, defina os outros parâmetros como um. Um parâmetro de valor um significa que não há alterações de dimensionamento no eixo específico.

O método appendScale() pode ser usado para redimensionar e também para gerenciar distorções, como expansão ou contração de um objeto de exibição, ou para aplicar mais zoom ou menos zoom em um local. As transformações de dimensionamento são realizadas automaticamente durante a rotação e a translação do objeto de exibição.

A ordem de transformação é importante. Um redimensionamento seguido de uma transformação de translação produz um efeito diferente de uma translação seguida de uma transformação de redimensionamento.

Parâmetros

Elementos da API relacionados

Acrescenta uma translação incremental, um reposicionamento ao longo dos eixos x, y e z, a um objeto Matrix3D. Quando o objeto Matrix3D é aplicado a um objeto de exibição, a matriz executa as alterações de translação depois de outras transformações no objeto Matrix3D.

A translação é definida como um conjunto de três alterações incrementais ao longo dos três eixos (x,y,z). Quando a transformação é aplicada a um objeto de exibição, esse objeto se movimenta a partir do local atual ao longo dos eixos x, y e z, conforme especificado pelos parâmetros. Para que a translação afete somente um eixo específico, defina os outros parâmetros como zero. Um parâmetro zero significa que não há alterações no eixo específico.

As alterações de translação não são absolutas. Elas são relativas à posição e à orientação atuais da matriz. Para fazer uma alteração absoluta na matriz de transformação, use o método recompose(). A ordem de transformação também é importante. Uma translação seguida de uma transformação de rotação produz um efeito diferente de uma rotação seguida de uma translação.

Parâmetros

Elementos da API relacionados

Retorna um novo objeto Matrix3D que é uma cópia exata do objeto Matrix3D atual.

Copia um objeto de Vector3D na coluna específica do objeto de chamada Matrix3D.

Parâmetros

Copia a coluna específica do objeto de chamada Matrix3D no objeto de Vector3D.

Parâmetros

Copia todos os dados de matriz do objeto de origem Matrix3D para o objeto Matrix3D da chamada.

Parâmetros

Copia todos dos dados de vetor do objeto vetor de origem para a chamada objeto Matrix3D. O parâmetro de índice opcional permite selecionar qualquer slot inicial no vetor.

Parâmetros

Copia todos dos dados de matriz do objeto de chamada Matrix3D para o vetor fornecido. O parâmetro de índice opcional permite selecionar qualquer slot de inicial no vetor.

Parâmetros

Copia um objeto de Vector3D na linha específica do objeto de chamada Matrix3D.

Parâmetros

Copia a linha específica do objeto de chamada Matrix3D no objeto de Vector3D.

Parâmetros

Parâmetros

Retorna as configurações de translação, rotação e dimensionamento da matriz de transformação como um Vector de três objetos Vector3D. O primeiro objeto Vector3D contém os elementos da translação. O segundo objeto Vector3D contém os elementos da rotação. O terceiro objeto Vector3D contém os elementos do dimensionamento.

Alguns métodos Matrix3D, como o interpolateTo(), decompõem e recompõem automaticamente a matriz para executar a transformação.

Para modificar a transformação da matriz com um quadro de referência pai absoluto, recupere as configurações com o método decompose() e faça as alterações apropriadas. Assim, você pode definir o objeto Matrix3D como a transformação modificada usando o método recompose().

O parâmetro do método decompose() especifica o estilo de orientação que deverá ser usado na transformação. A orientação padrão é eulerAngles, que define a orientação com três ângulos separados de rotação para cada eixo. As rotações ocorrem consecutivamente e não alteram o eixo um do outro. As propriedades do eixo do objeto de exibição executam a transformação do estilo de orientação Ângulos de Euler. As outras opções de estilo de orientação são axisAngle e quaternion. A orientação de tipo Ângulo do eixo usa uma combinação de um eixo e um ângulo para determinar a orientação. O eixo ao redor do qual o objeto gira é um vetor unitário que representa uma direção. O ângulo representa a magnitude da rotação sobre o vetor. A direção também determina o lado para o qual um objeto de exibição está voltado e o ângulo determina o trajeto de movimentação. Os métodos appendRotation() e prependRotation() utilizam a orientação Ângulo do eixo. A orientação de quatérnion utiliza números complexos e o quarto elemento de um vetor. Os três eixos de rotação (x,y,z) e um ângulo de rotação (w) representam a orientação. O método interpolate() utiliza o quatérnion.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.geom.*;
    import flash.events.Event;
    
    public class Matrix3DdecomposeExample extends MovieClip {
        private var ellipse:Shape = new Shape();

        public function Matrix3DdecomposeExample():void {
            
            ellipse.x = (this.stage.stageWidth / 2);
            ellipse.y = (this.stage.stageHeight - 40);
            ellipse.z = 1;
            ellipse.graphics.beginFill(0xFF0000);
            ellipse.graphics.lineStyle(2);
            ellipse.graphics.drawEllipse(0, 0, 50, 40);
            ellipse.graphics.endFill();
            addChild(ellipse);

            ellipse.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }

        private function enterFrameHandler(e:Event):void {  

            var v3:Vector.<Vector3D> = new Vector.<Vector3D>(3);
            v3 = ellipse.transform.matrix3D.decompose();
            v3[0].incrementBy(new Vector3D(0,0,1));
            v3[2].incrementBy(new Vector3D(0.01,0,0));
            ellipse.transform.matrix3D.recompose(v3);
        }
    }
}

Usa a matriz de transformação sem seus elementos de translação para transformar um objeto Vector3D de uma coordenada de espaço para outra. O objeto Vector3D retornado conterá as novas coordenadas depois de aplicadas as transformações de rotação e dimensionamento. Se o método deltaTransformVector() aplicar uma matriz que contiver apenas uma transformação de translação, o Vector3D retornado será igual ao objeto Vector3D original.

Você pode usar o método deltaTransformVector() para que um objeto de exibição de um espaço de coordenadas responda à transformação de rotação de um segundo objeto de exibição. O objeto não copia a rotação; ele apenas altera sua posição para refletir as alterações na rotação. Por exemplo, para usar a API display.Graphics para desenhar objeto de exibição 3D em rotação, mapeie as coordenadas de rotação do objeto para um ponto bidimensional. Primeiramente, recupere as coordenadas 3D do objeto após cada rotação, usando o método deltaTransformVector(). Em seguida, aplique o método local3DToGlobal() do objeto de exibição para transladar as coordenadas tridimensionais aos pontos bidimensionais. Em seguida, você pode usar os pontos bidimensionais para desenhar o objeto 3D em rotação.

Observação: este método define automaticamente o componente w do Vector3D transmitido como 0.0.

Parâmetros

Elementos da API relacionados

Converte a matriz atual em uma matriz de identidade ou unitária. Uma matriz de identidade tem o valor 1 para os elementos na diagonal principal e um valor zero para todos os outros elementos. O resultado é uma matriz em que o valor de rawData é 1,0,0,0,0,1,0,0,0,0,1,0,0,0,0,1, a rotação está definida como Vector3D(0,0,0), a posição ou a translação está definida como Vector3D(0,0,0) e o dimensionamento está definido como Vector3D(1,1,1). Veja uma representação de matriz de identidade:

Um objeto transformado pela aplicação de uma matriz de identidade não realiza transformações. Em outras palavras, se uma matriz for multiplicada por uma matriz de identidade, o resultado será uma matriz idêntica à matriz original.

Interpola a tradução, rotação, e transformação de escala de uma matriz em direção àqueles da matriz de destino.

O método interpolate() evita que alguns resultados indesejáveis ocorram quando são usados métodos como as propriedades de rotação do eixo do objeto de exibição. O método interpolate() invalida o valor da propriedade de rotação armazenado em cache do objeto de exibição e converte os elementos de orientação da matriz do objeto de exibição em quatérnion antes da interpolação. Esse método garante o caminho mais curto e eficiente para a rotação. Além disso, ele produz uma rotação suave e livre de gimbal lock (travamento das rotações). O problema de gimbal lock pode ocorrer ao usar Ângulos de Euler, em que cada eixo é manipulado de forma independente. Durante a rotação ao redor de dois ou mais eixos, os eixos podem ficar alinhados, levando a resultados inesperados. A rotação de quatérnion evita esse problema.

As chamadas consecutivas ao método interpolate() podem produzir o efeito de um objeto de exibição iniciando rapidamente e, depois, se aproximando lentamente de outro objeto de exibição. Por exemplo, se você definir o parâmetro thisMat como o objeto Matrix3D retornado, o parâmetro toMat como o objeto Matrix3D associado do objeto de exibição de destino e o parâmetro percent como 0,1, o objeto de exibição se movimentará 10% em direção ao objeto de destino. Nas chamadas ou nos quadros subsequentes, o objeto se movimentará 10% dos 90% restantes, em seguida, 10% da distância restante, e continua até chegar ao destino.

Parâmetros

Elementos da API relacionados

Interpola esta matriz em direção à tradução, rotação, e transformações de escala da matriz de destino.

O método interpolateTo() evita que resultados indesejáveis ocorram quando são usados métodos como as propriedades de rotação do eixo do objeto de exibição. O método interpolateTo() invalida o valor da propriedade de rotação armazenado em cache do objeto de exibição e converte os elementos de orientação da matriz do objeto de exibição em quatérnion antes da interpolação. Esse método garante o caminho mais curto e eficiente para a rotação. Além disso, ele produz uma rotação suave e livre de gimbal lock (travamento das rotações). O problema de gimbal lock pode ocorrer ao usar Ângulos de Euler, em que cada eixo é manipulado de forma independente. Durante a rotação ao redor de dois ou mais eixos, os eixos podem ficar alinhados, levando a resultados inesperados. A rotação de quatérnion evita esse problema.

Observação: no caso de uma interpolação, o valor de dimensionamento da matriz será redefinido e a matriz normalizada.

As chamadas consecutivas ao método interpolateTo() podem produzir o efeito de um objeto de exibição iniciando rapidamente e, depois, se aproximando lentamente de outro objeto de exibição. Por exemplo, se o parâmetro de percentual for definido como 0,1, o objeto de exibição se movimentará 10% em direção ao objeto de destino especificado pelo parâmetro toMat. Nas chamadas ou nos quadros subsequentes, o objeto se movimentará 10% dos 90% restantes, em seguida, 10% da distância restante, e continua até chegar ao destino.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.display.Graphics;
    import flash.geom.*;
    import flash.events.Event;

    public class InterpolateToExample extends MovieClip {
        private var ellipse1:Shape = new Shape();
        private var ellipse2:Shape = new Shape();

        public function InterpolateToExample():void {

            ellipse1 = myEllipses(250, 100, 500, 0xFF0000);
            addChild(ellipse1);
            
            ellipse2 = myEllipses(-30, 120, 1, 0x00FF00);
            addChild(ellipse2);

            addEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }

        private function myEllipses(x:Number, y:Number, z:Number, c:Number):Shape {
            var s:Shape = new Shape();                            
            s.x = x;
            s.y = y;
            s.z = z;
            s.graphics.beginFill(c);
            s.graphics.lineStyle(2);
            s.graphics.drawEllipse(100, 50, 100, 80);
            s.graphics.endFill();
            return s;
        }

        private function enterFrameHandler(e:Event) {
            ellipse1.rotationY += 1;

            ellipse2.transform.matrix3D.interpolateTo(ellipse1.transform.matrix3D, 0.1);
        }
    }
}

Inverte a matriz atual. Uma matriz invertida tem o mesmo tamanho da original, mas realiza a transformação oposta à da original. Por exemplo, se a matriz original tiver uma rotação de objeto ao redor do eixo x em uma direção, o inverso da matriz terá a rotação do objeto ao redor do eixo na direção oposta. A aplicação de matriz invertida a um objeto desfaz a transformação realizada pela matriz original. Se uma matriz for multiplicada pela matriz inversa, o resultado será uma matriz de identidade.

O inverso de uma matriz pode ser usado para dividir uma matriz pela outra. A forma de dividir a matriz A pela B é multiplicar a matriz A pelo inverso da matriz B. A matriz inversa pode ser usada também com um espaço de câmera. Quando a câmera se move no espaço global, o objeto no espaço global precisa se movimentar na direção oposta para transformar da visão global para o espaço da câmera ou da visão. Por exemplo, quando a câmera se aproxima, os objetos ficam maiores. Em outras palavras, se a câmera mover-se para baixo do eixo z global, o objeto se movimentará para cima do eixo z.

O método invert() substitui a matriz atual pela matriz invertida. Para inverter uma matriz sem alterar a matriz atual, primeiramente copie a matriz atual usando o método clone() e depois aplique o método invert() à copia.

O objeto Matrix3D deve ser invertível.

Elementos da API relacionados

Gira o objeto de exibição para que ele se volte a uma determinada posição. Esse método permite uma modificação no local para a orientação. O vetor de direção para frente dos pontos do objeto de exibição (o objeto Vector3D em) na posição relativa global especificada. A direção para cima do objeto de exibição é especificada com o objeto Vector3D up.

O método pointAt() invalida o valor da propriedade de rotação armazenado em cache do objeto de exibição. O método decompõe a matriz do objeto de exibição e modifica os elementos de rotação para que o objeto vire para a posição especificada. Ele recompõe (atualiza) a matriz do objeto de exibição que executa a transformação. Se o objeto estiver apontando para um destino em movimento, por exemplo, a posição de um objeto em movimento, a cada chamada subsequente o método terá a rotação do objeto em direção ao destino em movimento.

Nota: se você usar o método Matrix3D.pointAt() sem definir os parâmetros opcionais, um objeto de destino não ficará em frente da posição relativa mundial especificada por padrão. Você deve estabelecer os valores de at para o eixo -y (0,-1,0) e up para o eixo -z (0,0,-1).

Parâmetros

Elementos da API relacionados

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.display.Graphics;
    import flash.geom.*;
    import flash.events.Event;

    public class PointAtExample extends MovieClip {
        private var ellipse:Shape = new Shape();
        private var triangle:Shape = new Shape();

        public function PointAtExample():void {
            ellipse.graphics.beginFill(0xFF0000);
            ellipse.graphics.lineStyle(2);
            ellipse.graphics.drawEllipse(30, 40, 50, 40);
            ellipse.graphics.endFill();
            ellipse.x = 100;
            ellipse.y = 150;
            ellipse.z = 1;

            triangle.graphics.beginFill(0x0000FF);
            triangle.graphics.moveTo(0, 0);
            triangle.graphics.lineTo(40, 40);
            triangle.graphics.lineTo(80, 0);
            triangle.graphics.lineTo(0, 0);
            triangle.graphics.endFill();
            triangle.x = 200;
            triangle.y = 50;
            triangle.z = 1;

            addChild(ellipse);
            addChild(triangle);

            ellipse.addEventListener(Event.ENTER_FRAME, ellipseEnterFrameHandler);
            triangle.addEventListener(Event.ENTER_FRAME, triangleEnterFrameHandler);
        }

        private function ellipseEnterFrameHandler(e:Event) {
            if(e.target.y > 0) {
                e.target.y -= 1;
                e.target.x -= 1;
            }
        }
        
        private function triangleEnterFrameHandler(e:Event) {
            e.target.transform.matrix3D.pointAt(ellipse.transform.matrix3D.position,
                                                Vector3D.X_AXIS, Vector3D.Y_AXIS);
        }
    }
}

Precede uma matriz multiplicando o objeto Matrix3D atual por outro objeto Matrix3D. O resultado combina as duas transformações de matriz.

A multiplicação de matriz é diferente da adição de matriz. A multiplicação de matriz não é comutativa. Em outras palavras, A vezes B não é igual a B vezes A. Com o método prepend(), a multiplicação ocorre do lado direito, significando que o objeto Matrix3D rhs está no lado direito do operador de multiplicação.

As modificações feitas pelo método prepend() são relativas ao espaço do objeto. Em outras palavras, elas são sempre relativas ao quadro inicial de referência do objeto.

O método prepend() substitui a matriz atual pela matriz precedente. Para adicionar duas matrizes precedentes sem alterar a matriz atual, copie a matriz atual usando o método clone() e aplique o método prepend() à copia.

Parâmetros

Elementos da API relacionados

Acrescenta uma rotação incremental a um objeto Matrix3D. Quando o objeto Matrix3D é aplicado a um objeto de exibição, a matriz executa a rotação antes de outras transformações no objeto Matrix3D.

A rotação do objeto de exibição é definida por um eixo, um grau incremental de rotação ao redor do eixo e um ponto de pivô opcional do centro da rotação do objeto. O eixo pode ser qualquer direção em geral. Os eixos comuns são X_AXS (Vector3D (1.0.0)), Y_AXIS (Vector3D (0.1.0)) e Z_AXIS (Vector3D (0.0.1)). Na terminologia da aviação, a rotação sobre o eixo y é chamada de guinada. A rotação sobre o eixo x é chamada de arfada. A rotação sobre o eixo z é chamada de rolamento.

A ordem de transformação é importante. Uma rotação seguida de uma transformação de translação produz um efeito diferente de uma translação seguida de uma rotação.

O efeito da rotação não é absoluto. O efeito é relativo ao objeto, relativo ao quadro de referência da posição e orientação originais. Para fazer uma alteração absoluta na transformação, use o método recompose().

Quando a transformação do método prependRotation() é aplicada a um objeto Matrix3D de um objeto de exibição, os valores da propriedade de rotação armazenados em cache do objeto de exibição são invalidados.

Uma forma de fazer com que um objeto de exibição gire ao redor de um ponto específico relativo à sua localização é definir a translação do objeto como o ponto especificado, girar o objeto usando o método prependRotation() e transladar o objeto de volta à posição original. No exemplo a seguir, o objeto de exibição 3D myObject faz uma rotação do eixo y ao redor da coordenada (10,10,0).

    
    myObject.z = 1; 
    myObject.transform.matrix3D.prependTranslation(10,10,0);
    myObject.transform.matrix3D.prependRotation(1, Vector3D.Y_AXIS);
    myObject.transform.matrix3D.prependTranslation(-10,-10,0);
     
    

Parâmetros

Elementos da API relacionados

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.geom.*;
    import flash.events.MouseEvent;
    
    public class Matrix3DprependRotationExample extends MovieClip {
        private var ellipse:Shape = new Shape();

        public function Matrix3DprependRotationExample():void {

            ellipse.graphics.beginFill(0xFF0000);
            ellipse.graphics.lineStyle(2);
            ellipse.graphics.drawEllipse(-50, -40, 100, 80);
            ellipse.graphics.endFill();

            ellipse.x = (this.stage.stageWidth / 2);
            ellipse.y = (this.stage.stageHeight / 2);
            ellipse.z = 1;
            
            addChild(ellipse);

            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseMoveHandler(e:MouseEvent):void {
            var y:int;
            var x:int;
            
            if(e.localX > ellipse.x) {
                y = (Math.round(e.localX) / 100);   
            } else {
                y = -(Math.round(e.localX) / 10);   
            }
            
            if(e.localY > ellipse.y) {
                x = (Math.round(e.localY) / 100);
            } else {
                x = -(Math.round(e.localY) / 100);
            }
            
            ellipse.transform.matrix3D.prependRotation(y, Vector3D.Y_AXIS);
            ellipse.transform.matrix3D.prependRotation(x, Vector3D.X_AXIS);
        }
        
    }
}

Acrescenta uma alteração de dimensionamento incremental nos eixos x, y e z a um objeto Matrix3D. Quando o objeto Matrix3D é aplicado a um objeto de exibição, a matriz executa as alterações de dimensionamento antes de outras transformações no objeto Matrix3D. As alterações são relativas ao objeto, relativas ao quadro de referência da posição e orientação originais. O fator de dimensionamento padrão é (1.0, 1.0, 1.0).

O dimensionamento é definido como um conjunto de três alterações incrementais ao longo dos três eixos (x,y,z). Você pode multiplicar cada eixo por um número diferente. Quando as alterações de dimensionamento são aplicadas a um objeto de exibição, o tamanho do objeto aumenta ou diminui. Por exemplo, se os eixos x, y e z forem definidos como dois, o tamanho do objeto será duplicado e, se eles forem definidos como 0,5, o tamanho será dividido por dois. Para que a transformação de dimensionamento afete somente um eixo específico, defina os outros parâmetros como um. Um parâmetro de valor um significa que não há alterações de dimensionamento no eixo específico.

O método prependScale() pode ser usado para redimensionar e também para gerenciar distorções, por exemplo, expansão ou contração de um objeto de exibição. Ele pode ser usado também para aplicar mais zoom ou menos zoom a um local. As transformações de dimensionamento são realizadas automaticamente durante a rotação e a translação do objeto de exibição.

A ordem de transformação é importante. Um redimensionamento seguido de uma transformação de translação produz um efeito diferente de uma translação seguida de uma transformação de redimensionamento.

Parâmetros

Elementos da API relacionados

Acrescenta uma translação incremental, um reposicionamento ao longo dos eixos x, y e z, a um objeto Matrix3D. Quando o objeto Matrix3D é aplicado a um objeto de exibição, a matriz executa as alterações de translação antes de outras transformações no objeto Matrix3D.

A translação especifica a distância que o objeto de exibição percorre, a partir de sua localização atual, nos eixos x, y e z. O método prependTranslation() define a translação como um conjunto de três alterações incrementais ao longo dos três eixos (x,y,z). Para que haja alteração de translação somente em um eixo específico, defina os outros parâmetros como zero. Um parâmetro zero significa que não há alterações no eixo específico.

As alterações de translação não são absolutas. O efeito é relativo ao objeto, relativo ao quadro de referência da posição e orientação originais. Para fazer uma alteração absoluta na matriz de transformação, use o método recompose(). A ordem de transformação também é importante. Uma translação seguida de uma transformação de rotação produz um efeito diferente de uma rotação seguida de uma transformação de translação. Quando o método prependTranslation() é usado, o objeto de exibição continua se movimentando na direção para a qual está voltada, independentemente das outras transformações. Por exemplo, se um objeto de exibição estiver voltado para um eixo x positivo, ele continuará se movimentando na direção especificada pelo método prependTranslation(), independentemente de como o objeto seja girado. Para que as alterações de translação ocorram depois de outras transformações, use o método appendTranslation().

Parâmetros

Elementos da API relacionados

package {
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.geom.*;
    import flash.events.MouseEvent;

    public class Matrix3DprependTranslationExample extends MovieClip {
        private var ellipse:Sprite = new Sprite();

        public function Matrix3DprependTranslationExample():void {
            ellipse.x = this.stage.stageWidth / 2;
            ellipse.y = this.stage.stageHeight - 100;
            ellipse.z = 1;
            ellipse.graphics.beginFill(0xFF0000);
            ellipse.graphics.lineStyle(2);
            ellipse.graphics.drawEllipse(0, 0, 60, 50);
            ellipse.graphics.endFill();
            addChild(ellipse);

            ellipse.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            ellipse.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        }

        private function mouseOverHandler(e:MouseEvent):void {
            if(ellipse.y > 0) { 
                ellipse.transform.matrix3D.prependTranslation(0, -10, 0);
            } 
        }
        
        private function mouseOutHandler(e:MouseEvent):void {
            if(ellipse.y > 0) { 
                ellipse.transform.matrix3D.prependTranslation(0, -10, 0);
            } else {
                ellipse.transform.matrix3D.prependTranslation(0, 
                                     (this.stage.stageHeight - 100), 0);
            }   
        }
    }
}

Define as configurações de translação, rotação e dimensionamento da matriz de transformação. Ao contrário das alterações incrementais feitas pelas propriedades de rotação do objeto de exibição ou pelos métodos de rotação do objeto Matrix3D, as alterações feitas pelo método recompose() são alterações absolutas. O método recompose() substitui a transformação da matriz.

Para modificar a transformação da matriz com um quadro de referência pai absoluto, recupere as configurações com o método decompose() e faça as alterações apropriadas. Assim, você pode definir o objeto Matrix3D como a transformação modificada usando o método recompose().

O parâmetro do método recompose() especifica o estilo de orientação usado na transformação. A orientação padrão é eulerAngles, que define a orientação com três ângulos separados de rotação para cada eixo. As rotações ocorrem consecutivamente e não alteram o eixo um do outro. As propriedades do eixo do objeto de exibição executam a transformação do estilo de orientação Ângulos de Euler. As outras opções de estilo de orientação são axisAngle e quaternion. A orientação de tipo Ângulo do eixo usa uma combinação de um eixo e um ângulo para determinar a orientação. O eixo ao redor do qual o objeto gira é um vetor unitário que representa uma direção. O ângulo representa a magnitude da rotação sobre o vetor. A direção também determina o lado para o qual um objeto de exibição está voltado e o ângulo determina o trajeto de movimentação. Os métodos appendRotation() e prependRotation() utilizam a orientação Ângulo do eixo. A orientação de quatérnion utiliza números complexos e o quarto elemento de um vetor. Uma orientação é representada pelos três eixos de rotação (x,y,z) e um ângulo de rotação (w). O método interpolate() utiliza o quatérnion.

Parâmetros

Elementos da API relacionados

Usa a matriz de transformação para transformar um objeto Vector3D de uma coordenada de espaço para outra. O objeto Vector3D retornado contém as novas coordenadas após a transformação. Todas as transformações de matriz, incluindo a translação, são aplicadas ao objeto Vector3D.

Se o resultado do método transformVector() tiver sido aplicado à posição de um objeto de exibição, somente a posição desse objeto será alterada. Os elementos de rotação e de dimensionamento do objeto de exibição permanecerão inalterados.

Observação: este método define automaticamente o componente w do Vector3D transmitido como 1.0.

Parâmetros

Elementos da API relacionados

Usa a matriz de transformação para transformar um Vector de números de um espaço de coordenadas para outro. O método tranformVectors() interpreta cada grupo de três números do objeto Vector vEntrada como uma coordenada tridimensional (x,y,z) e coloca uma coordenada tridimensional transformada no objeto Vector vSaída. Todas as transformações de matriz, incluindo a translação, são aplicadas ao objeto Vector vEntrada. Você pode usar o método transformVectors() para renderizar e transformar um objeto 3D como uma malha. Uma malha é um conjunto de vértices que define a forma do objeto.

Parâmetros

Elementos da API relacionados

Converte o objeto Matrix3D atual em uma matriz em que as linhas e colunas são trocadas. Por exemplo, se a propriedade rawData do objeto Matrix3D atual contiver os seguintes 16 números, 1,2,3,4,11,12,13,14,21,22,23,24,31,32,33,34, o método transpose() interpretará cada grupo de quatro números como uma linha e transformará as linhas em colunas. O resultado será uma matriz com a propriedade rawData de: 1,11,21,31,2,12,22,32,3,13,23,33,4,14,24,34.

O método transpose() substitui a matriz atual por uma matriz transposta. Para transpor uma matriz sem alterar a matriz atual, primeiramente copie a matriz atual usando o método clone() e depois aplique o método transpose() à copia.

Uma matriz ortogonal é uma matriz quadrada cuja transposição é igual ao seu inverso.