GradientGlowFilter  - AS3

Tablica wartości przezroczystości alpha, które odpowiadają kolorom z tablicy colors. Poprawne wartości dla każdego elementu tablicy należą do zakresu od 0 do 1. Przykład: wartość 0,25 powoduje ustawienie wartości przezroczystości alpha równej 25%.

Właściwość alphas nie może być zmieniana poprzez bezpośrednie modyfikowanie jej wartości. Zamiast tego należy uzyskać odwołanie do właściwości alphas, zmienić odwołanie, a następnie ustawić właściwość alphas na wartość odwołania.

Właściwości colors, alphas i ratios są ze sobą powiązane. Pierwszy element tablicy colors odpowiada pierwszemu elementowi w tablicy alphas oraz w tablicy ratios, itd.

Powiązane elementy interfejsu API

Kąt w stopniach. Poprawne wartości należą do zakresu od 0 do 360. Wartością domyślną jest 45.

Wartość kąta reprezentuje kąt padania światła z teoretycznego źródła światła oświetlającego obiekt oraz określa położenie efektu względem obiektu. Jeśli dla właściwości distance zostanie ustawiona wartość 0, efekt nie zostanie przesunięty z obiektu i dlatego właściwość angle nie będzie miała żadnego efektu.

Intensywność rozmycia w poziomie. Poprawne wartości należą do zakresu od 0 do 255. Rozmycie równe 1 oznacza, że obraz oryginalny jest kopiowany w stanie oryginalnym. Wartością domyślną jest 4. Wartości, które są potęgami 2 (dwójki 2, 4, 8, 16 i 32) są zoptymalizowane i są renderowane szybciej niż inne wartości.

Intensywność rozmycia w pionie. Poprawne wartości należą do zakresu od 0 do 255. Rozmycie równe 1 oznacza, że obraz oryginalny jest kopiowany w stanie oryginalnym. Wartością domyślną jest 4. Wartości, które są potęgami 2 (dwójki 2, 4, 8, 16 i 32) są zoptymalizowane i są renderowane szybciej niż inne wartości.

Tablica kolorów definiująca gradient. Na przykład: czerwony ma wartość 0xFF0000, niebieski 0x0000FF itd.

Właściwość colors nie może być zmieniana poprzez bezpośrednie modyfikowanie jej wartości. Zamiast tego należy uzyskać odwołanie do właściwości colors, zmienić odwołanie, a następnie ustawić właściwość colors na wartość odwołania.

Właściwości colors, alphas i ratios są ze sobą powiązane. Pierwszy element tablicy colors odpowiada pierwszemu elementowi w tablicy alphas oraz w tablicy ratios, itd.

Powiązane elementy interfejsu API

Przesunięcie blasku. Wartością domyślną jest 4.

Określa, czy z tym obiektem skojarzono ramkę odcięcia. Efekt odcięcia sprawia, że wypełnienie obiektu jest przezroczyste i ujawnia kolor tła dokumentu. Wartość true określa efekt odcięcia; wartością domyślną jest false (brak efektu odcięcia).

Liczba operacji zastosowania filtra. Wartością domyślną jest BitmapFilterQuality.LOW, która jest równoważna jednorazowemu zastosowaniu filtra. Wartość BitmapFilterQuality.MEDIUM powoduje dwukrotne zastosowanie filtra; wartość BitmapFilterQuality.HIGH powoduje trzykrotne zastosowanie filtra. Filtry o niższych wartościach są renderowane szybciej.

W większości zastosowań wystarczające są następujące wartości quality: low, medium i high. Mimo że w celu osiągnięcia różnych efektów można stosować dodatkowe wartości liczbowe (aż do 15), wyższe wartości są renderowane wolniej. Zamiast zwiększać wartość quality — w celu uzyskania podobnego efektu przy krótszym czasie renderowania — można po prostu zwiększać wartości właściwości blurX i blurY.

Powiązane elementy interfejsu API

Tablica współczynników rozkładu kolorów, które odpowiadają kolorom z tablicy colors. Poprawne wartości należą do zakresu od 0 do 255.

Właściwość ratios nie może być zmieniana poprzez bezpośrednie modyfikowanie jej wartości. Zamiast tego należy uzyskać odwołanie do właściwości ratios, zmienić odwołanie, a następnie ustawić właściwość ratios na wartość odwołania.

Właściwości colors, alphas i ratios są ze sobą powiązane. Pierwszy element tablicy colors odpowiada pierwszemu elementowi w tablicy alphas oraz w tablicy ratios, itd.

Filtr poświaty gradientowej należy traktować jako poświatę, która wydobywa się z wnętrza obiektu (jeśli dla wartości distance ustawiono 0), z gradientami w postaci pasków, które się przenikają. Pierwszy kolor w tablicy colors jest najbardziej zewnętrznym kolorem poświaty. Kolor ostatni jest najbardziej wewnętrznym kolorem poświaty.

Każda wartość w tablicy ratios ustawia położenie koloru na promieniu gradientu. Wartość 0 odpowiada najbardziej zewnętrznemu punktowi gradientu, a wartość 255 odpowiada najbardziej wewnętrznemu punktowi gradientu. Wartości współczynników mogą należeć do zakresu od 0 do 255 pikseli — są to wartości wzrastające; na przykład: [0, 64, 128, 200, 255]. Wartości od 0 do 128 pojawiają się na zewnętrznych krawędziach poświaty. Wartości od 129 do 255 pojawiają się w wewnętrznym obszarze poświaty. Kolory filtru — w zależności od wartości współczynników kolorów i wartości type filtru — mogą być zasłonięte przez obiekt, do którego filtr został zastosowany.

W poniższym kodzie i obrazie filtr został zastosowany do klipu filmowego przedstawiającego czarne koło, a dla filtru ustawiono typ „full”. W celu przedstawienia pełnego efektu ustawiono dla pierwszego koloru w tablicy colors (różowego) wartość alpha równą 1, dzięki czemu jest on widoczny na białym tle dokumentu. (W praktyce możliwe jest, że użytkownik nie chciałby, aby pierwszy kolor wyglądał w ten sposób). Ostatni kolor w tablicy, żółty, zasłania czarne koło, do którego filtr został zastosowany:

	var colors:Array = [0xFFCCFF, 0x0000FF, 0x9900FF, 0xFF0000, 0xFFFF00];
	var alphas:Array = [1, 1, 1, 1, 1];
	var ratios:Array = [0, 32, 64, 128, 225];
	var myGGF:GradientGlowFilter = new GradientGlowFilter(0, 0, colors, alphas, ratios, 50, 50, 1, 2, "full", false);
	

Aby uzyskać efekt gładkiego przejścia po ustawieniu typu type na wartość„outer” lub „full”, należy ustawić pierwszy kolor w tablicy na taki sam kolor, co kolor tła dokumentu, lub należy ustawić wartość alpha pierwszego koloru na 0 — każda z tych technik sprawi, że efekt filtru na krawędzi zostanie wymieszany z kolorem tła.

Po wprowadzeniu dwóch niewielkich zmian w kodzie efekt poświaty może być bardzo różny, nawet w przypadku takich samych tablic ratios i colors. Ustawienie 0 dla wartości alpha pierwszego koloru w tablicy sprawi, że efekt filtru zostanie zmieszany z białym tłem dokumentu; dla właściwości type należy również ustawić wartość „outer” lub „inner”. Wyniki przedstawiają poniższe obrazy.

Należy pamiętać, że zakres kolorów w gradiencie jest uzależniony od wartości właściwości blurX, blurY, strength i quality, a także wartości ratios.

Powiązane elementy interfejsu API

Siła odciskania lub zalewkowania. Im wyższa jest wartość, tym więcej koloru zostaje odciśnięte, co powoduje również wzmocnienie kontrastu między poświatą i tłem. Poprawne wartości należą do zakresu od 0 do 255. Wartość 0 oznacza, że filtr nie jest stosowany. Wartością domyślną jest 1.

Umiejscowienie efektu filtra. Możliwe wartości to stałe flash.filters.BitmapFilterType:

• BitmapFilterType.OUTER — poświata na zewnętrznej krawędzi obiektu
• BitmapFilterType.INNER — faza na zewnętrznej krawędzi obiektu, domyślna.
• BitmapFilterType.FULL — poświata na górnej stronie obiektu

Inicjuje filtr z zadanymi parametrami.

Zwraca kopię tego obiektu typu Filter.

1. Zaimportuj wymagane klasy.
2. Zadeklaruj zmienne globalne w celu zdefiniowania kwadratu i filtru.
3. Utwórz funkcję konstruktora, którego działanie jest następujące:
   • Wywołuje metodę draw(), która korzysta z klasy Graphics, do której uzyskuje dostęp za pośrednictwem właświwości graphics Sprite, w celu narysowania kwadratu.
   • Tworzy obiekt BitmapFilter o nazwie filter i przypisuje do niego wartość zwracaną przez wywołanie metody getBitmapFilter(), która tworzy filtr.
   • Tworzy nową tablicę o nazwie myFilters i dodaje do niej obiekt filter.
   • Przypisuje tablicę myFilters do właściwości filters obiektu GradientGlowFilterExample. To spowoduje zastosowanie wszystkich filtrów zalezionych w obiekcie myFilters — w tym przykładzie jest to filtr filter.

package {
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;
    import flash.filters.GradientGlowFilter;
    import flash.display.Sprite;

    public class GradientGlowFilterExample extends Sprite {
        private var bgColor:uint = 0xCCCCCC;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        private var distance:Number  = 0;
        private var angleInDegrees:Number = 45;
        private var colors:Array     = [0xFFFFFF, 0xFF0000, 0xFFFF00, 0x00CCFF];
        private var alphas:Array     = [0, 1, 1, 1];
        private var ratios:Array     = [0, 63, 126, 255];
        private var blurX:Number     = 50;
        private var blurY:Number     = 50;
        private var strength:Number  = 2.5;
        private var quality:Number   = BitmapFilterQuality.HIGH;
        private var type:String      = BitmapFilterType.OUTER;
        private var knockout:Boolean = false;

        public function GradientGlowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            return new GradientGlowFilter(distance,
                                          angleInDegrees,
                                          colors,
                                          alphas,
                                          ratios,
                                          blurX,
                                          blurY,
                                          strength,
                                          quality,
                                          type,
                                          knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}