ContextMenu  - AS3

ContextMenuBuiltInItems 클래스의 forwardAndBack, loop, play, print, quality, rewind, save 및 zoom 속성을 갖는 인스턴스입니다. 이러한 속성을 false로 설정하면 지정된 ContextMenu 객체에서 해당 메뉴 항목이 제거됩니다. 이들 속성은 열거 가능하며 기본적으로 true로 설정되어 있습니다.

참고: AIR에서는 컨텍스트 메뉴에 내장 항목이 없습니다.

관련 API 요소

ContextMenuClipboardItems 클래스의 속성이 cut, copy, paste, delete, selectAll인 인스턴스입니다. 이러한 속성 중 하나를 false로 설정하면 클립보드 메뉴에서 해당 항목이 비활성화됩니다.

관련 API 요소

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

클립보드 메뉴를 사용할지 여부를 지정합니다. 이 값이 true이면 clipboardItems 속성에 따라 클립보드 메뉴에서 활성화하거나 비활성화할 항목이 결정됩니다.

link 속성이 null이 아니면 이 clipBoardMenu 속성은 무시됩니다.

ContextMenuItem 객체의 배열입니다. 배열 내의 각 객체는 사용자가 정의한 컨텍스트 메뉴 항목을 나타냅니다. 이 속성을 사용하여 사용자 정의 메뉴 항목을 추가, 삭제 또는 수정할 수 있습니다.

새 메뉴 항목을 추가하려면 ContextMenuItem 객체를 만든 다음 Array.push()와 같은 메서드를 사용하여 customItems 배열에 추가합니다. 메뉴 항목 작성에 대한 자세한 내용은 ContextMenuItem 클래스 항목을 참조하십시오.

관련 API 요소

현재 플랫폼에서 ContextMenu 클래스가 지원되면 isSupported 속성이 true로 설정되고, 그렇지 않으면 false로 설정됩니다.

이 메뉴에 있는 사용자 정의 항목의 배열입니다.

이 속성을 사용하는 것은 customItems 속성을 사용하는 것과 같습니다. 배열은 표시 순서대로 정렬됩니다.

링크의 URLRequest입니다. 이 속성이 null이면 일반적인 컨텍스트 메뉴가 표시됩니다. 이 속성이 null이 아니면 링크 컨텍스트 메뉴가 표시되고 지정한 url에서 작동합니다.

link를 지정하면 clipboardMenu 속성이 무시됩니다.

기본값은 null입니다.

이 메뉴에 있는 항목의 수입니다.

ContextMenu 객체를 만듭니다.

관련 API 요소

메뉴의 맨 아래에 메뉴 항목을 추가합니다.

컨텍스트 메뉴를 만들 때 NativeMenuItem 또는 ContextMenuItem 객체를 추가할 수 있습니다. 그러나 메뉴의 모든 항목이 같은 속성을 가지도록 컨텍스트 메뉴에서 하나의 객체 유형만 사용하는 것이 좋습니다.

매개 변수

지정된 ContextMenu 객체의 복사본을 만듭니다. 이 복사본은 원본 메뉴 객체의 모든 속성을 상속합니다.

이 메뉴에 지정된 메뉴 항목이 포함되어 있는지 여부를 보고합니다.

매개 변수

지정된 위치에서 이 메뉴를 표시합니다.

참고: Flash Player에서는 이 메서드가 지원되지 않습니다.

매개 변수

지정된 인덱스의 메뉴 항목을 가져옵니다.

매개 변수

지정된 항목의 위치를 가져옵니다.

매개 변수

지정된 ContextMenu 객체에서 [설정]을 제외한 모든 내장 메뉴 항목을 숨깁니다. 디버거 버전의 Flash Player를 실행하는 경우에는 [디버깅] 메뉴 항목이 표시됩니다. SWF 파일에서 원격 디버깅을 사용하지 않는 경우에는 이 항목이 흐리게 표시됩니다.

이 메서드는 표준 컨텍스트 메뉴에 표시되는 메뉴 항목만 숨기며 편집 메뉴와 오류 메뉴에 표시되는 항목에는 영향을 주지 않습니다.

이 메서드는 my_cm .builtInItems의 모든 부울 멤버를 false로 설정합니다. my_cm .builtInItems에서 원하는 내장 항목에 해당하는 멤버를 true로 설정하여 항목을 선택적으로 표시할 수도 있습니다.

참고: AIR에서는 컨텍스트 메뉴에 내장 항목이 없습니다. 이 메서드를 호출해도 마찬가지입니다.

관련 API 요소

메뉴에서 모든 항목을 제거합니다.

지정된 인덱스의 메뉴 항목을 제거 및 반환합니다.

매개 변수

사용자가 컨텍스트 메뉴를 처음 생성할 때, 그러나 컨텍스트 메뉴의 내용이 표시되기 전에 전달됩니다. 프로그램에서는 이를 통해 메뉴를 표시하기 전에 컨텍스트 메뉴 항목 집합을 수정할 수 있습니다. 사용자가 포인팅 장치의 오른쪽 버튼을 클릭하면 컨텍스트 메뉴가 생성됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

1. myContextMenu 속성이 선언되어 새 ContextMenu 객체에 할당되고 redRectangle 속성(Sprite 유형)이 선언됩니다.
2. removeDefaultItems() 메서드를 호출하여 인쇄를 제외한 모든 내장 컨텍스트 메뉴 항목을 제거합니다.
3. addCustomMenuItems() 메서드를 호출하여 Red to Black라는 메뉴 항목을 defaultItems 배열에 추가합니다. 이때 배열의 push() 메서드를 사용합니다. menuItemSelect 이벤트 리스너가 ContextMenuItem 객체에 추가되고, 연관된 메서드 menuItemSelectHandler()가 호출됩니다. 이 메서드는 trace()를 사용하여 몇 가지 명령문을 출력합니다. 이 작업은 컨텍스트 메뉴를 열고 Red to Black을 선택할 때마다 수행됩니다. 또한 빨강 사각형이 제거되고 검정 사각형으로 바뀝니다.
4. menuSelect 유형의 이벤트 리스너가 관련 메서드인 menuSelectHandler와 함께 추가됩니다. 여기에서는 사용자가 컨텍스트 메뉴의 항목을 열 때마다 trace()를 사용하여 세 가지 명령문을 출력합니다.
5. addChildren()은 빨강 사각형을 그리고 이를 표시 목록에 추가하여 즉시 표시되게 합니다.
6. 마지막으로 myContextMenu가 redRectangle Sprite의 컨텍스트 메뉴에 할당되어 마우스 포인터가 사각형 위에 있을 때만 사용자 정의 컨텍스트 메뉴가 표시되도록 합니다.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}