ContextMenuItem  - AS3

패키지	flash.ui
클래스	public final class ContextMenuItem
상속	ContextMenuItem NativeMenuItem EventDispatcher Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9

ContextMenuItem 클래스는 컨텍스트 메뉴의 항목을 나타냅니다. 각 ContextMenuItem 객체에는 컨텍스트 메뉴에 표시되는 텍스트 캡션이 있습니다. 컨텍스트 메뉴에 새 항목을 추가하려면 이를 ContextMenu 객체의 customItems 배열에 추가합니다.

ContextMenuItem 클래스의 속성을 사용하면 특정 메뉴 항목을 활성화하거나 비활성화할 수 있고 항목을 표시하거나 숨길 수 있습니다.

menuItemSelect 이벤트에 대한 이벤트 핸들러를 작성하여 사용자가 메뉴 항목을 선택할 때 실행할 기능을 추가합니다.

사용자 정의 메뉴 항목은 컨텍스트 메뉴의 맨 위에, 내장 항목 위에 표시됩니다. 사용자 정의 메뉴 항목과 내장 항목 사이에는 구분 표시줄이 표시됩니다. AIR에는 내장 항목이 없으며 AIR 응용 프로그램 샌드박스의 내용에 다음과 같은 제한이 적용되지 않습니다.

여기에는 다음과 같은 제한이 있습니다.

• 컨텍스트 메뉴에 사용자 정의 항목을 15개까지 추가할 수 있습니다.
• 각 캡션에는 표시 가능한 문자가 하나 이상 있어야 합니다.
• 제어 문자, 개행 문자 및 기타 공백 문자는 무시됩니다.
• 캡션에는 최대 100자까지만 입력할 수 있습니다.
• 내장 메뉴 항목 또는 다른 사용자 정의 항목과 동일한 캡션은 일치하는 항목의 표시 여부와 관계없이 무시됩니다. 메뉴 캡션은 대/소문자, 문장 부호 또는 공백을 고려하지 않고 내장 캡션 또는 기존의 사용자 정의 캡션과 비교됩니다.
• 다음 캡션은 개별적으로 사용할 수 없지만 다른 단어와 결합하여 사용자 정의 캡션을 구성할 수는 있습니다. 예를 들어 "Paste"는 사용할 수 없지만 "Paste tastes great"는 사용할 수 있습니다.

   Save
   Zoom In
   Zoom Out
   100%
   Show All
   Quality
   Play
   Loop
   Rewind
   Forward
   Back
   Movie not loaded
   About
   Print
   Show Redraw Regions
   Debugger
   Undo
   Cut
   Copy
   Paste
   Delete
   Select All
   Open
   Open in new window
   Copy link
   

• 다음 단어는 사용자 정의 캡션에 단독으로 사용할 수 없을 뿐만 아니라 다른 단어와 결합하여 사용할 수도 없습니다.

   Adobe
   Macromedia
   Flash Player
   Settings
   

참고: 영어를 사용하지 않는 시스템에서 Flash Player를 실행하는 경우 캡션 문자열은 영어 목록 및 지역화된 해당 문자열 모두와 비교됩니다.

예제 보기

관련 API 요소

---

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}