GradientGlowFilter  - AS3

Tableau de valeurs de transparence alpha pour les couleurs correspondantes du tableau colors. Les valeurs valides pour chaque élément du tableau sont comprises entre 0 et 1. Par exemple, 0,25 définit une valeur de transparence de 25 %.

La propriété alphas ne peut pas être modifiée en manipulant directement ses valeurs. Vous devez obtenir une référence à alphas, effectuer les modifications sur la référence, puis définir la propriété alphas sur la référence.

Les propriétés colors, alphas et ratios sont liées. Le premier élément du tableau colors correspond au premier élément du tableau alphas, du tableau ratios, etc.

Eléments de l’API associés

Angle, exprimé en degrés. Les valeurs possibles sont comprises entre 0 et 360. La valeur par défaut est 45.

La valeur d’angle représente l’angle de la source lumineuse théorique éclairant l’objet et détermine l’emplacement de l’effet par rapport à ce dernier. Si la valeur de distance est 0, il n’y a pas d’effet de décalage par rapport à l’objet. La propriété angle n’a donc aucun effet.

Quantité de flou horizontal. Les valeurs possibles sont comprises entre 0 et 255. Un flou d’une valeur inférieure ou égale à 1 signifie que l’image d’origine n’est pas modifiée avant d’être copiée. La valeur par défaut est 4. Les valeurs correspondant à une puissance de 2 (telles que 2, 4, 8, 16 et 32) sont optimisées pour obtenir un rendu plus rapide qu’avec les autres valeurs.

Quantité de flou vertical. Les valeurs possibles sont comprises entre 0 et 255. Un flou d’une valeur inférieure ou égale à 1 signifie que l’image d’origine n’est pas modifiée avant d’être copiée. La valeur par défaut est 4. Les valeurs correspondant à une puissance de 2 (telles que 2, 4, 8, 16 et 32) sont optimisées pour obtenir un rendu plus rapide qu’avec les autres valeurs.

Tableau de couleurs définissant un dégradé. Par exemple, rouge correspond à 0xFF0000, bleu à 0x0000FF, etc.

La propriété colors ne peut pas être modifiée en manipulant directement ses valeurs. Vous devez obtenir une référence à colors, effectuer les modifications sur la référence, puis définir la propriété colors sur la référence.

Les propriétés colors, alphas et ratios sont liées. Le premier élément du tableau colors correspond au premier élément du tableau alphas, du tableau ratios, etc.

Eléments de l’API associés

Distance de décalage du rayonnement. La valeur par défaut est 4.

Spécifie si l’objet a un effet de masquage. Un effet de masquage rend le remplissage de l’objet transparent et révèle la couleur d’arrière-plan du document. La valeur true spécifie un effet de masquage ; la valeur par défaut est false (pas d’effet de masquage).

Nombre d’applications du filtre. La valeur par défaut est BitmapFilterQuality.LOW, ce qui revient à appliquer le filtre une seule fois. La valeur BitmapFilterQuality.MEDIUM applique le filtre deux fois. La valeur BitmapFilterQuality.HIGH l’applique trois fois. Les rendus des filtres de valeurs faibles sont obtenus plus rapidement.

Pour la plupart des applications, une valeur de quality faible, moyenne ou élevée est suffisante. Il est possible d’utiliser des valeurs numériques allant jusqu’à 15 pour obtenir différents effets, mais le rendu des valeurs les plus élevées est moins rapide. Sans augmenter la valeur de quality, vous pouvez généralement obtenir un effet similaire, avec un rendu plus rapide, en augmentant simplement les valeurs des propriétés blurX et blurY.

Eléments de l’API associés

Tableau de taux de répartition des couleurs, pour les couleurs correspondantes du tableau colors. Les valeurs possibles sont comprises entre 0 et 255.

La propriété ratios ne peut pas être modifiée en manipulant directement ses valeurs. Vous devez obtenir une référence à ratios, effectuer les modifications sur la référence, puis définir la propriété ratios sur la référence.

Les propriétés colors, alphas et ratios sont liées. Le premier élément du tableau colors correspond au premier élément du tableau alphas, du tableau ratios, etc.

Considérez le filtre de rayonnement dégradé comme un rayonnement émanant du centre de l’objet (si la valeur distance est définie sur 0), avec des bandes de couleurs se mêlant les unes aux autres pour constituer le dégradé. La première couleur du tableau colors est la couleur la plus proche de l’extérieur du rayonnement. La dernière couleur est la plus au centre du rayonnement.

Chaque valeur du tableau ratios définit l’emplacement de la couleur sur le rayon du dégradé, 0 représentant le point le plus éloigné et 255, le point le plus proche du centre du dégradé. Les valeurs de ratio s’échelonnent progressivement de 0 à 255 pixels : par exemple [0, 64, 128, 200, 255]. Les valeurs comprises entre 0 et 128 apparaissent sur les bords extérieurs du rayonnement. Les valeurs comprises entre 129 et 255 apparaissent à l’intérieur du rayonnement. Selon les valeurs de ratio des couleurs et la valeur type du filtre, les couleurs du filtre peuvent être obscurcies par l’objet auquel le filtre est appliqué.

Dans le code et l’image ci-dessous, un filtre est appliqué à un cercle noir animé, le type étant défini sur la valeur "full". Pour les besoins de la démonstration, la première couleur du tableau colors, rose, a une valeur alpha de 1 pour qu’elle se détache bien sur le fond blanc du document (dans la pratique, vous ne choisirez probablement pas la première couleur ainsi). La dernière couleur du tableau, jaune, cache le cercle noir auquel le filtre est appliqué :

	var colors:Array = [0xFFCCFF, 0x0000FF, 0x9900FF, 0xFF0000, 0xFFFF00];
	var alphas:Array = [1, 1, 1, 1, 1];
	var ratios:Array = [0, 32, 64, 128, 225];
	var myGGF:GradientGlowFilter = new GradientGlowFilter(0, 0, colors, alphas, ratios, 50, 50, 1, 2, "full", false);
	

Pour obtenir un effet de transparence homogène sur le fond de votre document lorsque vous définissez la valeur type sur "outer" ou "full", définissez la première couleur du tableau comme identique à celle de l’arrière-plan du document, ou définissez la valeur alpha de la première couleur sur 0. Ces deux techniques entraînent le mélange du filtre avec l’arrière-plan.

Deux petites modifications au code peuvent se traduire par un effet du rayonnement complètement différent et ce, même si les tableaux ratios et colors restent les mêmes. Définissez la valeur alpha de la première colonne du tableau sur 0 pour que le filtre se mélange à l’arrière-plan blanc du document ; puis définissez la propriété type sur "outer" ou "inner". Observez le résultat sur les illustrations suivantes.

N’oubliez pas que la répartition des couleurs dans le dégradé varie en fonction des valeurs des propriétés blurX, blurY, strength et quality, ainsi que des valeurs de ratios.

Eléments de l’API associés

Intensité de l’empreinte ou recouvrement. Plus la valeur est élevée, plus le recouvrement est intense et plus le contraste entre le rayonnement et l’arrière-plan est important. Les valeurs possibles sont comprises entre 0 et 255. La valeur 0 signifie que le filtre n’est pas appliqué. La valeur par défaut est 1.

Positionnement de l’effet de filtre. Les valeurs possibles sont les constantes flash.filters.BitmapFilterType :

• BitmapFilterType.OUTER, rayonnement sur le bord extérieur de l’objet ;
• BitmapFilterType.INNER, rayonnement sur le bord intérieur de l’objet, il s’agit de la valeur par défaut.
• BitmapFilterType.FULL, rayonnement au-dessus de l’objet.

Initialise le filtre avec les paramètres spécifiés.

Renvoie une copie de cet objet filtre.

1. Importation des classes requises.
2. Déclaration des variables globales utilisées pour définir le carré et le filtre.
3. Création de la fonction constructeur qui effectue les actions suivantes :
   • Appel de la méthode draw() qui utilise des méthodes de la classe Graphics, accessibles par le biais de la propriété graphics de Sprite, pour dessiner un carré.
   • Création d’un objet BitmapFilter nommé filter auquel est attribuée la valeur renvoyée d’un appel à getBitmapFilter() qui crée le filtre.
   • Création d’un nouveau tableau nommé myFilters auquel est ajouté filter.
   • Attribution de myFilters à la propriété filters de l’objet GradientGlowFilterExample. Ceci a pour effet d’appliquer tous les filtres trouvés dans myFilters, en l’occurrence filter uniquement.

package {
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;
    import flash.filters.GradientGlowFilter;
    import flash.display.Sprite;

    public class GradientGlowFilterExample extends Sprite {
        private var bgColor:uint = 0xCCCCCC;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        private var distance:Number  = 0;
        private var angleInDegrees:Number = 45;
        private var colors:Array     = [0xFFFFFF, 0xFF0000, 0xFFFF00, 0x00CCFF];
        private var alphas:Array     = [0, 1, 1, 1];
        private var ratios:Array     = [0, 63, 126, 255];
        private var blurX:Number     = 50;
        private var blurY:Number     = 50;
        private var strength:Number  = 2.5;
        private var quality:Number   = BitmapFilterQuality.HIGH;
        private var type:String      = BitmapFilterType.OUTER;
        private var knockout:Boolean = false;

        public function GradientGlowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            return new GradientGlowFilter(distance,
                                          angleInDegrees,
                                          colors,
                                          alphas,
                                          ratios,
                                          blurX,
                                          blurY,
                                          strength,
                                          quality,
                                          type,
                                          knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}