XML  - AS3

Détermine si les commentaires XML sont ignorés lorsque les objets XML analysent les données XML source. Par défaut, les commentaires sont ignorés (true). Pour inclure les commentaires XML, réglez cette propriété sur false. La propriété ignoreComments n’est utilisée que lors de l’analyse XML et non pendant l’appel d’une méthode, telle que myXMLObject.child(*).toXMLString(). Si les données XML source contiennent des nœuds de commentaire, ils sont conservés ou éliminés lors de l’analyse XML.

Eléments de l’API associés

XML.ignoreComments = false;
var xml1:XML = 
        <foo>
            <!-- comment -->
        </foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>

XML.ignoreComments = true;
var xml2:XML = 
        <foo>
            <!-- example -->
        </foo>;
trace(xml2.toXMLString()); // <foo/>

Détermine si les instructions de traitement XML sont ignorées lorsque les objets XML analysent les données XML source. Par défaut, les instructions de traitement sont ignorées (true). Pour les inclure, réglez la propriété sur false. La propriété ignoreProcessingInstructions n’est utilisée que lors de l’analyse XML et non pendant l’appel de toute méthode telle que myXMLObject.child(*).toXMLString(). Si les données XML source contiennent des nœuds d’instructions de traitement, ils sont conservés ou éliminés lors de l’analyse XML.

Eléments de l’API associés

XML.ignoreProcessingInstructions = false;
var xml1:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>

XML.ignoreProcessingInstructions = true;
var xml2:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml2.toXMLString()); // <foo/>

Détermine si les caractères d’espace blanc placés au début et à la fin des nœuds de texte sont ignorés lors de l’analyse. Les espaces blancs sont ignorés par défaut (true). Si un nœud de texte est entièrement composé d’espaces blancs et que la propriété ignoreWhitespace est définie sur true, il n’est pas créé. Pour afficher les espaces blancs dans un nœud de texte, réglez la propriété ignoreWhitespace sur false.

Lorsque vous créez un objet XML, il place en mémoire cache la valeur actuelle de la propriété ignoreWhitespace. La modification de la propriété ignoreWhitespace ne change pas le comportement des objets XML.

XML.ignoreWhitespace = false;
var xml1:XML = <foo>    </foo>;
trace(xml1.children().length()); // 1

XML.ignoreWhitespace = true;
var xml2:XML = <foo>    </foo>;
trace(xml2.children().length()); // 0

Détermine la taille du retrait appliqué par les méthodes toString() et toXMLString() si la propriété XML.prettyPrinting est définie sur true. Les retraits sont appliqués à l’aide de caractères d’espace et non de caractères de tabulation. La valeur par défaut est 2.

Eléments de l’API associés

var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());

XML.prettyIndent = 1;
trace(xml.toXMLString());

XML.prettyIndent = 2;
trace(xml.toXMLString());

Détermine si les méthodes toString() et toXMLString() normalisent les caractères d’espace blanc entre certaines balises. La valeur par défaut est true.

Eléments de l’API associés

var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());

XML.prettyPrinting = true;
trace(xml.toXMLString());

Crée un objet XML. Vous devez utiliser le constructeur pour créer un objet XML avant d’appeler une des méthodes de la classe XML.

La méthode toXMLString() permet de renvoyer une représentation sous forme de chaîne de l’objet XML, que son contenu soit simple ou complexe.

Informations complémentaires

Eléments de l’API associés

//
// Requires:
//   - TextArea control UI component in the Flash Professional Library.
//
import fl.controls.TextArea;
 
var xml:XML;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
 
var urlLoader:URLLoader = new URLLoader();
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
var textArea:TextArea = new TextArea();
textArea.move(5, 5);
textArea.setSize(stage.stageWidth - 10, stage.stageHeight - 10);
addChild(textArea);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.currentTarget.data);
    textArea.text = xml.toXMLString();
}

var xml:XML;
var textArea:TextField = new TextField();
textArea.width = 300;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.target.data);
    textArea.text = xml.toXMLString();
    addChild(textArea);
}

Ajoute un espace de noms à l’ensemble d’espaces de noms du domaine associé à l’objet XML. Si l’espace de noms figure déjà dans l’ensemble d’espaces de noms du domaine associé à l’objet XML (avec un préfixe qui correspond au paramètre spécifié), le préfixe correspondant est réglé sur undefined. Si le paramètre d’entrée est un objet Namespace, il est utilisé directement. S’il correspond à un objet QName, l’URI du paramètre d’entrée est utilisé pour créer un espace de noms. Dans le cas contraire, il est converti en chaîne et un espace de noms est généré à partir de la chaîne.

Paramètres

Informations complémentaires

var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();

var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>

Ajoute l’enfant indiqué à la fin des propriétés de l’objet XML. La méthode appendChild() accepte un objet XML, un objet XMLList ou tout autre type de données qui est ensuite converti en chaîne.

Utilisez l’opérateur delete (XML) pour supprimer les nœuds XML.

Paramètres

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.appendChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>

Renvoie la valeur XML de l’attribut dont le nom correspond au paramètre attributeName. Les attributs sont intégrés aux éléments XML. Dans l’exemple suivant, l’élément a un attribut appelé "gender" avec la valeur "boy" : <first gender="boy">John</first>.

Le paramètre attributeName peut correspondre à n’importe quel type de données, mais String est généralement utilisé. Si vous transmettez un objet autre que QName, le paramètre attributeName utilise la méthode toString() pour convertir le paramètre en chaîne.

Si une référence de nom complet s’impose, vous pouvez transmettre un objet QName. Un objet QName définit un espace de noms et le nom local, que vous pouvez utiliser pour définir le nom complet d’un attribut. De ce fait, appeler attribute(qname) n’est pas équivalent à appeler attribute(qname.toString()).

Paramètres

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

 var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />       
 var qn:QName = new QName("http://uri", "attr");
 trace (xml.attribute(qn)); // 7

 var xml:XML = <example class="first" />
 trace(xml.attribute("class"));
 

Renvoie une liste de valeurs d’attribut associée à l’objet XML indiqué. Utilisez la méthode name() en conjonction avec la méthode attributes() pour renvoyer le nom d’un attribut. L’utilisation de xml.attributes() est équivalente à xml.@*.

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color

 
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;

trace (attNamesList is XMLList); // true
trace (attNamesList.length()); // 2

for (var i:int = 0; i < attNamesList.length(); i++)
{ 
    trace (typeof (attNamesList[i])); // xml
    trace (attNamesList[i].nodeKind()); // attribute
    trace (attNamesList[i].name()); // id and color
} 

Recense les enfants d’un objet XML. Un enfant XML est un élément, un nœud de texte, un commentaire ou une instruction de traitement XML.

Le paramètre propertyName permet de recenser le contenu d’un enfant XML spécifique. Par exemple, pour renvoyer le contenu d’un enfant appelé <first>, appelez child("first") sur l’objet XML. Vous pouvez générer le même résultat à partir du numéro d’index de l’enfant. Le numéro d’index identifie la position de l’enfant dans la liste d’enfants XML. Par exemple, child(0) renvoie le premier enfant d’une liste.

Utilisez un astérisque (*) pour extraire tous les enfants dans un document XML. Exemple : doc.child("*").

La méthode length() associée au paramètre astérisque (*) de la méthode child() permet de produire le nombre total d’enfants. Exemple : numChildren = doc.child("*").length().

Paramètres

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <foo>
            <bar>text1</bar>
            <bar>text2</bar>
        </foo>;
trace(xml.child("bar").length());  // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>

Identifie la position d’index qui commence à zéro de cet objet XML dans le contexte de l’objet parent.

Informations complémentaires

var xml:XML = 
            <foo>
                <bar />
                text
                <bob />
            </foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2

Recense les enfants de l’objet XML dans l’ordre dans lequel ils apparaissent. Un enfant XML est un élément, un nœud de texte, un commentaire ou une instruction de traitement XML.

Informations complémentaires

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML = 
        <foo id="22">
            <bar>44</bar>
            text
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>

Recense les propriétés de l’objet XML qui contient des commentaires XML.

Informations complémentaires

XML.ignoreComments = false;
var xml:XML = 
        <foo>
            <!-- example -->
            <!-- example2 -->
        </foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->

Compare l’objet XML au paramètre value spécifié.

Paramètres

Informations complémentaires

var xml:XML = 
        <order>
            <item>Rice</item>
            <item>Kung Pao Shrimp</item>
        </order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false

Renvoie une copie de l’objet XML spécifié. Cette copie est une duplication de l’arborescence entière de nœuds. L’objet XML copié ne possède pas de parent et renvoie null si vous tentez d’appeler la méthode parent().

Informations complémentaires

var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1

Renvoie un objet avec les propriétés suivantes définies sur les valeurs par défaut : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting. Les valeurs par défaut sont les suivantes :

• ignoreComments = true
• ignoreProcessingInstructions = true
• ignoreWhitespace = true
• prettyIndent = 2
• prettyPrinting = true

Remarque : cette méthode ne doit pas être appliquée à une occurrence de la classe XML, mais à XML, comme illustré dans le code suivant : var df:Object = XML.defaultSettings().

Informations complémentaires

Eléments de l’API associés

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Renvoie tous les descendants (enfants, petits-enfants, arrière-petits-enfants, etc.) de l’objet XML associés au paramètre name indiqué. Le paramètre name est facultatif. Le paramètre name peut être un objet QName, un type de données String ou tout autre type de données converti ensuite au type de données String.

Pour renvoyer tous les descendants, utilisez le paramètre « * ». Si aucun paramètre n’est transmis, la chaîne « * » est transmise et renvoie tous les descendants de l’objet XML.

Paramètres

Eléments de l’API associés

var xml:XML = 
  <enrollees>
    <student id="239">
        <class name="Algebra" />
        <class name="Spanish 2"/>
    </student>
    <student id="206">
        <class name="Trigonometry" />
        <class name="Spanish 2" />
    </student>
  </enrollees>
trace(xml.descendants("class")); 

XML.ignoreComments = false;
var xml:XML = 
        <body>
            <!-- comment -->
            text1
            <a>
                <b>text2</b>
            </a>
        </body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>

Recense les éléments d’un objet XML. Un élément se compose d’une balise de début et d’une balise de fin, telle que <first></first>. Le paramètre name est facultatif. Le paramètre name peut être un objet QName, un type de données String ou tout autre type de données converti ensuite au type de données String. Utilisez le paramètre name pour recenser un élément spécifique. Par exemple, l’élément first renvoie John dans cet exemple : <first>John</first>.

Pour recenser tous les éléments, utilisez le paramètre astérisque (*). L’astérisque est également le paramètre par défaut.

La méthode length() associée au paramètre astérisque permet d’extraire le nombre total d’éléments. Par exemple, numElement = addressbook.elements("*").length().

Paramètres

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
            text
            <a>1</a>
            <b>2</b>
        </foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b>

var xml:XML =
 <student id="206">
    <class name="Trigonometry" />
    <class name="Spanish 2" />
 </student>
trace(xml.elements("class")); 

Vérifie si l’objet XML intègre un contenu complexe. Le contenu d’un objet XML est complexe s’il possède des éléments enfant. Les objets XML qui représentent des attributs, des commentaires, des instructions de traitement et des nœuds de texte n’intègrent pas un contenu complexe. Le contenu d’un objet qui intègre ces entités peut néanmoins être considéré comme complexe si l’objet possède des éléments enfant.

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

Vérifie si l’objet possède la propriété spécifiée par le paramètre p.

Paramètres

Informations complémentaires

var xml:XML = 
        <foo>
            <a />
            <a>
                <b>10</b>
            </a>
            <a>
                <b>11</b>
            </a>
        </foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11")); 

trace(xml.a.(b == "11"));

var xml:XML = 
        <orders>
            <order id='1'>
                <item>toothbrush</item>
                <item>toothpaste</item>
            </order>
            <order>
                <returnItem>shoe polish</returnItem>
            </order>
        </orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush"))); 

Vérifie si l’objet XML intègre un contenu simple. Un objet XML intègre un contenu simple s’il représente un nœud de texte, un nœud d’attribut ou un élément XML sans élément enfant. Les objets XML qui représentent des commentaires et des instructions de traitement n’intègrent pas un contenu simple.

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

Recense les espaces de noms associés à l’objet XML, par rapport au parent de l’objet.

Informations complémentaires

Insère le paramètre child2 indiqué après le paramètre child1 dans cet objet XML et renvoie l’objet produit. Si le paramètre child1 est réglé sur null, la méthode insère le contenu de child2 avant tous les enfants de l’objet XML (en d’autres termes, après none). Si child1 est fourni, mais qu’il n’existe pas dans l’objet XML, celui-ci n’est pas modifié et undefined est renvoyé.

Si vous appelez cette méthode pour un enfant XML qui n’est pas un élément (texte, attributs, commentaires, pi, etc.), undefined est renvoyé.

Utilisez l’opérateur delete (XML) pour supprimer les nœuds XML.

Paramètres

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

 <menu>
     <item>burger</item>
     <saleItem>fries</saleItem>
     <item>soda</item>
 </menu>

Insère le paramètre child2 indiqué après le paramètre child1 dans cet objet XML et renvoie l’objet produit. Si le paramètre child1 est réglé sur null, la méthode insère le contenu de child2 après tous les enfants de l’objet XML (en d’autres termes, avant none). Si child1 est fourni, mais qu’il n’existe pas dans l’objet XML, celui-ci n’est pas modifié et undefined est renvoyé.

Si vous appelez cette méthode pour un enfant XML qui n’est pas un élément (texte, attributs, commentaires, pi, etc.), undefined est renvoyé.

Utilisez l’opérateur delete (XML) pour supprimer les nœuds XML.

Paramètres

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildBefore(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

 <menu>
     <saleItem>fries</saleItem>
     <item>burger</item>
     <item>soda</item>
 </menu>

Pour les objets XML, cette méthode renvoie toujours l’entier 1. La méthode length() de la classe XMLList renvoie la valeur 1 si l’objet XMLList ne contient qu’une seule valeur.

Informations complémentaires

Indique la partie nom local du nom complet de l’objet XML.

Informations complémentaires

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.localName()); // Envelope

Indique le nom complet de l’objet XML.

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope"

var xml:XML = 
        <foo x="15" y="22">
            text
        </foo>;
        
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x

Si vous ne fournissez pas de paramètre, indique l’espace de noms associé au nom complet de cet objet XML. Si vous spécifiez un paramètre prefix, la méthode renvoie l’espace de noms correspondant au paramètre prefix qui figure dans le domaine associé à l’objet XML. S’il n’existe pas d’espace de noms de ce type, la méthode renvoie undefined.

Paramètres

Informations complémentaires

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope

var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather"

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">
                <!-- ... -->
        </rdf:RDF>;
                    
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined

Recense les déclarations d’espace de nom associées à l’objet XML dans le contexte de l’objet parent.

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">

            <!-- ... -->
            
        </rdf:RDF>;
                    
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
    var ns:Namespace = xml.namespaceDeclarations()[i]; 
    var prefix:String = ns.prefix;
    if (prefix == "") {
        prefix = "(default)";
    }
    trace(prefix + ":" , ns.uri);
}

rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
 dc: http://purl.org/dc/elements/1.1/
 (default): http://purl.org/rss/1.0/

Définit le type de nœud : texte, commentaire, instruction de traitement, attribut ou élément.

Informations complémentaires

Eléments de l’API associés

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;

var xml:XML = 
    <example id="10">
        <!-- this is a comment -->
        <?test this is a pi ?>
        and some text
    </example>;

trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute

Pour l’objet XML et tous les objets XML descendants, fusionne les nœuds de texte adjacents et supprime les nœuds de texte vides.

Informations complémentaires

var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1

Renvoie le parent de l’objet XML. Si l’objet XML ne possède pas de parent, la méthode renvoie undefined.

Plus d’exemples

Informations complémentaires

var xml:XML = 
    <body>
        <p id="p1">Hello</p>
        <p id="p2">Test:
            <ul>
                <li>1</li>
                <li>2</li>
            </ul>
        </p>
    </body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2

Insère une copie de l’objet child fourni dans l’élément XML avant toute propriété XML associée à cet élément.

Utilisez l’opérateur delete (XML) pour supprimer les nœuds XML.

Paramètres

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.prependChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>

Si un paramètre name est spécifié, recense tous les enfants de l’objet XML qui contiennent des instructions de traitement portant le name indiqué. Si aucun paramètre n’est spécifié, la méthode recense tous les enfants de l’objet XML qui contiennent des instructions de traitement.

Paramètres

Informations complémentaires

XML.ignoreProcessingInstructions = false;
var xml:XML =
    <body>
            foo
            <?xml-stylesheet href="headlines.css" type="text/css" ?>
            <?instructionX ?>
            
    </body>;

trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet

Vérifie si la propriété p figure dans le jeu de propriétés qui peut faire l’objet d’une itération avec une instruction for..in appliquée à l’objet XML. Ne renvoie true que si toString(p) == "0".

Paramètres

Informations complémentaires

var xml:XML = 
        <body>
             <p>Hello</p>
               <p>World</p>
        </body>;

trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false

for (var propertyName:String in xml) {
    trace(xml[propertyName]);
}

var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false

for (var propertyName:String in list) { 
    trace(list[propertyName]);
}

Supprime l’espace de noms indiqué pour cet objet et tous ses descendants. La méthode removeNamespaces() ne supprime pas un espace de noms s’il est référencé par le nom complet de l’objet ou celui des attributs de l’objet.

Paramètres

Informations complémentaires

var xml:XML = 
    <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
        xmlns:dc="http://purl.org/dc/elements/1.1/" 
        xmlns="http://purl.org/rss/1.0/">
    
        <!-- ... -->
        
    </rdf:RDF>;

trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); // 
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2

Remplace les propriétés spécifiées par le paramètre propertyName par le paramètre value indiqué. Si aucune propriété ne correspond à propertyName, l’objet XML n’est pas modifié.

Paramètres

Informations complémentaires

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace(1, <p>Bob</p>);
trace(xml);

 <body>
     <p>Hello</p>
     <p>Bob</p>
     <hr/>
 </body>
 

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("p", <p>Hi</p>); 
trace(xml);

 <body>
     <p>Hi</p>
     <hr/>
 </body>;
 

var xml:XML = 
    <ns:body xmlns:ns = "myNS">
        <ns:p>Hello</ns:p>
        <ns:p>World</ns:p>
        <hr/>
    </ns:body>;

var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);

 <ns:body xmlns:ns = "myNS">
     <p>Bob</p>
     <hr/>
 </ns:body>
 

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("*", <img src = "hello.jpg"/>);
trace(xml);

 <body>
     <img src="hello.jpg"/>
 </body>
 

Remplace les propriétés enfant de l’objet XML par l’ensemble de propriétés XML spécifié, fourni dans le paramètre value.

Paramètres

Informations complémentaires

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
    </body>;

var list:XMLList = xml.p;

xml.setChildren(<p>hello</p>);
trace(xml);

//    <body>
//        <p>hello</p>
//    </body>

xml.setChildren(list);
trace(xml);

//    <body>
//        <p>Hello</p>
//        <p>World</p>
//    </body>

Remplace le nom local de l’objet XML par le paramètre name indiqué.

Paramètres

Informations complémentaires

var xml:XML = 
    <ns:item xmlns:ns="http://example.com">
        toothbrush
    </ns:item>;
    
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>

Règle le nom de l’objet XML sur le nom complet ou le nom d’attribut indiqué.

Paramètres

Informations complémentaires

var xml:XML = 
    <item>
        toothbrush
    </item>;
    
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>

Définit l’espace de noms associé à l’objet XML.

Paramètres

Informations complémentaires

var xml1:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
            <!-- ... -->
        </soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");

var xml2:XML = 
    <Envelope>
        <Body/>
    </Envelope>;
    
xml2.setNamespace(ns);

trace(xml2);

Définit les valeurs des propriétés XML suivantes : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting. Les réglages par défaut, appliqués si vous ne spécifiez pas de paramètre setObj, sont les suivants :

• XML.ignoreComments = true
• XML.ignoreProcessingInstructions = true
• XML.ignoreWhitespace = true
• XML.prettyIndent = 2
• XML.prettyPrinting = true

Remarque : cette méthode ne doit pas être appliquée à une occurrence de la classe XML, mais à XML, comme illustré dans le code suivant : XML.setSettings().

Paramètres

Informations complémentaires

Eléments de l’API associés

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Extrait les propriétés suivantes : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting.

Eléments de l’API associés

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Renvoie un objet XMLList contenant toutes les propriétés XML de l’objet XML qui représente les nœuds de texte XML.

Informations complémentaires

var xml:XML =
        <body>
            text1
            <hr/>
            text2
        </body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2

Fournit une méthode remplaçable pour personnaliser l’encodage JSON de valeurs dans un objet XML.

La méthode JSON.stringify() recherche une méthode toJSON() sur chaque objet qu’elle traverse. Si la méthode toJSON() est trouvée, la méthode JSON.stringify() l’appelle automatiquement pour chaque valeur qu’elle rencontre, en transmettant la clé associée à la valeur.

XML fournit une implémentation par défaut de la méthode toJSON(), qui renvoie simplement le nom de la classe. Les clients qui souhaitent exporter les objets XML vers la méthode JSON doivent fournir leur propre implémentation. Pour ce faire, vous pouvez redéfinir la méthode toJSON() sur le prototype de classe.

La méthode toJSON() peut renvoyer une valeur de n’importe quel type. Si elle renvoie un objet, stringify() se répète dans cet objet. Si toJSON() renvoie une chaîne, stringify() ne se répète pas et poursuit sa traversée.

Paramètres

Informations complémentaires

Eléments de l’API associés

Renvoie l’objet XML sous forme de chaîne. Les règles de cette conversion varient selon que l’objet XML intègre un contenu simple ou complexe :

• Si l’objet XML comporte un contenu simple, toString() renvoie le contenu de la chaîne de l’objet XML en éliminant les éléments suivants : la balise initiale, les attributs, les déclarations d’espace de noms et la balise de fin.

• Si l’objet XML intègre un contenu complexe, toString() renvoie une chaîne codée au format XML qui représente l’objet XML entier, y compris la balise de début, les attributs, les déclarations d’espace de noms et la balise de fin.

Pour renvoyer à chaque fois l’objet XML entier, utilisez la méthode toXMLString().

Plus d’exemples

Eléments de l’API associés

var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example

var test:XML = 
<type name="Joe">
    <base name="Bob"></base>
    example
</type>;
trace(test.toString());
  // <type name="Joe">
  // <base name="Bob"/>
  // example
  // </type> 

Renvoie l’objet XML sous forme de chaîne. A l’encontre de la méthode toString(), la méthode toXMLString() renvoie toujours la balise de début, les attributs et la balise de fin de l’objet XML, que son contenu soit simple ou complexe (la méthode toString() supprime ces éléments si l’objet XML intègre un contenu simple).

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

var xml:XML =
        <p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>

Renvoie l’objet XML.

Informations complémentaires

var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true