QName  - AS3

Nom local de l’objet QName.

URI (Uniform Resource Identifier) de l’objet QName.

Crée un objet QName qui est une copie d’un autre objet QName. Si le paramètre transmis au constructeur est un objet QName, une copie de ce dernier est créée. Si le paramètre n’est pas un objet QName, le paramètre est converti en chaîne et affecté à la propriété localName de la nouvelle occurrence de QName. Si le paramètre est réglé sur undefined ou n’est pas spécifié, un nouvel objet est créé et sa propriété localName est définie sur la chaîne vide.

Remarque : cette classe utilise deux entrées de constructeur, car chaque forme accepte des paramètres différents. Le constructeur se comporte différemment selon le type et le nombre de paramètres transmis, comme indiqué dans chaque entrée. ActionScript 3.0 ne prend pas en charge la surcharge d’une méthode ou d’un constructeur.

Crée un objet QName associé à une URI à partir d’un objet Namespace et une valeur localName extraite d’un objet QName. Si l’un des paramètres ne correspond pas au type de données attendu, le paramètre est converti en chaîne et est affecté à la propriété correspondante du nouvel objet QName. Si, par exemple, les deux paramètres sont des chaînes, un nouvel objet QName est renvoyé. La propriété uri est définie sur le premier paramètre et la propriété localName est définie sur le second paramètre. En d’autres termes, les permutations suivantes (qui ne constituent que quelques exemples) représentent des formes valides du constructeur :

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

Si vous transmettez null pour le paramètre uri, la propriété uri du nouvel objet QName est définie sur null.

Remarque : cette classe utilise deux entrées de constructeur, car chaque forme accepte des paramètres différents. Le constructeur se comporte différemment selon le type et le nombre de paramètres transmis, comme indiqué dans chaque entrée. ActionScript 3.0 ne prend pas en charge la surcharge d’une méthode ou d’un constructeur.

Renvoie une chaîne composée de l’URI et le nom local de l’objet QName, séparés par « :: ».

Le format varie selon la propriété uri de l’objet QName :

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

Renvoie l’objet QName.

1. Création d’une occurrence d’espace de noms, puis utilisation de cette dernière en tant qu’entrée pour le constructeur QName. Cette approche est préférable lorsque vous utilisez ultérieurement la propriété Namespace.prefix à d’autres fins.
2. Création d’une occurrence de QName utilisant une valeur de chaîne pour le paramètre uri dans le constructeur QName.

Ce code produit les résultats suivants :

1. Définit une variable XML appelée rssXML.
2. Crée un nouvel objet Namespace avec le préfixe dc.
3. Crée un objet QName qui utilise l’objet Namespace et le créateur de nom local.
4. Appelle la méthode showDescendants(), qui utilise la méthode XML.descendants() pour obtenir une occurrence XMLList contenant tous les éléments descendants dont le nom qualifié correspond à l’occurrence QName donnée.
5. Affiche le nom qualifié et la valeur de texte des éléments de la liste à l’aide d’une boucle for each.
6. Crée un autre objet QName qui utilise une valeur de chaîne pour le paramètre uri et la date du nom local.
7. Appelle à nouveau la méthode showDescendants() pour afficher le nom et la valeur de texte des éléments descendants.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}