MovieClip  - AS3

Gibt die Nummer des Bilds in der Zeitleiste der MovieClip-Instanz zurück, bei dem sich der Abspielkopf gerade befindet. Umfasst der Movieclip mehrere Szenen, bezeichnet dieser Wert die Bildnummer in der aktuellen Szene.

mc1.gotoAndStop(mc1.currentFrame + 5);

Die Beschriftung des aktuellen Bilds in der Zeitleiste der MovieClip-Instanz. Wenn das aktuelle Bild keine Beschriftung hat, hat currentLabel den Wert null.

Die aktuelle Bezeichnung der Szene in der Zeitleiste der MovieClip-Instanz, in der sich der Abspielkopf gerade befindet. Wenn das aktuelle Bild keine Bezeichnung aufweist, wird currentLabel auf den Namen eines vorherigen Bilds gesetzt, das über eine Bezeichnung verfügt. Wenn das aktuelle Bild und die vorherigen Bilder keine Bezeichnung enthalten, wird für currentLabel der Wert null zurückgegeben.

trace(mc1.currentLabel);

Gibt ein Array an FrameLabel-Objekten aus der aktuellen Szene zurück. Verwendet die MovieClip-Instanz keine Szenen, enthält das Array alle Bildbezeichnungen aus der gesamten MovieClip-Instanz.

Verwandte API-Elemente

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

Die aktuelle Szene in der Zeitleiste der MovieClip-Instanz, in der sich der Abspielkopf gerade befindet.

Verwandte API-Elemente

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

Ein boolescher Wert, der angibt, ob ein Movieclip aktiviert ist. Der Standardwert von enabled lautet true. Wenn enabled auf false gesetzt ist, werden die Bilder „Over“, „Down“ und „Up“ des Movieclips deaktiviert. Der Movieclip empfängt auch weiterhin Ereignisse (beispielsweise mouseDown, mouseUp, keyDown und keyUp).

Die enabled-Eigenschaft steuert nur die schaltflächenähnlichen Eigenschaften eines Movieclips. Sie können die enabled-Eigenschaft jederzeit ändern. Der geänderte Movieclip wird dann sofort aktiviert oder deaktiviert. Wenn enabled auf false gesetzt ist, wird das Objekt bei der automatischen Tabulatorreihenfolge nicht berücksichtigt.

mc1.enabled = false;

Die Anzahl der Bilder, die aus einer SWF-Streaming-Datei geladen werden. Mithilfe der framesLoaded-Eigenschaft können Sie feststellen, ob die Inhalte eines bestimmten Bildes und aller vorausgehenden Bilder geladen wurden und im Browser lokal zur Verfügung stehen. Außerdem kann damit der Download großer SWF-Dateien überwacht werden. Beispielsweise können Sie eine Meldung anzeigen lassen, die dem Benutzer mitteilt, dass die SWF-Datei geladen wird, bis ein bestimmtes Bild in der SWF-Datei vollständig geladen ist.

Umfasst der Movieclip mehrere Szenen, gibt die framesLoaded-Eigenschaft die Anzahl der für alle Szenen im Movieclip geladenen Bilder zurück.

Verwandte API-Elemente

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

Ein boolescher Wert, der angibt, ob zurzeit ein Movieclip abgespielt wird.

Ein Array an Scene-Objekten, von denen jedes den Namen, die Anzahl der Bilder und die Bildbezeichnungen für eine Szene in der MovieClip-Instanz auflistet.

Verwandte API-Elemente

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

Die Anzahl aller Bilder in der MovieClip-Instanz.

Umfasst der Movieclip mehrere Szenen, gibt die totalFrames-Eigenschaft die Anzahl der Bilder in allen Szenen im Movieclip zurück.

 trace(mc1.totalFrames);

Gibt an, ob andere Anzeigeobjekte, die SimpleButton- oder MovieClip-Objekte sind, Mouse-Release-Ereignisse oder Release-Ereignisse von anderen Benutzereingaben empfangen können. Die trackAsMenu-Eigenschaft dient zum Erstellen von Menüs. Sie können die trackAsMenu-Eigenschaft für jedes SimpleButton- oder MovieClip-Objekt setzen. Der Standardwert der trackAsMenu-Eigenschaft lautet false.

Sie können die trackAsMenu-Eigenschaft jederzeit ändern. Der geänderte Movieclip übernimmt sofort das neue Verhalten.

 mc1.trackAsMenu = true;

Erstellt eine neue MovieClip-Instanz. Nachdem Sie den Movieclip erstellt haben, rufen Sie für einen Anzeigeobjekt-Container, der sich auf der Bühne befindet, die Methode addChild() oder addChildAt() auf.

Startet die Wiedergabe der SWF-Datei beim angegebenen Bild. Dies passiert, nachdem alle im Bild verbleibenden Aktionen ganz ausgeführt worden sind. Um eine Szene und ein Bild anzugeben, geben Sie einen Wert für den Parameter scene an.

Parameter

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

Verschiebt den Abspielkopf zum angegebenen Bild im Movieclip und hält ihn dort an. Dies passiert, nachdem alle im Bild verbleibenden Aktionen ganz ausgeführt worden sind. Wenn Sie eine Szene zusätzlich zu einem Bild angeben möchten, verwenden Sie den Parameter scene.

Parameter

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

Verschiebt den Abspielkopf zum nächsten Bild und stoppt die Wiedergabe. Dies passiert, nachdem alle im Bild verbleibenden Aktionen ganz ausgeführt worden sind.

Verwandte API-Elemente

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Verschiebt den Abspielkopf in die nächste Szene der Movieclip-Instanz. Dies passiert, nachdem alle im Bild verbleibenden Aktionen ganz ausgeführt worden sind.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Verschiebt den Abspielkopf in der Zeitleiste des Movieclips.

Verwandte API-Elemente

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

Verschiebt den Abspielkopf zum vorigen Bild und stoppt die Wiedergabe. Dies passiert, nachdem alle im Bild verbleibenden Aktionen ganz ausgeführt worden sind.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Verschiebt den Abspielkopf in die vorige Szene der MovieClip-Instanz. Dies passiert, nachdem alle im Bild verbleibenden Aktionen ganz ausgeführt worden sind.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Stoppt den Abspielkopf im Movieclip.

1. Die Konstruktorfunktion definiert ein Textfeld, das verwendet wird, um die Werte der Eigenschaften des MovieClipExample-Objekts anzuzeigen (das „MovieClip“ erweitert).
2. Der Rückgabewert der getPropertiesString()-Methode wird als Text für das outputText-Textfeld verwendet. Die getPropertiesString()-Methode gibt einen String zurück, der mit Werten der folgenden Eigenschaften des Movieclips gefüllt wird: currentFrame, currentLabel, currentScene, framesLoaded, totalFrames und trackAsMenu.
3. Zwei Codezeilen in der Konstruktorfunktion passen die Eigenschaften width und height des Textfelds outputText an.
4. Die letzte Zeile der Konstruktorfunktion fügt das Textfeld outputText der Anzeigeliste hinzu.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}