SimpleButton  - AS3

指定用來當作按鈕「按下」狀態 (指的是當使用者選取 hitTestState物件時，按鈕所處的狀態) 視覺物件的顯示物件。

相關 API 元素

指定按鈕是否已啟用的 Boolean 值。 按鈕停用時 (enabled 屬性設為 false)，可以看見卻無法按下按鈕。 預設值是 true。如果您想要停用部份瀏覽功能時，這個屬性便十分實用；例如，您可能會想要停用現在顯示頁面中的按鈕，使該按鈕的狀態變為無法按下，頁面也無法重新載入。

注意：為了防止按鈕上發生 mouseClicks，請將 enabled 和 mouseEnabled 屬性都設定為 false。

指定用來當作按鈕測試物件的顯示物件。 如果是基本按鈕，請將 hitTestState 屬性設為 overState 屬性所屬的相同顯示物件。 如果您沒有設定 hitTestState 屬性，便不會啟用 SimpleButton，表示該類別不會回應使用者輸入事件。

相關 API 元素

指定用來當做按鈕「一般」狀態 (指的是當指標滑入按鈕上方時，按鈕所處的狀態) 視覺物件的顯示物件。

相關 API 元素

指定給這個按鈕的 SoundTransform 物件。 SoundTransform 物件包含可用來設定音量、左右相位、指定左邊喇叭，以及指定右邊喇叭的屬性。 這個 SoundTransform 物件可以套用至所有按鈕狀態。 這個 SoundTransform 物件只會影響內嵌的聲音。

相關 API 元素

指示其他屬於 SimpleButton 或 MovieClip 物件的顯示物件是否可以接收使用者輸入放開事件。trackAsMenu 屬性可讓您建立選單。 您可以在任何 SimpleButton 或 MovieClip 物件上設定 trackAsMenu 屬性。 如果 trackAsMenu 屬性不存在，則預設的行為指令是 false。

您可以隨時更改 trackAsMenu 屬性；修改後的按鈕會立即採用新的行為指令。

指定用來當做按鈕「一般」狀態 (指的是當指標並尚未滑入按鈕上方時，按鈕所處的狀態) 之視覺物件的顯示物件。

相關 API 元素

Boolean 值，設定為 true時，表示指標滑入按鈕上方時是否顯示手掌游標。如果屬性設定為 false，則會顯示箭頭游標。 預設值為 true。

您可以隨時更改 useHandCursor 屬性；修改後的按鈕會立即採用新的游標行為指令。

建立新的 SimpleButton 實體。 代表不同按鈕狀態可設為建構函式中的參數之任何或所有顯示物件。

1. 在 SimpleButtonExample() 建構函式中，建立名為 button、類型為 SimpleButton 的新 CustomSimpleButton 物件，此物件會呼叫 CustomSimpleButton 建構函式方法。 button 物件會加入至顯示清單。 該按鈕的顏色和大小會在接下來的步驟中決定。
2. 在 CustomSimpleButton 類別中宣告實體屬性，稍後會使用這些屬性來控制 button 的大小和背景顏色 (根據它的狀態而定，橘色為一般狀態、深黃色為滑鼠滑入狀態，而淺綠色則為滑鼠按下狀態)。 * 在 button 的所有狀態中，您可以使用 size 屬性將正方形的大小設為 80 像素。
3. CustomSimpleButton 類別的建構函數會設定 ButtonDisplayState 類別之四個實體的 downState、overState、upState、hitTestState 和 useHandCursor 屬性。
4. 在 ButtonDisplayState 類別中，此建構函式會設定正方形的大小值與背景顏色，並呼叫 draw() 方法。
5. draw() 方法會以該建構函式中所設定、視按鈕狀態而定的大小與背景顏色，重新繪製該正方形。

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}